build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

plugins {
    id 'java'
    id 'distribution'
}

group 'org.citydb.plugins'
version '2.3.0'

apply from: 'properties.gradle'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(11)
    }
}

repositories {
    maven {
        url 'https://repo.osgeo.org/repository/release'
    }
    maven{
        url 'https://3dcitydb.org/maven'
    }
    mavenCentral()
}

dependencies {
    implementation 'org.citydb:impexp-client-gui:5.5.0'
    implementation fileTree(dir: 'lib', include: '*.jar')
}

processResources {
    filesMatching('**/plugin.xml') {
        filteringCharset = 'UTF-8'
        filter(ReplaceTokens, tokens: [
                name: project.pluginShortName,
                version: project.version,
                url: project.pluginUrl,
                vendor: project.citydbProject,
                vendorUrl: project.citydbWebsiteUrl,
                citydbName: project.citydbName,
                citydbShortName: project.citydbShortName,
                testADEUrl: project.testADEUrl
        ])
    }
}

jar {
    manifest {
        attributes('Implementation-Title': project.name,
                'Implementation-Version': project.version
        )
    }
    into('META-INF') {
        from 'resources/license/APACHE-2.0.txt'
        from 'resources/license/LICENSE.txt'
    }
}

distributions.main.contents {
    from jar
    from('resources/doc/README.txt') {
        filteringCharset = 'UTF-8'
        filter(ReplaceTokens, tokens: [
                pluginName: project.pluginName,
                pluginShortName: project.pluginShortName,
                version: project.version,
                date: project.date.format('yyyy-MM-dd'),
                impexpName: project.impexpName,
                impexpVersion: project.impexpVersion,
                pkgName: "$project.name-$project.version".toString(),
                zipName: "$project.name-$project.version".toString() + '.zip',
                citydbName: project.citydbName,
                citydbWebsiteUrl: project.citydbWebsiteUrl,
                citydbVcsUrl: project.citydbVcsUrl,
                pluginUrl: project.pluginUrl,
                vendorName: project.vendorName,
                vendorOrganisation: project.vendorOrganisation,
                vendorCountry: project.vendorCountry,
                vendorCopyright: project.vendorCopyright,
                vendorWebsiteUrl: project.vendorWebsiteUrl
        ])
    }
    into('lib') {
        from 'lib'
        exclude 'shared'
    }
    into('samples') {
        from 'samples'
    }
    into('license') {
        from 'resources/license/APACHE-2.0.txt'
        from 'resources/license/LICENSE.txt'
    }
}