Installer script

[terenc3]

Hi, i've written an installer script for NSIS. It features autostart and uninstaller with correct icons. It may not be perfect but i'd like to share it

# Taken from /main/VoicemeeterOsdProgram/VoicemeeterOsdProgram.csproj#L11
!define APPNAME "VoicemeeterFancyOsd"
# Taken from /main/VoicemeeterOsdProgram/VoicemeeterOsdProgram.csproj#L12
!define APPPUBLISHER "A-tg"
!define APPVERSION "0.10.3.1"

!define ARP "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APPNAME}"

!include "FileFunc.nsh"

Name "${APPNAME} ${APPVERSION}"
OutFile "${APPNAME}-${APPVERSION}.exe"
InstallDir "$PROGRAMFILES\${APPNAME}"
Page components
Page directory
Page instfiles
UninstPage uninstConfirm
UninstPage instfiles

Section "Application"
	SetOutPath $INSTDIR
	File /r /x setup.nsi *.*
	WriteUninstaller $INSTDIR\uninstaller.exe

	# Uninstaller
	WriteRegStr HKLM "${ARP}" "DisplayName" "${APPNAME}"
	WriteRegStr HKLM "${ARP}" "DisplayVersion" "${APPVERSION}"
	WriteRegStr HKLM "${ARP}" "InstallLocation" "$INSTDIR"
	WriteRegStr HKLM "${ARP}" "Publisher" "${APPPUBLISHER}"
	WriteRegStr HKLM "${ARP}" "DisplayIcon" "$\"$INSTDIR\VoicemeeterFancyOsdHost.exe$\""
	WriteRegStr HKLM "${ARP}" "UninstallString" "$\"$INSTDIR\uninstaller.exe$\""

	${GetSize} "$INSTDIR" "/S=0K" $0 $1 $2
	IntFmt $0 "0x%08X" $0
	WriteRegDWORD HKLM "${ARP}" "EstimatedSize" "$0"
SectionEnd

Section "Startmenu"
	SetShellVarContext all
	CreateShortCut "$SMPROGRAMS\${APPNAME}.lnk" "$INSTDIR\VoicemeeterFancyOsdHost.exe" "" "$INSTDIR\VoicemeeterFancyOsdHost.exe" 0
SectionEnd

Section "Autostart"
	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "${APPNAME}" '"$INSTDIR\VoicemeeterFancyOsdHost.exe"'
	# Company and Name are taken from the .exe
SectionEnd

Section "Uninstall"
	SetShellVarContext all
	DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "${APPNAME}"
	DeleteRegKey HKLM "${ARP}"
	Delete "$INSTDIR\uninstaller.exe"
	Delete "$SMPROGRAMS\${APPNAME}.lnk"
	RMDir /r $INSTDIR
SectionEnd

Function .onInit
	SectionSetFlags 0 17
FunctionEnd

To use it, install nsis, save the script somewhere and compile it with right click, which generates an installer

[A-tG]

You should use VoicemeeterFancyOsdHost.exe instead of VoicemeeterFancyOsd.exe as decribed