build.gradle

plugins {
    id 'fabric-loom' version '0.10-SNAPSHOT' apply false
    id "com.matthewprenger.cursegradle" version "$cursegradle_version" apply false
}

subprojects {
    apply plugin: 'java'

    java.toolchain.languageVersion = JavaLanguageVersion.of(17)
//    java.withSourcesJar()
//    java.withJavadocJar()

    jar {
        manifest {
            attributes([
                    'Specification-Title'     : mod_name,
                    'Specification-Vendor'    : mod_author,
                    'Specification-Version'   : project.jar.archiveVersion,
                    'Implementation-Title'    : project.name,
                    'Implementation-Version'  : project.jar.archiveVersion,
                    'Implementation-Vendor'   : mod_author,
                    'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                    'Timestampe'              : System.currentTimeMillis(),
                    'Built-On-Java'           : "${System.getProperty('java.vm.version')} (${System.getProperty('java.vm.vendor')})",
                    'Build-On-Minecraft'      : minecraft_version
            ])
        }
    }

    repositories {
        mavenCentral()

        maven {
            name = 'Sponge / Mixin'
            url = 'https://repo.spongepowered.org/repository/maven-public/'
        }

        maven {
            name = 'BlameJared Maven (CrT / Bookshelf)'
            url = 'https://maven.blamejared.com'
        }
    }


    tasks.withType(JavaCompile).configureEach {
        it.options.encoding = 'UTF-8'
        it.options.release = 17
    }

    // Disables Gradle's custom module metadata from being published to maven. The
    // metadata includes mapped dependencies which are not reasonably consumable by
    // other mod developers.
    tasks.withType(GenerateModuleMetadata) {
        enabled = false
    }

    def isForge = project.name == 'Forge'
    def key =  System.getenv('CURSEFORGEKEY')
    println key
    if (project.name != 'Common') {
        apply plugin: 'com.matthewprenger.cursegradle'
        if (!isForge) apply plugin: 'fabric-loom'
        def changelogFile = rootProject.file('CHANGELOG.md').text

        curseforge {
            apiKey = key
            project {
                id = project.projectId
                releaseType = project.releaseType
                changelogType = 'markdown'
                changelog = changelogFile
                addGameVersion project.minecraft_version
                addGameVersion project.name
                mainArtifact(isForge ? jar : remapJar)
            }
            options {
                debug = false
                forgeGradleIntegration = isForge
            }
        }
    }
}