build.gradle

buildscript {
    repositories {
        jcenter()
        maven {
            name = "forge"
            url = "https://files.minecraftforge.net/maven"
        }
        maven {
            url = "https://jitpack.io"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}

plugins {
    id 'java'
    id 'org.spongepowered.plugin' version '0.9.0'
    id 'com.github.johnrengelman.shadow' version '2.0.4'
}

apply plugin: 'net.minecraftforge.gradle.forge'

group 'agp.andwhat5'
version '1.1.0'
ext.spongeversion = '7.2.0'
ext.teslaversion = '1.1.6'
ext.pixelmonversion = '8.1.2'

repositories {
    maven {
        url 'https://jitpack.io'
    }

    flatDir {
        dirs 'libs'
    }
}

dependencies {
    compileOnly 'org.spongepowered:spongeapi:7.2.0'
    implementation "com.github.SimonFlash.TeslaPowered:TeslaLibs:v${teslaversion}"
    compileOnly "com.pixelmonmod:Pixelmon:1.12.2-${pixelmonversion}-universal"
}

jar {
    archiveName = "${project.name}-s${spongeversion[0..2]}-t${teslaversion}-v${version}.jar"
}

shadowJar {
    exclude "Pixelmon-1.12.2-${pixelmonversion}-universal.jar"
    dependencies {
        include dependency("com.github.SimonFlash.TeslaPowered:TeslaLibs:v${teslaversion}")
    }
    relocate 'com.mcsimonflash.sponge.teslalibs', 'co.carrd.andwhat5.sts.sponge.wondertrade.teslalibs'
    archiveName = "${project.name}-s${spongeversion.substring(0, 3)}-v${version}.jar"
}

reobf {
    shadowJar {
        mappingType = 'SEARGE'
    }
}

task copyJars(type: Copy) {
    from shadowJar into project.file("#releases/${version[0..4]}")
}

build.dependsOn(reobfShadowJar)
build.dependsOn(copyJars)

minecraft {
    version = "1.12.2-14.23.5.2838"
    runDir = "run"
    mappings = project.mcpVersion
    useDepAts = true
}

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'

        // replace version and mcversion
        expand 'version': project.version, 'mcversion': project.minecraft.version
    }

    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}