build.gradle

plugins {
	id 'fabric-loom' version '0.8-SNAPSHOT'
	id 'maven-publish'
}

sourceCompatibility = JavaVersion.VERSION_16
targetCompatibility = JavaVersion.VERSION_16

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
	// Add repositories to retrieve artifacts from in here.
	// You should only use this when depending on other mods because
	// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
	// See https://docs.gradle.org/current/userguide/declaring_repositories.html
	// for more information about repositories.

	maven {
		url 'https://raw.githubusercontent.com/Devan-Kerman/Devan-Repo/master/'
	}

	maven {
		name 'Terraformers'
		url 'https://maven.terraformersmc.com/releases/'
	}

	maven {
		name "AperLambda"
		url 'https://aperlambda.github.io/maven'
	}

	maven {
		name "Gegy"
		url 'https://maven.gegy.dev'
	}

	maven {
		name "Modrinth"
		url "https://api.modrinth.com/maven"
	}

	maven {
		name "dblsaiko"
		url "https://maven.dblsaiko.net/"
	}
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	// PSA: Some older mods, compiled on Loom 0.2.1, might have outdated Maven POMs.
	// You may need to force-disable transitiveness on them.

	//Libraries and APIs
	//ARRP
	modImplementation group: "net.devtech", name: "arrp", version: "${project.arrp_version}"	//API
	include group: "net.devtech", name: "arrp", version: "${project.arrp_version}"				//API

	//LamdDynamicLights
	modApi "dev.lambdaurora:lambdynamiclights:${project.Lambdynamiclights_version}"				//API

	//Datapack Item operations
	modImplementation "maven.modrinth:dp_item_ops:${project.datapack_item_ops_version}"			//API + Lib
	include "maven.modrinth:dp_item_ops:${project.datapack_item_ops_version}"					//API + Lib

	//JMX and FREX
	modApi ("grondag:frex-${project.mc_tag}:${project.frex_version}.+") { transitive = false}
	include "grondag:frex-${project.mc_tag}:${project.frex_version}.+"

	modImplementation ("grondag:jmx-${project.mc_tag}:${project.jmx_version}.+") { transitive = false}
	include "grondag:jmx-${project.mc_tag}:${project.jmx_version}.+"
}

minecraft {
	accessWidener =  file("src/main/resources/atbyw.accesswidener")
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	// ensure that the encoding is set to UTF-8, no matter what the system default is
	// this fixes some edge cases with special characters not displaying correctly
	// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
	// If Javadoc is generated, this must be specified in that task too.
	it.options.encoding = "UTF-8"

	// Minecraft 1.17 (21w19a) upwards uses Java 16.
	it.options.release = 16
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}"}
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			// add all the jars that should be included when publishing to maven
			artifact(remapJar) {
				builtBy remapJar
			}
			artifact(sourcesJar) {
				builtBy remapSourcesJar
			}
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}