build.gradle

plugins {
    id 'net.researchgate.release' version '2.8.1'
    id 'io.codearte.nexus-staging' version '0.30.0'
    id "com.github.ben-manes.versions" version "0.39.0"
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'maven'
    apply plugin: 'maven-publish'
    apply plugin: 'java-library-distribution'
    apply plugin: 'signing'

    repositories {
        mavenCentral()
        mavenLocal()
    }

    dependencies {
        testCompile(
                'junit:junit:4.13.2',
                'org.mockito:mockito-all:2.0.2-beta'
        )
    }

    project.ext.JETTY_VERSION = "9.4.53.v20231009"


    group = "com.baqend"

    distTar.compression "GZIP"

    tasks.register('javadocJar', Jar) {
        classifier = 'javadoc'
        from javadoc
    }

    tasks.register('sourcesJar', Jar) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    java {
        toolchain {
            languageVersion.set(JavaLanguageVersion.of(8))
        }
    }

    artifacts {
        archives javadocJar, sourcesJar
    }

    javadoc {
        //options.addBooleanOption('html5', true)
    }

    signing {
        sign configurations.archives
    }

    uploadArchives {
        repositories {
            mavenDeployer {
                beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

                repository(url: "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/") {
                    authentication(userName: findProperty('sonatype_user'), password: findProperty('sonatype_password'))
                }

                snapshotRepository(url: "https://s01.oss.sonatype.org/content/repositories/snapshots/") {
                    authentication(userName: findProperty('sonatype_user'), password: findProperty('sonatype_password'))
                }

                pom.project {
                    name 'Restful Jetty'
                    packaging 'jar'
                    description 'A powerful REST Layer for Jetty'
                    url 'https://github.com/Baqend/restful-jetty'

                    scm {
                        connection 'scm:git:https://github.com/Baqend/restful-jetty'
                        developerConnection 'scm:git:https://github.com/Baqend/restful-jetty'
                        url 'https://github.com/Baqend/restful-jetty'
                    }

                    licenses {
                        license {
                            name 'MIT'
                            url 'https://github.com/Baqend/restful-jetty/blob/master/LICENSE'
                        }
                    }

                    developers {
                        developer {
                            id 'com.baqend'
                            name 'Baqend GmbH'
                            email 'info@baqend.com'
                        }
                    }
                }
            }
        }
    }
}

nexusStaging {
    packageGroup = "com.baqend.restful-jetty"
    serverUrl = "https://s01.oss.sonatype.org/service/local/"
    username = findProperty('sonatype_user')
    password = findProperty('sonatype_password')
}

tasks.register('assemble') {
    dependsOn 'restful-jetty:assemble', 'restful-jetty-server:assemble'
}

release {
    preTagCommitMessage = "[ci skip] pre tag commit:"
    tagCommitMessage = "creating tag:"
    newVersionCommitMessage = "[ci skip] new version commit:"
    buildTasks = ['assemble']
    git {
        requireBranch = 'master'
        pushToRemote = 'origin'
    }
}

afterReleaseBuild.dependsOn 'restful-jetty:uploadArchives', 'restful-jetty-server:uploadArchives'