-
Notifications
You must be signed in to change notification settings - Fork 87
/
Copy pathlpr_arrayProgScript.sml
1981 lines (1872 loc) · 56.2 KB
/
lpr_arrayProgScript.sml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(*
This refines lpr_list to use arrays
*)
open preamble basis md5ProgTheory lpr_composeProgTheory UnsafeProofTheory lprTheory lpr_listTheory HashtableProofTheory;
val _ = new_theory "lpr_arrayProg"
val _ = temp_delsimps ["NORMEQ_CONV"]
val _ = diminish_srw_ss ["ABBREV"]
val _ = set_trace "BasicProvers.var_eq_old" 1
val _ = translation_extends"lpr_composeProg";
(* Pure translation of LPR checker *)
val _ = register_type``:lprstep``;
val _ = register_type``:'a spt``;
val _ = translate insert_def;
(* TODO: make sure these get inlined! *)
val _ = translate w8z_def;
val _ = translate w8o_def;
val _ = translate index_def;
val w8z_v_thm = fetch "-" "w8z_v_thm";
val w8o_v_thm = fetch "-" "w8o_v_thm";
val index_side_def = fetch "-" "index_side_def"
val index_side = Q.prove(`
!x. index_side x ⇔ T`,
simp[index_side_def]>>
intLib.ARITH_TAC) |> update_precondition;
val _ = process_topdecs `
exception Fail string;
` |> append_prog
fun get_exn_conv name =
EVAL ``lookup_cons (Short ^name) ^(get_env (get_ml_prog_state ()))``
|> concl |> rand |> rand |> rand
val fail = get_exn_conv ``"Fail"``
Definition Fail_exn_def:
Fail_exn v = (∃s sv. v = Conv (SOME ^fail) [sv] ∧ STRING_TYPE s sv)
End
Definition eq_w8o_def:
eq_w8o v ⇔ v = w8o
End
val _ = translate (eq_w8o_def |> SIMP_RULE std_ss [w8o_def]);
val every_one_arr = process_topdecs`
fun every_one_arr carr cs =
case cs of [] => True
| c::cs =>
if eq_w8o (Unsafe.w8sub carr (index c)) then every_one_arr carr cs
else False` |> append_prog
Definition format_failure_def:
format_failure (lno:num) s =
strlit "c Checking failed at line: " ^ toString lno ^ strlit ". Reason: " ^ s ^ strlit"\n"
End
val _ = translate format_failure_def;
Definition unwrap_TYPE_def:
unwrap_TYPE P x y =
∃z. x = SOME z ∧ P z y
End
val delete_literals_sing_arr_def = process_topdecs`
fun delete_literals_sing_arr lno carr cs =
case cs of
[] => 0
| c::cs =>
if eq_w8o (Unsafe.w8sub carr (index c)) then
delete_literals_sing_arr lno carr cs
else
if every_one_arr carr cs then ~c
else raise Fail (format_failure lno "clause not empty or singleton after reduction")` |> append_prog
val xlet_autop = xlet_auto >- (TRY( xcon) >> xsimpl)
Theorem any_el_eq_EL[simp]:
LENGTH Clist > index h ⇒
any_el (index h) Clist w8z = EL (index h) Clist
Proof
rw[any_el_ALT]
QED
Theorem update_resize_LUPDATE[simp]:
LENGTH Clist > index h ⇒
update_resize Clist w8z v (index h) = LUPDATE v (index h) Clist
Proof
rw[update_resize_def]
QED
Theorem every_one_arr_spec:
∀ls lsv.
(LIST_TYPE INT) ls lsv ∧
EVERY ($> (LENGTH Clist) o index) ls
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "every_one_arr" (get_ml_prog_state()))
[Carrv; lsv]
(W8ARRAY Carrv Clist)
(POSTv v.
W8ARRAY Carrv Clist *
&BOOL (EVERY (λi. any_el (index i) Clist w8z = w8o) ls) v)
Proof
Induct>>rw[]>>
xcf "every_one_arr" (get_ml_prog_state ())>>
fs[LIST_TYPE_def]
>-
(xmatch>>xcon>>xsimpl)
>>
xmatch>>
rpt xlet_autop>>
fs[eq_w8o_def]>>
xif
>-
(xapp>>xsimpl)
>>
xcon>> xsimpl
QED
Theorem delete_literals_sing_arr_spec:
∀ls lsv lno lnov.
NUM lno lnov ∧
(LIST_TYPE INT) ls lsv ∧
EVERY ($> (LENGTH Clist) o index) ls
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "delete_literals_sing_arr" (get_ml_prog_state()))
[lnov; Carrv; lsv]
(W8ARRAY Carrv Clist)
(POSTve
(λv. W8ARRAY Carrv Clist *
&unwrap_TYPE INT (delete_literals_sing_list Clist ls) v)
(λe. &(Fail_exn e ∧ delete_literals_sing_list Clist ls = NONE)))
Proof
Induct>>simp[delete_literals_sing_list_def]>>
rpt strip_tac>>
xcf "delete_literals_sing_arr" (get_ml_prog_state ())
>- (
fs[LIST_TYPE_def]>>
xmatch>>
xlit
>- (
simp[unwrap_TYPE_def]>>
xsimpl)>>
xsimpl)>>
fs[LIST_TYPE_def]>> xmatch>>
rpt xlet_autop >>
fs[eq_w8o_def]>>
IF_CASES_TAC>>fs[] >- (
xif>>instantiate>>
xapp>>xsimpl>>
metis_tac[])>>
xif>>instantiate>>
xlet_auto>>
xif
>- (
xapp>>xsimpl>>simp[unwrap_TYPE_def]>>
metis_tac[])>>
rpt xlet_autop>>
xraise>>xsimpl>>
IF_CASES_TAC>-
metis_tac[NOT_EVERY]>>
simp[unwrap_TYPE_def,Fail_exn_def]>>
metis_tac[]
QED
val is_AT_arr_aux = process_topdecs`
fun is_AT_arr_aux lno fml ls c carr =
case ls of
[] => Inr c
| (i::is) =>
case Array.lookup fml None i of
None => raise Fail (format_failure lno ("clause index unavailable: " ^ Int.toString i))
| Some ci =>
let val nl = delete_literals_sing_arr lno carr ci in
if nl = 0 then Inl c
else
(Unsafe.w8update carr (index nl) w8o;
is_AT_arr_aux lno fml is (nl::c) carr)
end` |> append_prog
(* For every literal in every clause and their negations,
the index is bounded above by n *)
Definition bounded_fml_def:
bounded_fml n fmlls ⇔
EVERY (λCopt.
case Copt of
NONE => T
| SOME C => EVERY ($> n o index) C ∧ EVERY ($> n o index o $~) C
) fmlls
End
Theorem delete_literals_sing_list_MEM:
∀C.
delete_literals_sing_list ls C = SOME x ∧ x ≠ 0
⇒
MEM (-x) C
Proof
Induct>>rw[delete_literals_sing_list_def] >> simp[] >>
CCONTR_TAC >> fs [] >> rw []
QED
Theorem is_AT_arr_aux_spec:
∀ls lsv c cv fmlv fmlls fml Carrv Clist lno lnov.
NUM lno lnov ∧
(LIST_TYPE NUM) ls lsv ∧
(LIST_TYPE INT) c cv ∧
LIST_REL (OPTION_TYPE (LIST_TYPE INT)) fmlls fmllsv ∧
bounded_fml (LENGTH Clist) fmlls
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "is_AT_arr_aux" (get_ml_prog_state()))
[lnov; fmlv; lsv; cv; Carrv]
(ARRAY fmlv fmllsv * W8ARRAY Carrv Clist)
(POSTve
(λv. ARRAY fmlv fmllsv *
(SEP_EXISTS Clist'.
W8ARRAY Carrv Clist' *
&unwrap_TYPE ($= o SND) (is_AT_list_aux fmlls ls c Clist) Clist'
) *
&unwrap_TYPE
(SUM_TYPE (LIST_TYPE INT) (LIST_TYPE INT) o FST)
(is_AT_list_aux fmlls ls c Clist) v)
(λe. ARRAY fmlv fmllsv * &(Fail_exn e ∧ is_AT_list_aux fmlls ls c Clist = NONE)))
Proof
Induct>>rw[]>>
xcf "is_AT_arr_aux" (get_ml_prog_state ())>>
simp[is_AT_list_aux_def]
>- (
fs[LIST_TYPE_def]>>
xmatch>> xcon
>- (
xsimpl>>simp[unwrap_TYPE_def]>>
simp[SUM_TYPE_def])>>
xsimpl)>>
fs[LIST_TYPE_def]>>
xmatch>>
rpt xlet_autop>>
`OPTION_TYPE (LIST_TYPE INT) (any_el h fmlls NONE) v'` by (
rw[any_el_ALT]>>
fs[LIST_REL_EL_EQN,OPTION_TYPE_def])>>
qpat_x_assum`v' = _` (assume_tac o SYM)>>
TOP_CASE_TAC>>fs[OPTION_TYPE_def]
>- (
xmatch>>
rpt(xlet_autop)>>
xraise>>xsimpl>>
simp[Fail_exn_def,unwrap_TYPE_def]>>
metis_tac[])>>
xmatch>>
xlet_auto
>- (
xsimpl>>
fs[bounded_fml_def,EVERY_EL]>>
first_x_assum(qspec_then`h` mp_tac)>>
fs[any_el_ALT])
>- (
xsimpl>>rw[]>> simp[]>>
metis_tac[])>>
fs[unwrap_TYPE_def]>>
xlet_autop>>
xif
>- (
xcon>>xsimpl>>
simp[SUM_TYPE_def])>>
rpt xlet_autop>>
`index z < LENGTH Clist ∧ WORD8 w8o w8o_v` by (
fs[w8o_v_thm]>>
fs[bounded_fml_def,EVERY_EL]>>
first_x_assum(qspec_then`h` assume_tac)>>rfs[]>>
drule delete_literals_sing_list_MEM>>fs[]>>
fs[LIST_REL_EL_EQN]>>
fs[any_el_ALT]>>
`h < LENGTH fmllsv` by fs[LIST_REL_EL_EQN]>>
fs[]>>rfs[LIST_REL_EL_EQN]>>
fs[MEM_EL]>>rw[]>>
rpt (first_x_assum drule)>>
rw[]>>
qpat_x_assum`-z = _` sym_sub_tac>>fs[])>>
rpt xlet_autop>>
xapp>>
xsimpl>>
qexists_tac`fmlls`>>qexists_tac`z::c`>>
simp[LIST_TYPE_def]>>
metis_tac[]
QED
val set_array = process_topdecs`
fun set_array carr v cs =
case cs of [] => ()
| (c::cs) =>
(Unsafe.w8update carr (index c) v;
set_array carr v cs)` |> append_prog
Theorem set_array_spec:
∀c cv Carrv Clist.
(LIST_TYPE INT) c cv ∧
WORD8 v vv ∧
EVERY ($> (LENGTH Clist) o index) c
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "set_array" (get_ml_prog_state()))
[Carrv; vv; cv]
(W8ARRAY Carrv Clist)
(POSTv uv.
W8ARRAY Carrv (set_list Clist v c))
Proof
Induct>>
rw[]>>
xcf "set_array" (get_ml_prog_state ())>>
rw[set_list_def]>>
fs[LIST_TYPE_def]
>- (xmatch>>xcon>>xsimpl)>>
xmatch>>
rpt xlet_autop>>
xapp>>
xsimpl
QED
val is_AT_arr = process_topdecs`
fun is_AT_arr lno fml ls c carr =
(set_array carr w8o c;
case is_AT_arr_aux lno fml ls c carr of
Inl c => (set_array carr w8z c; Inl ())
| Inr c => (set_array carr w8z c; Inr c))` |> append_prog
Theorem LENGTH_set_list_bound[simp]:
∀c Clist.
EVERY ($> (LENGTH Clist) ∘ index) c ⇒
LENGTH (set_list Clist v c) = LENGTH Clist
Proof
Induct>>simp[set_list_def]
QED
(* a version of this is true even if x, h are not bounded *)
Theorem update_resize_twice:
index x < LENGTH Clist ∧ index h < LENGTH Clist ⇒
update_resize (update_resize Clist w8z w8o (index x)) w8z w8o (index h) =
update_resize (update_resize Clist w8z w8o (index h)) w8z w8o (index x)
Proof
rw[update_resize_def]>>
Cases_on`x=h`>>simp[]>>
`index x ≠ index h` by metis_tac[index_11]>>
metis_tac[LUPDATE_commutes]
QED
Theorem set_list_update_resize:
∀c Clist.
index x < LENGTH Clist ∧ EVERY ($> (LENGTH Clist) ∘ index) c ⇒
set_list Clist w8o (x::c) =
update_resize (set_list Clist w8o c) w8z w8o (index x)
Proof
Induct>>rw[]>>fs[set_list_def]>>
Cases_on`x=h`>>simp[]
>-
(first_x_assum (qspec_then` LUPDATE w8o (index h) Clist` mp_tac)>>
simp[])
>>
dep_rewrite.DEP_ONCE_REWRITE_TAC[LUPDATE_commutes]>>
simp[index_11]
QED
Theorem is_AT_list_aux_length_bound:
∀ls c Clist.
bounded_fml (LENGTH Clist) fmlls ∧
EVERY ($> (LENGTH Clist) ∘ index) c ∧
is_AT_list_aux fmlls ls c (set_list Clist w8o c) = SOME(q,r) ⇒
case q of
INL d => r = set_list Clist w8o d ∧ LENGTH r = LENGTH Clist ∧ EVERY ($> (LENGTH Clist) ∘ index) d
| INR d => r = set_list Clist w8o d ∧ LENGTH r = LENGTH Clist ∧ EVERY ($> (LENGTH Clist) ∘ index) d
Proof
Induct>>rw[is_AT_list_aux_def,set_list_def]
>-
simp[]
>>
pop_assum mp_tac>>
TOP_CASE_TAC>>simp[]>>
TOP_CASE_TAC>>simp[]>>
IF_CASES_TAC>-
(rw[]>>simp[])>>
strip_tac>>
first_x_assum irule>>
drule delete_literals_sing_list_MEM>> simp[]>>
strip_tac>>
fs[bounded_fml_def,EVERY_MEM,any_el_ALT]>>
first_x_assum(qspec_then`EL h fmlls` mp_tac)>>
impl_tac>-
(`h < LENGTH fmlls` by fs[]>>
metis_tac[MEM_EL])>>
simp[]>>strip_tac>>
qexists_tac`x'::c`>>
CONJ_TAC >- (
dep_rewrite.DEP_ONCE_REWRITE_TAC[set_list_update_resize]>>
simp[EVERY_MEM]>>
pop_assum drule>>
simp[]) >>
simp[]>>
rw[]
>- (
pop_assum drule>>
simp[])>>
metis_tac[]
QED
Theorem is_AT_arr_spec:
∀ls lsv c cv fmlv fmlls Carrv Clist lno lnov.
NUM lno lnov ∧
(LIST_TYPE NUM) ls lsv ∧
(LIST_TYPE INT) c cv ∧
LIST_REL (OPTION_TYPE (LIST_TYPE INT)) fmlls fmllsv ∧
bounded_fml (LENGTH Clist) fmlls ∧
EVERY ($> (LENGTH Clist) ∘ index) c
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "is_AT_arr" (get_ml_prog_state()))
[lnov; fmlv; lsv; cv; Carrv]
(ARRAY fmlv fmllsv * W8ARRAY Carrv Clist)
(POSTve
(λv. ARRAY fmlv fmllsv *
(SEP_EXISTS Clist'.
W8ARRAY Carrv Clist' * (* TODO: actually Clist' = Clist, but not needed? *)
&(unwrap_TYPE ($= o SND) (is_AT_list fmlls ls c Clist) Clist' ∧
LENGTH Clist = LENGTH Clist')
) *
&unwrap_TYPE
(SUM_TYPE UNIT_TYPE (LIST_TYPE INT) o FST)
(is_AT_list fmlls ls c Clist) v)
(λe. ARRAY fmlv fmllsv * &(Fail_exn e ∧ is_AT_list fmlls ls c Clist = NONE)))
Proof
rw[]>>
xcf "is_AT_arr" (get_ml_prog_state ())>>
`WORD8 w8z w8z_v ∧ WORD8 w8o w8o_v` by
simp[w8z_v_thm,w8o_v_thm]>>
xlet_autop>>
xlet_auto
>- (
xsimpl>>fs[])
>- (
simp[is_AT_list_def]>>
xsimpl>>
rw[]>>simp[]>>
metis_tac[])>>
fs[unwrap_TYPE_def]>>
simp[is_AT_list_def]>>
rw[]>>fs[]>>rw[]>>
TOP_CASE_TAC>>fs[]>>
drule is_AT_list_aux_length_bound>>
rpt (disch_then drule)>>
strip_tac>>Cases_on`q`>>fs[SUM_TYPE_def]
>- (
xmatch>>
xlet_auto >- (xsimpl>>rw[]>>fs[])>>
xlet_autop>>
xcon>>xsimpl>>
simp[LENGTH_set_list_bound] )>>
xmatch>>
xlet_auto >- (xsimpl>>rw[]>>fs[])>>
xcon>>xsimpl>>
simp[LENGTH_set_list_bound]
QED
val _ = translate (check_overlap_def |> SIMP_RULE (srw_ss()) [MEMBER_INTRO] |> INST_TYPE [alpha |-> ``:int``]);
val _ = translate flip_def;
val _ = translate (delete_literals_def |> SIMP_RULE (srw_ss()) [MEMBER_INTRO]);
val _ = translate overlap_assignment_def;
val _ = translate overlap_assignment_def;
val check_RAT_arr = process_topdecs`
fun check_RAT_arr lno fml carr np c ik i ci =
(
if List.member np ci then
case Alist.lookup ik i of
None => raise Fail (format_failure lno ("clause index has no reduction sequence: " ^ Int.toString i))
| Some is =>
case is of
[] => if check_overlap ci (overlap_assignment [~np] c)
then ()
else raise Fail (format_failure lno ("clause index not satisfied but is reduced by witness: " ^ Int.toString i))
| _ =>
case is_AT_arr lno fml is (c @ delete_literals ci [np]) carr of
Inl d => ()
| _ => raise Fail (format_failure lno ("clause index not reduced to empty clause: " ^ Int.toString i))
else ())` |> append_prog
Theorem check_RAT_arr_spec:
∀i iv ci civ c cv pp ppv ik ikv fmlv fmlls fml lno lnov.
NUM lno lnov ∧
NUM i iv ∧
LIST_TYPE INT ci civ ∧
INT pp ppv ∧
(LIST_TYPE INT) c cv ∧
LIST_TYPE (PAIR_TYPE NUM (LIST_TYPE NUM)) ik ikv ∧
LIST_REL (OPTION_TYPE (LIST_TYPE INT)) fmlls fmllsv ∧
bounded_fml (LENGTH Clist) fmlls ∧
EVERY ($> (LENGTH Clist) ∘ index) c ∧
EVERY ($> (LENGTH Clist) ∘ index) ci
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "check_RAT_arr" (get_ml_prog_state()))
[lnov; fmlv; Carrv; ppv; cv; ikv ; iv ; civ]
(ARRAY fmlv fmllsv * (W8ARRAY Carrv Clist))
(POSTve
(λv. ARRAY fmlv fmllsv *
(SEP_EXISTS Clist'.
W8ARRAY Carrv Clist' *
&(check_RAT_list fmlls Clist pp c ik i ci = SOME Clist' ∧ LENGTH Clist = LENGTH Clist')
))
(λe. ARRAY fmlv fmllsv * &(Fail_exn e ∧ check_RAT_list fmlls Clist pp c ik i ci = NONE)))
Proof
simp[check_RAT_list_def]>>
rpt strip_tac>>
xcf "check_RAT_arr" (get_ml_prog_state ())>>
fs[MEMBER_INTRO]>>
xlet_autop>>
reverse xif
>- (xcon>>xsimpl) >>
xlet_autop>>
TOP_CASE_TAC >> fs[OPTION_TYPE_def]
>- (
xmatch>>
rpt (xlet_autop)>>
xraise>>xsimpl>>
simp[Fail_exn_def]>>
metis_tac[])>>
xmatch >>
TOP_CASE_TAC >> fs[LIST_TYPE_def]
>- (
xmatch>>
rpt(xlet_autop)>>
xlet `POSTv resv. &LIST_TYPE INT (overlap_assignment [-pp] c) resv * ARRAY fmlv fmllsv * W8ARRAY Carrv Clist`
>- (
xapp>>xsimpl>>
metis_tac[LIST_TYPE_def])>>
xlet_autop>>
xif >- (xcon>>xsimpl)>>
rpt(xlet_autop)>>
xraise>>xsimpl>>
simp[Fail_exn_def]>>
metis_tac[]) >>
xmatch >>
rpt xlet_autop >>
xlet `POSTv resv. &LIST_TYPE INT (delete_literals ci [pp]) resv * ARRAY fmlv fmllsv * W8ARRAY Carrv Clist`
>- (
xapp>>xsimpl>>
metis_tac[LIST_TYPE_def])>>
rpt xlet_autop>>
qmatch_goalsub_abbrev_tac`is_AT_list _ lss cc`>>
xlet`(POSTve
(λv. ARRAY fmlv fmllsv *
(SEP_EXISTS Clist'.
W8ARRAY Carrv Clist' *
&(unwrap_TYPE ($= o SND) (is_AT_list fmlls lss cc Clist) Clist' ∧
LENGTH Clist = LENGTH Clist')
) *
&unwrap_TYPE
(SUM_TYPE UNIT_TYPE (LIST_TYPE INT) o FST)
(is_AT_list fmlls lss cc Clist) v)
(λe. ARRAY fmlv fmllsv * &(Fail_exn e ∧ is_AT_list fmlls lss cc Clist = NONE)))`
>- (
xapp>>
unabbrev_all_tac>>simp[LIST_TYPE_def]>>
simp[delete_literals_def,EVERY_MEM,MEM_FILTER]>>rw[]>>
fs[EVERY_MEM]>>
metis_tac[])
>- (
xsimpl>> rw[]>>
simp[] >> metis_tac[]) >>
fs[unwrap_TYPE_def]>>
TOP_CASE_TAC>>
TOP_CASE_TAC>>fs[SUM_TYPE_def]
>- (
xmatch>>xcon>>
xsimpl>>
rw[])>>
xmatch>>
rpt (xlet_autop)>>
xraise>>xsimpl>>
simp[Fail_exn_def]>>
metis_tac[]
QED
val check_PR_arr = process_topdecs`
fun check_PR_arr lno fml carr nw c ik i ci =
if check_overlap ci nw then
case Alist.lookup ik i of
None => if check_overlap ci (flip_1 nw) then () else raise Fail (format_failure lno ("clause index has no reduction sequence but is not satisfied by witness: " ^ Int.toString i))
| Some is =>
(case is of
[] => if check_overlap ci (overlap_assignment (flip_1 nw) c) then () else raise Fail (format_failure lno ("clause index not satisfied but is reduced by witness: " ^ Int.toString i))
| _ =>
(case is_AT_arr lno fml is (c @ delete_literals ci (flip_1 (overlap_assignment (flip_1 nw) c))) carr of
Inl d => True
| _ => raise Fail (format_failure lno ("clause index not reduced to empty clause: " ^ Int.toString i))))
else True` |> append_prog
Theorem check_PR_arr_spec:
∀i iv ci civ c cv w wv ik ikv fmlv fmlls fml lno lnov.
NUM lno lnov ∧
NUM i iv ∧
LIST_TYPE INT ci civ ∧
(LIST_TYPE INT) w wv ∧
(LIST_TYPE INT) c cv ∧
LIST_TYPE (PAIR_TYPE NUM (LIST_TYPE NUM)) ik ikv ∧
LIST_REL (OPTION_TYPE (LIST_TYPE INT)) fmlls fmllsv ∧
bounded_fml (LENGTH Clist) fmlls ∧
EVERY ($> (LENGTH Clist) ∘ index) c ∧
EVERY ($> (LENGTH Clist) ∘ index) ci
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "check_PR_arr" (get_ml_prog_state()))
[lnov; fmlv; Carrv; wv; cv; ikv ; iv ; civ]
(ARRAY fmlv fmllsv * (W8ARRAY Carrv Clist))
(POSTve
(λv. ARRAY fmlv fmllsv *
(SEP_EXISTS Clist'.
W8ARRAY Carrv Clist' *
&(check_PR_list fmlls Clist w c ik i ci = SOME Clist' ∧ LENGTH Clist = LENGTH Clist')
))
(λe. ARRAY fmlv fmllsv * &(Fail_exn e ∧ check_PR_list fmlls Clist w c ik i ci = NONE)))
Proof
rw[]>>
xcf "check_PR_arr" (get_ml_prog_state ())>>
simp[check_PR_list_def]>>
xlet_autop>>
reverse xif
>- (xcon >> xsimpl)>>
xlet_autop>>
TOP_CASE_TAC>>fs[OPTION_TYPE_def]
>- (
xmatch>>
rpt xlet_autop>>
xif >- (xcon >> xsimpl)>>
xsimpl>>
rpt (xlet_autop) >>
xraise>>
xsimpl>>
simp[Fail_exn_def]>>
metis_tac[]) >>
xmatch>>
TOP_CASE_TAC>>fs[LIST_TYPE_def]>>
xmatch
>- (
rpt xlet_autop>>
xif >- (xcon>>xsimpl)>>
xsimpl >>
rpt xlet_autop>>
xraise>>
xsimpl>>
simp[Fail_exn_def]>>
metis_tac[])>>
rpt xlet_autop>>
qmatch_goalsub_abbrev_tac`is_AT_list _ lss cc`>>
xlet`(POSTve
(λv. ARRAY fmlv fmllsv *
(SEP_EXISTS Clist'.
W8ARRAY Carrv Clist' * (* TODO: actually Clist' = Clist, but not needed? *)
&(unwrap_TYPE ($= o SND) (is_AT_list fmlls lss cc Clist) Clist' ∧
LENGTH Clist = LENGTH Clist')
) *
&unwrap_TYPE
(SUM_TYPE UNIT_TYPE (LIST_TYPE INT) o FST)
(is_AT_list fmlls lss cc Clist) v)
(λe. ARRAY fmlv fmllsv * &(Fail_exn e ∧ is_AT_list fmlls lss cc Clist = NONE)))`
>- (
xapp>>
unabbrev_all_tac>>simp[LIST_TYPE_def]>>
fs[EVERY_MEM,delete_literals_def,MEM_FILTER]>>
metis_tac[])
>- (
xsimpl>> rw[]>>
simp[] >> metis_tac[]) >>
fs[unwrap_TYPE_def]>>
TOP_CASE_TAC>>
TOP_CASE_TAC>>fs[SUM_TYPE_def]
>- (
xmatch>>xcon>>
xsimpl>>
rw[]) >>
xmatch>>
rpt xlet_autop>>
xraise>>xsimpl>>
simp[Fail_exn_def]>>
metis_tac[]
QED
(*
Lift the definitions of check_{RAT|PR}_arr so they are not higher order
NOTE: The underspecification of pattern match does not matter since ls rs will always
be the same length
*)
(* val res = translate filter_reindex_def;
val res = translate filter_reindex_full_def; *)
val res = translate min_opt_def;
val list_min_opt_arr = process_topdecs`
fun list_min_opt_arr min earr ls =
case ls of [] => min
| (i::is) =>
list_min_opt_arr (min_opt min (Array.lookup earr None (index i))) earr is` |> append_prog
Theorem list_min_opt_arr_spec:
∀ls lsv earliest earliestv min minv Earrv.
(LIST_TYPE INT) ls lsv ∧
(OPTION_TYPE NUM) min minv ∧
LIST_REL (OPTION_TYPE NUM) earliest earliestv
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "list_min_opt_arr" (get_ml_prog_state()))
[minv; Earrv; lsv]
(ARRAY Earrv earliestv)
(POSTv v.
ARRAY Earrv earliestv *
&OPTION_TYPE NUM (list_min_opt min (MAP (λx. any_el (index x) earliest NONE) ls)) v)
Proof
Induct>>rw[list_min_opt_def]>>
xcf "list_min_opt_arr" (get_ml_prog_state ())>>
fs[LIST_TYPE_def]>>
xmatch
>- (xvar>> xsimpl)>>
drule LIST_REL_LENGTH>>
strip_tac>>
rpt(xlet_autop)>>
xlet_auto>>
xlet`(POSTv v. ARRAY Earrv earliestv * &OPTION_TYPE NUM (min_opt min (any_el (index h) earliest NONE)) v)`
>- (
xapp>>xsimpl>>
asm_exists_tac>>
simp[GSYM index_def]>>
fs[any_el_ALT]>>rw[]>>
fs[LIST_REL_EL_EQN]
>- (
first_x_assum(qspec_then`index h` assume_tac)>>
rfs[]>>
asm_exists_tac>>
simp[])>>
qexists_tac`NONE`>>xsimpl>>
simp[OPTION_TYPE_def])>>
xapp>>
xsimpl
QED
val res = translate REV_DEF;
val every_check_RAT_inds_arr = process_topdecs`
fun every_check_RAT_inds_arr lno fml carr np d ik mini ls acc =
case ls of [] => List.rev acc
| (i::is) =>
if i >= mini then
case Array.lookup fml None i of
None => every_check_RAT_inds_arr lno fml carr np d ik mini is acc
| Some y =>
(check_RAT_arr lno fml carr np d ik i y ;
every_check_RAT_inds_arr lno fml carr np d ik mini is (i::acc))
else
rev_1 acc (i::is)
` |> append_prog
Theorem every_check_RAT_inds_arr_spec:
∀ls lsv lno lnov pp ppv c cv ik ikv mini miniv fmlls fmllsv fmlv acc accv Carrv Clist.
NUM lno lnov ∧
LIST_TYPE NUM ls lsv ∧
INT pp ppv ∧
(LIST_TYPE INT) c cv ∧
LIST_TYPE (PAIR_TYPE NUM (LIST_TYPE NUM)) ik ikv ∧
NUM mini miniv ∧
LIST_TYPE NUM acc accv ∧
LIST_REL (OPTION_TYPE (LIST_TYPE INT)) fmlls fmllsv ∧
bounded_fml (LENGTH Clist) fmlls ∧
EVERY ($> (LENGTH Clist) ∘ index) c
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "every_check_RAT_inds_arr" (get_ml_prog_state()))
[lnov; fmlv; Carrv; ppv; cv; ikv ; miniv; lsv ; accv]
(ARRAY fmlv fmllsv * (W8ARRAY Carrv Clist))
(POSTve
(λv. ARRAY fmlv fmllsv *
(SEP_EXISTS inds' Clist'.
W8ARRAY Carrv Clist' *
&(every_check_RAT_inds_list fmlls Clist pp c ik mini ls acc = SOME (inds',Clist') ∧
LIST_TYPE NUM inds' v ∧
LENGTH Clist = LENGTH Clist')
))
(λe. ARRAY fmlv fmllsv * &(Fail_exn e ∧ every_check_RAT_inds_list fmlls Clist pp c ik mini ls acc = NONE)))
Proof
Induct>>
rw[]>>
xcf "every_check_RAT_inds_arr" (get_ml_prog_state ())>>
fs[LIST_TYPE_def,every_check_RAT_inds_list_def]>>
xmatch >- (
xapp_spec (ListProgTheory.reverse_v_thm |> INST_TYPE [alpha |-> ``:num``])>>
xsimpl>>
metis_tac[])>>
rpt xlet_autop>>
reverse xif
>- (
xlet_autop>>
xapp_spec (fetch "-" "rev_1_v_thm" |> INST_TYPE [alpha |-> ``:num``])>>
xsimpl>>simp[]>>
rpt(asm_exists_tac>>simp[])>>
qexists_tac`h::ls`>>simp[LIST_TYPE_def])>>
rpt xlet_autop>>
drule LIST_REL_LENGTH >>
strip_tac>>
`OPTION_TYPE (LIST_TYPE INT) (any_el h fmlls NONE) v'` by (
rw[any_el_ALT]>>
fs[LIST_REL_EL_EQN,OPTION_TYPE_def])>>
qpat_x_assum`v' = _` (assume_tac o SYM)>>
TOP_CASE_TAC>>fs[OPTION_TYPE_def]
>- (
xmatch>>
xapp>>
xsimpl>>
metis_tac[])>>
xmatch>>
xlet_auto >- (
xsimpl>>
fs[bounded_fml_def,EVERY_EL]>>
last_x_assum(qspec_then`h` assume_tac)>>rfs[any_el_ALT])
>- xsimpl>>
xlet_autop >>
xapp>>
xsimpl>>
qpat_x_assum`_ = LENGTH _` sym_sub_tac>>
rpt(asm_exists_tac>> simp[])>>
qexists_tac`ik`>>simp[]>>
qexists_tac`h::acc`>>
simp[LIST_TYPE_def]
QED
val every_check_PR_inds_arr = process_topdecs`
fun every_check_PR_inds_arr lno fml carr nw d ik mini ls acc =
case ls of [] => List.rev acc
| (i::is) =>
if i >= mini then
case Array.lookup fml None i of
None => every_check_PR_inds_arr lno fml carr nw d ik mini is acc
| Some y =>
(check_PR_arr lno fml carr nw d ik i y ;
every_check_PR_inds_arr lno fml carr nw d ik mini is (i::acc))
else
rev_1 acc (i::is)
` |> append_prog
Theorem every_check_PR_inds_arr_spec:
∀ls lsv lno lnov w wv c cv ik ikv mini miniv fmlls fmllsv fmlv acc accv Carrv Clist.
NUM lno lnov ∧
LIST_TYPE NUM ls lsv ∧
(LIST_TYPE INT) w wv ∧
(LIST_TYPE INT) c cv ∧
LIST_TYPE (PAIR_TYPE NUM (LIST_TYPE NUM)) ik ikv ∧
NUM mini miniv ∧
LIST_TYPE NUM acc accv ∧
LIST_REL (OPTION_TYPE (LIST_TYPE INT)) fmlls fmllsv ∧
bounded_fml (LENGTH Clist) fmlls ∧
EVERY ($> (LENGTH Clist) ∘ index) c
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "every_check_PR_inds_arr" (get_ml_prog_state()))
[lnov; fmlv; Carrv; wv; cv; ikv ; miniv; lsv ; accv]
(ARRAY fmlv fmllsv * (W8ARRAY Carrv Clist))
(POSTve
(λv. ARRAY fmlv fmllsv *
(SEP_EXISTS inds' Clist'.
W8ARRAY Carrv Clist' *
&(every_check_PR_inds_list fmlls Clist w c ik mini ls acc = SOME (inds',Clist') ∧
LIST_TYPE NUM inds' v ∧
LENGTH Clist = LENGTH Clist')
))
(λe. ARRAY fmlv fmllsv * &(Fail_exn e ∧ every_check_PR_inds_list fmlls Clist w c ik mini ls acc = NONE)))
Proof
Induct>>
rw[]>>
xcf "every_check_PR_inds_arr" (get_ml_prog_state ())>>
fs[LIST_TYPE_def,every_check_PR_inds_list_def]>>
xmatch >- (
xapp_spec (ListProgTheory.reverse_v_thm |> INST_TYPE [alpha |-> ``:num``])>>
xsimpl>>
metis_tac[])>>
rpt xlet_autop>>
reverse xif
>- (
xlet_autop>>
xapp_spec (fetch "-" "rev_1_v_thm" |> INST_TYPE [alpha |-> ``:num``])>>
xsimpl>>simp[]>>
rpt(asm_exists_tac>>simp[])>>
qexists_tac`h::ls`>>simp[LIST_TYPE_def])>>
xlet_autop>>
drule LIST_REL_LENGTH >>
strip_tac>>
xlet_autop>>
`OPTION_TYPE (LIST_TYPE INT) (any_el h fmlls NONE) v'` by (
rw[any_el_ALT]>>
fs[LIST_REL_EL_EQN,OPTION_TYPE_def])>>
qpat_x_assum`v' = _` (assume_tac o SYM)>>
TOP_CASE_TAC>>fs[OPTION_TYPE_def]
>- (
xmatch>>
xapp>>
xsimpl>>
metis_tac[])>>
xmatch>>
xlet_auto >- (
xsimpl>>
fs[bounded_fml_def,EVERY_EL]>>
last_x_assum(qspec_then`h` assume_tac)>>rfs[any_el_ALT])
>- xsimpl>>
xlet_autop >>
xapp>>
xsimpl>>
qpat_x_assum`_ = LENGTH _` sym_sub_tac>>
rpt(asm_exists_tac>> simp[])>>
qexists_tac`ik`>>simp[]>>
qexists_tac`h::acc`>>
simp[LIST_TYPE_def]
QED
val is_PR_arr = process_topdecs`
fun is_PR_arr lno fml inds carr earr p c wopt i0 ik =
case is_AT_arr lno fml i0 c carr of
(Inl d) => inds
| (Inr d) =>
if p <> 0 then
case wopt of
None =>
(let val miniopt = list_min_opt_arr None earr [~p] in
case miniopt of None => inds
| Some mini => (every_check_RAT_inds_arr lno fml carr (~p) d ik mini inds [])
end)
| Some w =>
if check_overlap w (flip_1 w) then raise Fail (format_failure lno "witness overlaps its own negation")
else
(let val miniopt = list_min_opt_arr None earr (flip_1 w) in
case miniopt of None => inds
| Some mini => (every_check_PR_inds_arr lno fml carr (flip_1 w) d ik mini inds [])
end)
else
raise Fail (format_failure lno "pivot must be non-zero")` |> append_prog
Theorem is_PR_arr_spec:
NUM lno lnov ∧
(LIST_TYPE NUM) ls lsv ∧
INT pp ppv ∧
(LIST_TYPE INT) c cv ∧
OPTION_TYPE (LIST_TYPE INT) wopt woptv ∧
(LIST_TYPE NUM) i0 i0v ∧
LIST_TYPE (PAIR_TYPE NUM (LIST_TYPE NUM)) ik ikv ∧
LIST_REL (OPTION_TYPE (LIST_TYPE INT)) fmlls fmllsv ∧
LIST_REL (OPTION_TYPE NUM) earliest earliestv ∧
bounded_fml (LENGTH Clist) fmlls ∧
EVERY ($> (LENGTH Clist) ∘ index) c
⇒
app (p : 'ffi ffi_proj)
^(fetch_v "is_PR_arr" (get_ml_prog_state()))
[lnov; fmlv; lsv ; Carrv; Earrv; ppv; cv; woptv; i0v; ikv]
(ARRAY fmlv fmllsv * W8ARRAY Carrv Clist * ARRAY Earrv earliestv)
(POSTve
(λv. ARRAY fmlv fmllsv *
ARRAY Earrv earliestv *
(SEP_EXISTS Clist'.
W8ARRAY Carrv Clist' *
&(unwrap_TYPE ($= o SND) (is_PR_list fmlls ls Clist earliest pp c wopt i0 ik) Clist' ∧
LENGTH Clist' = LENGTH Clist)
) *
&unwrap_TYPE
((LIST_TYPE NUM) o FST)
(is_PR_list fmlls ls Clist earliest pp c wopt i0 ik) v)
(λe. ARRAY fmlv fmllsv * ARRAY Earrv earliestv *
&(Fail_exn e ∧ is_PR_list fmlls ls Clist earliest pp c wopt i0 ik = NONE)))
Proof
rw[is_PR_list_def]>>
xcf "is_PR_arr" (get_ml_prog_state ())>>
xlet_autop
>- (
xsimpl>> rw[]>>simp[]>>
metis_tac[])>>
fs[unwrap_TYPE_def]>>
TOP_CASE_TAC>>
TOP_CASE_TAC>>fs[SUM_TYPE_def]
>- (
xmatch>>
xvar>>xsimpl>>
rw[])>>
xmatch>>
xlet_autop>>
reverse xif>>simp[]
>- (