ERORR IN test (testFundUpdatesFundedDataStructure) ,, FOUNDRY FUND_ME

[SrijitGyawali]

    function testFundUpdatesFundedDataStructure() public {
        vm.prank(USER);
        fundMe.fund{value: SEND_VALUE}();
        uint256 amountFunded = fundMe.getAddressToAmountFunded(USER);
        assertEq(amountFunded, SEND_VALUE);
    }

While testing this function: forge test --match-test testFundUpdatesFundedDataStructure -vvv

I m stuck in these error since three days.

[EngrPips]

Hello @SrijitGyawali, On what chain are you running your test?

[chainflash]

Send a screenshot of the fund function, it seems you made a mistake there.
Look, you wrote the exact code below :

    function fund() public payable {
        require(msg.value.getConversionRate(s_priceFeed) >= MINIMUM_USD, "You need to spend more ETH!");
        s_addressToAmountFunded[msg.sender] += msg.value;
        s_funders.push(msg.sender);
    }

[orange810-ui]

i think you should run this command first source .env
after this run this command forge test --mt testFundUpdatesFundedDataStructure --fork-url $SEPOLIA_RPC_URL

because i recently use this and i got no error i think you should run these commands

[SrijitGyawali]

[orange810-ui]

copy it and then run it source .env

[SrijitGyawali]

what to copy mate?

[EngrPips]

Run source .env and not source.env

[SrijitGyawali]

did this got same error

[EngrPips]

Show us your terminal.

[SrijitGyawali]

[EngrPips]

The image you shared is not showing for me. Please copy the process output and paste it here. Make sure to format it nicely.

[SrijitGyawali]

PS C:\Users\USER\Desktop\FOUNDRY\foundry-fund-me> source .env
source : The term 'source' is not recognized as the name of a cmdlet, function, script file, or operable program. Check the spelling of the name, or if   
a path was included, verify that the path is correct and try again.
At line:1 char:1
+ source .env
+ ~~~~~~
    + CategoryInfo          : ObjectNotFound: (source:String) [], CommandNotFoundException
    + FullyQualifiedErrorId : CommandNotFoundException

[EngrPips]

Interesting.

[orange810-ui]

1. Your .env file should have a line like : SEPOLIA_RPC_URL=https://your-sepolia-rpc-url

2. Load the environment variables : . .\.env

3. Run your forge test command : forge test --mt testFundUpdatesFundedDataStructure --fork-url $env:SEPOLIA_RPC_URL

The dot (.) is the PowerShell equivalent of source in Bash. The . (dot) operator runs the script in the current session, so the environment variables inside the .env file will be set in your current PowerShell session.

Now i think it will help you try this bro ............

[KMean]

1. Your .env file should have a line like : SEPOLIA_RPC_URL=https://your-sepolia-rpc-url
2. Load the environment variables : . .\.env
3. Run your forge test command : forge test --mt testFundUpdatesFundedDataStructure --fork-url $env:SEPOLIA_RPC_URL

The dot (.) is the PowerShell equivalent of source in Bash. The . (dot) operator runs the script in the current session, so the environment variables inside the .env file will be set in your current PowerShell session.

Now i think it will help you try this bro ............

Not too familiar with powershell but isn't this only working if the file you’re dot-sourcing is a valid PowerShell script? So in the .env he should have something like $env:SEPOLIA_RPC_URL = "https://your-sepolia-rpc-url" before calling . .\.env?

maybe I'm wrong but I think he will complicate his life a lot if he wants to keep going with windows.

[EngrPips]

Interesting.

[chainflash]

1. Your .env file should have a line like : SEPOLIA_RPC_URL=https://your-sepolia-rpc-url
2. Load the environment variables : . .\.env
3. Run your forge test command : forge test --mt testFundUpdatesFundedDataStructure --fork-url $env:SEPOLIA_RPC_URL

The dot (.) is the PowerShell equivalent of source in Bash. The . (dot) operator runs the script in the current session, so the environment variables inside the .env file will be set in your current PowerShell session.
Now i think it will help you try this bro ............

Not too familiar with powershell but isn't this only working if the file you’re dot-sourcing is a valid PowerShell script? So in the .env he should have something like $env:SEPOLIA_RPC_URL = "https://your-sepolia-rpc-url" before calling . .\.env?

maybe I'm wrong but I think he will complicate his life a lot if he wants to keep going with windows.

great

[SrijitGyawali]

i ran it in bash it throwed me the same error

[EngrPips]

@SrijitGyawali Make sure your .env file is inside the foundry-fund-me folder.

[SrijitGyawali]

[SrijitGyawali]

@EngrPips yeah folder structure is already correct

[EngrPips]

Please show the folder structure.

[KMean]

source it again if you have removed spaces. and make sure to use bash... you're still on PS

wrong

correct

open a new terminal here and use bash

[SrijitGyawali]

[SrijitGyawali]

@KMean

It worked but the test fails

[EngrPips]

You can run your test with the -vvvv flag and show us the output of your test and like that we can easily help you.

[SrijitGyawali]

[KMean]

@SrijitGyawali By the way the cahinId for sepolia is wrong in your helperConfig should be 11155111 not 111555111.

[SrijitGyawali]

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.18;

import {Test, console} from "forge-std/Test.sol";
import {FundMe} from "../../src/FundMe.sol";
import {DeployFundMe} from "../../script/DeployFundMe.s.sol";

contract FundMeTest is Test {
    FundMe fundMe;

    address USER = makeAddr("user");
    uint256 constant SEND_VALUE = 0.1 ether;
    uint256 constant STARTING_BALANCE = 10 ether;

    function setUp() external {
        // fundMe = new FundMe(0x694AA1769357215DE4FAC081bf1f309aDC325306);
        DeployFundMe deployFundMe = new DeployFundMe();
        fundMe = deployFundMe.run();
        vm.deal(USER, STARTING_BALANCE);
    }

    function testMinimumDollarIsFive() public {
        assertEq(fundMe.MINIMUM_USD(), 5e18);
    }

    function testOwnerIsMsgSender() public {
        assertEq(fundMe.i_owner(), msg.sender);
    }

    function testPriceFeedVersionIsAccurate() public {
        uint256 version = fundMe.getVersion();
        assertEq(version, 4);
    }

    function testFundFailsWithoutEnoughETH() public {
        vm.expectRevert();
        fundMe.fund();
    }


       function testFundUpdatesFundedDataStructure() public {
        vm.prank(USER);
        fundMe.fund{value: SEND_VALUE}();

        uint256 amountFunded = fundMe.getAddressToAmountFunded(msg.sender);
        assertEq(amountFunded, 10e18);
    }
}

[KMean]

have you tried changing the chainId to 11155111 in your helperConfig?

[SrijitGyawali]

yeah mate i did it

[KMean]

Can you paste your MockV3Aggregator.sol? looks like the error is coming from 0x694AA1769357215DE4FAC081bf1f309aDC325306::latestRoundData()

[SrijitGyawali]

MOCK V3 AGGREGATOR

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import {AggregatorV3Interface} from "@chainlink/contracts/src/v0.8/shared/interfaces/AggregatorV3Interface.sol";

/**
 * @title MockV3Aggregator
 * @notice Based on the FluxAggregator contract
 * @notice Use this contract when you need to test
 * other contract's ability to read data from an
 * aggregator contract, but how the aggregator got
 * its answer is unimportant
 */
contract MockV3Aggregator is AggregatorV3Interface {
    uint256 public constant version = 4;

    uint8 public decimals;
    int256 public latestAnswer;
    uint256 public latestTimestamp;
    uint256 public latestRound;

    mapping(uint256 => int256) public getAnswer;
    mapping(uint256 => uint256) public getTimestamp;
    mapping(uint256 => uint256) private getStartedAt;

    constructor(uint8 _decimals, int256 _initialAnswer) {
        decimals = _decimals;
        updateAnswer(_initialAnswer);
    }

    function updateAnswer(int256 _answer) public {
        latestAnswer = _answer;
        latestTimestamp = block.timestamp;
        latestRound++;
        getAnswer[latestRound] = _answer;
        getTimestamp[latestRound] = block.timestamp;
        getStartedAt[latestRound] = block.timestamp;
    }

    function updateRoundData(uint80 _roundId, int256 _answer, uint256 _timestamp, uint256 _startedAt) public {
        latestRound = _roundId;
        latestAnswer = _answer;
        latestTimestamp = _timestamp;
        getAnswer[latestRound] = _answer;
        getTimestamp[latestRound] = _timestamp;
        getStartedAt[latestRound] = _startedAt;
    }

    function getRoundData(uint80 _roundId)
        external
        view
        returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound)
    {
        return (_roundId, getAnswer[_roundId], getStartedAt[_roundId], getTimestamp[_roundId], _roundId);
    }

    function latestRoundData()
        external
        view
        returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound)
    {
        return (
            uint80(latestRound),
            getAnswer[latestRound],
            getStartedAt[latestRound],
            getTimestamp[latestRound],
            uint80(latestRound)
        );
    }

    function description() external pure returns (string memory) {
        return "v0.6/test/mock/MockV3Aggregator.sol";
    }
}

[KMean]

that's weird... try again last time and make sure you have 11155111 and not 111555111 (it shouldnt make a difference as you are using anvil I guess) as chainId for sepolia in your helper config. Run again forge clean and delete the cache folder. Repaste the error if any please.

As @EngrPips said I think you're messing up with the PriceFeed somewhere. It should show something like this

[81348] FundMe::fund{value: 100000000000000000}()
    │   ├─ [8993] MockV3Aggregator::latestRoundData() [staticcall]
    │   │   └─ ← [Return] 1, 200000000000 [2e11], 1, 1, 1
    │   └─ ← [Stop] 

[SrijitGyawali]

it came up with same error, i have tried multiple time same as patrick did, but it didn't work either

[KMean]

what happen if you run
forge test --fork-url $SEPOLIA_RPC_URL

[SrijitGyawali]

same issue mate

[KMean]

If you want push it to github so we can have a look. Otherwise I guess you have to start it from scratch, slowly checking all the steps (which is good practice anyways).

[KMean]

Also looking back to your messages I noticed that your .env contains an alchemy mainet rpc url for sepolia. You have to create a sepolia rpc url.

so your .env should be like

SEPOLIA_RPC_URL=https://eth-sepolia.g.alchemy.com/v2/rB0vQ12W9cOzkcIwoxcK9oeY18XPohuk

make sure to copy the correct one from alchemy

[SrijitGyawali]

i got up on alchemy , i got a different interface from the patrick one and i did it on self. I will check once.

[KMean]

i got up on alchemy , i got a different interface from the patrick one and i did it on self. I will check once.

Don't give up on that... the all point of an helper config is to setup your deployments and test for different chains. You're going to need this over and over again in the future.

[EngrPips]

Please push your code to GitHub and share the link as @KMean suggested. That is the chance we have at figuring this out, It seems like you are fundamentally screwing things up

[SrijitGyawali]

https://github.com/SrijitGyawali/FUND-ME

[SrijitGyawali]

@KMean @EngrPips acknowledge me about the mistakes mate

[KMean]

@KMean @EngrPips acknowledge me about the mistakes mate

first remove this from PriceConverter

AggregatorV3Interface priceFeed = AggregatorV3Interface(0x694AA1769357215DE4FAC081bf1f309aDC325306); //you are forcing it to sepolia

then change your assert in the test to

assertEq(amountFunded, SEND_VALUE); // where did 10e18 came from???

and

uint256 amountFunded = fundMe.getAddressToAmountFunded(msg.sender); // msg.sender is the test contract

to

uint256 amountFunded = fundMe.getAddressToAmountFunded(USER);

Now this work

forge test
[⠒] Compiling 22 files with Solc 0.8.28
[⠑] Solc 0.8.28 finished in 433.79ms
Compiler run successful with warnings:
Warning (2018): Function state mutability can be restricted to view
  --> test/FundMeTest.t.sol:23:5:
   |
23 |     function testMinimumDollarIsFive() public {
   |     ^ (Relevant source part starts here and spans across multiple lines).

Warning (2018): Function state mutability can be restricted to view
  --> test/FundMeTest.t.sol:27:5:
   |
27 |     function testOwnerIsMsgSender() public {
   |     ^ (Relevant source part starts here and spans across multiple lines).

Warning (2018): Function state mutability can be restricted to view
  --> test/FundMeTest.t.sol:31:5:
   |
31 |     function testPriceFeedVersionIsAccurate() public {
   |     ^ (Relevant source part starts here and spans across multiple lines).


Ran 5 tests for test/FundMeTest.t.sol:FundMeTest
[PASS] testFundFailsWithoutEnoughETH() (gas: 25130)
[PASS] testFundUpdatesFundedDataStructure() (gas: 103420)
[PASS] testMinimumDollarIsFive() (gas: 8818)
[PASS] testOwnerIsMsgSender() (gas: 11253)
[PASS] testPriceFeedVersionIsAccurate() (gas: 14397)
Suite result: ok. 5 passed; 0 failed; 0 skipped; finished in 905.48µs (537.42µs CPU time)

Ran 1 test suite in 6.77ms (905.48µs CPU time): 5 tests passed, 0 failed, 0 skipped (5 total tests)

If you want to remove the warnings change your functions to view
Price Converter

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.18;

import {AggregatorV3Interface} from "@chainlink/contracts/src/v0.8/shared/interfaces/AggregatorV3Interface.sol";

// Why is this a library and not abstract?
// Why not an interface?
library PriceConverter {
    // We could make this public, but then we'd have to deploy it
    function getPrice(AggregatorV3Interface priceFeed) internal view returns (uint256) {
        // Sepolia ETH / USD Address
        // https://docs.chain.link/data-feeds/price-feeds/addresses
        
        (, int256 answer,,,) = priceFeed.latestRoundData();
        // ETH/USD rate in 18 digit
        return uint256(answer * 10000000000);
    }

    // 1000000000
    function getConversionRate(uint256 ethAmount, AggregatorV3Interface priceFeed) internal view returns (uint256) {
        uint256 ethPrice = getPrice(priceFeed);
        uint256 ethAmountInUsd = (ethPrice * ethAmount) / 1000000000000000000;
        // the actual ETH/USD conversion rate, after adjusting the extra 0s.
        return ethAmountInUsd;
    }
}

FundMeTest.t.sol

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.18;

import {Test, console} from "forge-std/Test.sol";
import {FundMe} from "../../src/FundMe.sol";
import {DeployFundMe} from "../../script/DeployFundMe.s.sol";

contract FundMeTest is Test {
    FundMe fundMe;

    address USER = makeAddr("user");
    uint256 constant SEND_VALUE = 0.1 ether;
    uint256 constant STARTING_BALANCE = 10 ether;

    function setUp() external {
        // fundMe = new FundMe(0x694AA1769357215DE4FAC081bf1f309aDC325306);

        DeployFundMe deployFundMe = new DeployFundMe();
        fundMe = deployFundMe.run();
        vm.deal(USER, STARTING_BALANCE);
    }

    function testMinimumDollarIsFive() public view {
        assertEq(fundMe.MINIMUM_USD(), 5e18);
    }

    function testOwnerIsMsgSender() public view {
        assertEq(fundMe.i_owner(), msg.sender);
    }

    function testPriceFeedVersionIsAccurate() public view {
        uint256 version = fundMe.getVersion();
        assertEq(version, 4);
    }

    function testFundFailsWithoutEnoughETH() public {
        vm.expectRevert();
        fundMe.fund();
    }

    function testFundUpdatesFundedDataStructure() public {
        vm.prank(USER);
        fundMe.fund{value: SEND_VALUE}();

        uint256 amountFunded = fundMe.getAddressToAmountFunded(USER);
        assertEq(amountFunded, SEND_VALUE);
    }
}

[EngrPips]

Phenomenal heads-up.

[SrijitGyawali]

@KMean @EngrPips Thanks a lot for the help.