build.gradle

plugins {
    id 'fabric-loom' version '0.12-SNAPSHOT'
    id 'maven-publish'
    id "me.shedaniel.unified-publishing" version "0.1.+"
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
}

processResources {
    inputs.property "version", project.version
    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

java {
    withSourcesJar()
}

jar {
    from "LICENSE"
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            from(components["java"])
        }
    }
    // select the repositories you want to publish to
    repositories {
        maven {
            url(project.findProperty('maven_url'))
            credentials {
                username(project.findProperty('maven_username'))
                password(project.findProperty('maven_password'))
            }
        }
    }
}

unifiedPublishing {
    project {
        gameVersions = [minecraft_version]
        gameLoaders = ["fabric"]

        mainPublication tasks.remapJar
        //secondaryPublication tasks.remapSourcesJar

        var cfToken = project.findProperty("cf_token")
        if (cfToken != null) {
            curseforge {
                token = cfToken
                id = "820136"
            }
        }

        var mrToken = project.findProperty("mr_token")
        if (mrToken != null) {
            modrinth {
                token = mrToken
                id = "fauLGdJR"
            }
        }
    }
}