-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathSetOpEnv.cmd
166 lines (140 loc) · 4.11 KB
/
SetOpEnv.cmd
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
@ECHO OFF
REM ===========================================================
REM @file
REM
REM @brief Automatically check & obtain admin rights.
REM
REM @version 1.0
REM @author Wei Tang <[email protected]>
REM @date 2020-06-03
REM
REM @copyright Copyright (c) 2020.
REM National Key Laboratory of Science and Technology on Communications,
REM University of Electronic Science and Technology of China.
REM All rights reserved.
REM
REM @see <a href="http://stackoverflow.com/users/1016343/matt">Matt</a>
REM @see <a href="http://stackoverflow.com/questions/7044985/how-can-i-auto-elevate-my-batch-file-so-that-it-requests-from-uac-admin-rights">link</a>
REM ===========================================================
SET SCRIPT_NAME=%0
CD /D "%~dp0"
IF "%1"=="/?" (
CALL :ShowHelp
EXIT /B
)
:: Parse command-line options
SET OPNET_VCVER=17
SET OPNET_PLATFORM=x64
SET OPNET_RELEASE=14.5.A
SET OPNET_USER_HOME=
SET OPNET_GUI=
CALL :ParseOptions %*
IF %ERRORLEVEL% GEQ 1 (
EXIT /B
)
:: Set OPNET platform (intel_win32 or amd_win64)
SET OPNET_PC=intel_win32
CALL :GetPc
:: ECHO.%OPNET_VCVER%
:: ECHO.%OPNET_PLATFORM%
:: ECHO.%OPNET_RELEASE%
:: ECHO.%OPNET_USER_HOME%
:: ECHO.%OPNET_GUI%
:: ECHO.%OPNET_PC%
:: Call the external batch file
CALL SetVcEnv %OPNET_VCVER% %OPNET_PLATFORM%
:: Setup environment for other tools
:: CALL SetUserEnv.cmd %OPNET_PLATFORM%
:: Setup OPNET environment
SET ProgramFiles64=%ProgramFiles%
IF "%ProgramW6432%" NEQ "" (
SET ProgramFiles64=%ProgramW6432%
)
:: C:\Program Files\OPNET
SET OPNET_ROOT_DIR=%ProgramFiles64%\OPNET
:: C:\Program Files\OPNET\14.5.A
SET OPNET_INSTALL_DIR=%OPNET_ROOT_DIR%\%OPNET_RELEASE%
:: C:\Program Files\OPNET\14.5.A\sys
SET OPNET_SYS_DIR=%OPNET_INSTALL_DIR%\sys
:: C:\Program Files\OPNET\14.5.A\sys\pc_intel_win32
:: C:\Program Files\OPNET\14.5.A\sys\pc_amd_win64
SET OPNET_PC_DIR=%OPNET_SYS_DIR%\pc_%OPNET_PC%
:: C:\Program Files\OPNET\14.5.A\models\std
SET OPNET_MODEL_DIR=%OPNET_INSTALL_DIR%\models\std
CALL Envvar :EnvvarPathAppend "PATH" "%OPNET_PC_DIR%\bin"
CALL Envvar :EnvvarPathAppend "PATH" "%OPNET_USER_HOME%\op_models\lib"
CALL Envvar :EnvvarPathAppend "INCLUDE" "%OPNET_SYS_DIR%\include"
CALL Envvar :EnvvarPathAppend "INCLUDE" "%OPNET_MODEL_DIR%\include"
CALL Envvar :EnvvarPathAppend "INCLUDE" "%OPNET_USER_HOME%\op_models"
CALL Envvar :EnvvarPathAppend "LIB" "%OPNET_PC_DIR%\lib"
CALL Envvar :EnvvarPathAppend "LIB" "%OPNET_USER_HOME%\op_models\lib"
IF "%OPNET_GUI%"=="1" (
:: Set current driver
FOR /D %%d IN ("%OPNET_ROOT_DIR%") DO (CD /D %%~dd)
:: Start OPNET modeler
START "" "%OPNET_PC_DIR%\bin\opnet.exe" -mem_shred
)
EXIT /B
:: ============ ShowHelp Begin ============
:ShowHelp
ECHO Usage: %SCRIPT_NAME% [-option value] ...
ECHO -vc: Microsoft Visual C++ version, defaults to "17"
ECHO -p: Platform architecture, defaults to "x64"
ECHO -op: OPNET Modeler version, defaults to "14.5.A"
ECHO -home: OPNET Modeler User Home.
ECHO -gui: Launch OPNET Modeler GUI.
ECHO.
ECHO For example,
ECHO %SCRIPT_NAME% -vc 17 -p x64 -op 14.5.A -home "D:\Development\op" -gui
EXIT /B
:: ============ ShowHelp End ============
:: ============ ParseOptions Begin ============
:ParseOptions
IF "%1"=="-vc" (
IF "%2" NEQ "" (
SET "OPNET_VCVER=%~2"
)
SHIFT /1
SHIFT /1
) ELSE IF "%1"=="-p" (
IF "%2" NEQ "" (
SET "OPNET_PLATFORM=%~2"
)
SHIFT /1
SHIFT /1
) ELSE IF "%1"=="-op" (
IF "%2" NEQ "" (
SET "OPNET_RELEASE=%~2"
)
SHIFT /1
SHIFT /1
) ELSE IF "%1"=="-home" (
IF EXIST "%~2" (
SET "OPNET_USER_HOME=%~2"
) ELSE (
ECHO '-home' specifies a non-existing directory!
EXIT /B 1
)
SHIFT /1
SHIFT /1
) ELSE IF "%1"=="-gui" (
SET OPNET_GUI=1
SHIFT /1
) ELSE (
EXIT /B
)
GOTO :ParseOptions
:: ============ ParseOptions End ============
:: ============ GetPc End ============
:GetPc
IF "%OPNET_PLATFORM%"=="x64" (
SET OPNET_PC=amd_win64
) ELSE IF "%OPNET_PLATFORM%"=="amd64" (
SET OPNET_PC=amd_win64
) ELSE IF "%OPNET_PLATFORM%"=="x86_x64" (
SET OPNET_PC=amd_win64
) ELSE IF "%OPNET_PLATFORM%"=="x86_amd64" (
SET OPNET_PC=amd_win64
)
EXIT /B
:: ============ GetPc End ============