-
Notifications
You must be signed in to change notification settings - Fork 7
/
NLOCT.m
1735 lines (1343 loc) · 102 KB
/
NLOCT.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(* ::Section:: *)
(*Some printout*)
NLO$Version="1.02";
(*1.01 : fix for the tadpole*)
(*1.02 : color simplification rules added*)
Print[" - NLOCT - "];
Print["Version: "<>NLO$Version];
Print["Authors: C. Degrande"];
Print["Please cite C. Degrande, Comput.Phys.Commun. 197 (2015) 239-262"];
NLO$ngluon=0;
NLO$ncolour=0;
Off[Simplify::time];(*avoid the warning from aborded long simplification*)
(* ::Subtitle:: *)
(*Simplification rules*)
red4v::usage="replacement rules for four 4-vector with loop momentum with lorentz indices not contracted together to the squared of the scalar product
of the loop momentum times the appropriate lorentz structure and coefficient in M$dim dimensions"
red2v::usage="replacement rules for four 2-vector with loop momentum with lorentz indices not contracted together to the scalar product
of the loop momentum times the appropriate lorentz structure and coefficient in M$dim dimensions"
red4v[lm_]:={FV[lm,a_]FV[lm,b_]FV[lm,c_]FV[lm,d_]->1/(M$dim+2)/M$dim SP[lm,lm]^2(ME[a,b]ME[c,d]+ME[a,c]ME[b,d]+ME[a,d]ME[b,c]),
LCivita[lm,a_,c_,d_]FV[lm,b_]FV[lm,e_]FV[lm,f_]->1/M$dim/(M$dim+2)* SP[lm,lm]^2(LCivita[b,a,c,d]ME[e,f]+
LCivita[e,a,c,d]ME[b,f]+LCivita[f,a,c,d]ME[e,b])};
red2v[lm_]:={FV[lm,a_]FV[lm,b_]->1/M$dim* SP[lm,lm]ME[a,b],SP[lm,a_]FV[lm,b_]:>1/M$dim* FV[a,b]SP[lm,lm]/;Not[a===lm],
FCh[a__,NonCommutative[DiracSlash[lm]],b__]FV[lm,c_]:>1/M$dim* FCh[a,NonCommutative[DiracMatrix[c]],b]SP[lm,lm],
LCivita[lm,a_,c_,d_]FV[lm,b_]->1/M$dim* SP[lm,lm]LCivita[b,a,c,d]};
(* ::Subsubtitle::Closed:: *)
(*LeviCivita*)
LCivita[d___,FourMomentum[Incoming,a_],FourMomentum[Internal,b_],c___]:=-LCivita[d,FourMomentum[Internal,b],FourMomentum[Incoming,a],c];
LCivita[d___,FourMomentum[Internal,a_],FourMomentum[Internal,b_],c___]:=-LCivita[d,FourMomentum[Internal,b],FourMomentum[Incoming,a],c]/;a>b;
LCivita[d___,FourMomentum[Incoming,a_],FourMomentum[Incoming,b_],c___]:=-LCivita[d,FourMomentum[Incoming,b],FourMomentum[Incoming,a],c]/;a>b;
LCivita[c___,Index[Lorentz,d_],a_FourMomentum,b___]:=-LCivita[c,a,Index[Lorentz,d],b];
LCivita[c___,Index[Lorentz,d_],Index[Lorentz,a_],b___]:=-LCivita[c,Index[Lorentz,a],Index[Lorentz,d],b]/;d>a;
(* ::Subsubtitle::Closed:: *)
(*Metric*)
ME::usage="Metric tensor in M$dim"
Attributes[ME]=Orderless;
ME/:ME[Index[Lorentz,a_],Index[Lorentz,b_]]*ME[Index[Lorentz,a_],Index[Lorentz,c_]]:=ME[Index[Lorentz,c],Index[Lorentz,b]];
ME/:ME[Index[Lorentz,a_],Index[Lorentz,b_]]^2:=M$dim;
ME/:ME[Index[Lorentz,a_],Index[Lorentz,b_]]*f_[c___,Index[Lorentz,a_],d___]:=f[c,Index[Lorentz,b],d]/;Not[f===PolarizationVector];
ME/:ME[Index[Lorentz,a_],Index[Lorentz,b_]]*FCh[c___,NonCommutative[DiracMatrix[Index[Lorentz,a_]]],d___]:=FCh[c,NonCommutative[DiracMatrix[Index[Lorentz,b]]],d];
ME/:ME[Index[Lorentz,a_],Index[Lorentz,b_]]*ME[Index[Lorentz,a_],Index[Lorentz,b_]]:=M$dim;
ME[Index[Lorentz,a_],Index[Lorentz,a_]]:=M$dim;
(* ::Subsubtitle::Closed:: *)
(*Four vector*)
FV::usage="four vector"
FV[-a_,b_]:=-FV[a,b];
FV[a_+b_,c_]:=FV[a,c]+FV[b,c];
FV[a_?(FreeQ[#,FourMomentum]&)*b_,c_]:=a*FV[b,c];
FV/:FV[a_,b_]*FV[c_,b_]:=SP[a,c];
FV/:FV[a_,b_]^2:=SP[a,a];
(* ::Subsubtitle::Closed:: *)
(*Dirac Trace*)
DTr::usage="Trace over gamma matices"
DTr[a___,NonCommutative[DiracSlash[b__]+Mass[yy__]],c___]:=DTr[a,NonCommutative[DiracSlash[b]],c]+Mass[yy]DTr[a,c];
DTr[a___,NonCommutative[DiracSlash[b__]]+Mass[yy__],c___]:=DTr[a,NonCommutative[DiracSlash[b]],c]+Mass[yy]DTr[a,c];
DTr[a___,NonCommutative[DiracSlash[d_?(FreeQ[#,FourMomentum]&)*b__]],c___]:=d*DTr[a,NonCommutative[DiracSlash[b]],c];
DTr[a___,NonCommutative[DiracSlash[d_+b_]],c___]:=DTr[a,NonCommutative[DiracSlash[b]],c]+DTr[a,NonCommutative[DiracSlash[d]],c];
DTr[a___,Mass[yy__],c___]:=Mass[yy]DTr[a,c];
DTr[a___,NonCommutative[DiracSlash[b_]],NonCommutative[DiracSlash[b_]],c___]:=DTr[a,c]SP[b,b];
DTr[NonCommutative[DiracSlash[b_]],a___,NonCommutative[DiracSlash[b_]],NonCommutative[ChiralityProjector[pm_]]]:=DTr[a,NonCommutative[ChiralityProjector[-pm]]]SP[b,b];
DTr[a___,NonCommutative[DiracSlash[0]],c___]:=0;
DTr[a___,b_+c_,d___]:=DTr[a,b,d]+DTr[a,c,d];
DTr[a___,b_*c_?(FreeQ[#,NonCommutative]&),d___]:=c*DTr[a,b,d];
DTr[a___,b_*G[k_][l_][m__][n__],d___]:=G[k][l][m][n]*DTr[a,b,d];
(*Depth of one for the feynman parameters*)
DTr[a___,c_?((FreeQ[#,NonCommutative]&&Depth[#]<2)&),d___]:=c*DTr[a,d];
DTr[a___,NonCommutative[b_,c__],d___]:=DTr[a,NonCommutative[b],NonCommutative[c],d];
DTr[a___,NonCommutative[ChiralityProjector[pm_]],NonCommutative[b:_DiracSlash|_DiracMatrix],d___]:=DTr[a,NonCommutative[b],NonCommutative[ChiralityProjector[-pm]],d];
DTr[a___,NonCommutative[ChiralityProjector[1]],NonCommutative[ChiralityProjector[-1]],d___]:=0;
DTr[a___,NonCommutative[ChiralityProjector[-1]],NonCommutative[ChiralityProjector[1]],d___]:=0;
DTr[a___,NonCommutative[ChiralityProjector[pm_]],NonCommutative[ChiralityProjector[pm_]],d___]:=DTr[a,NonCommutative[ChiralityProjector[pm]],d];
DTr[a___,NonCommutative[DiracSlash[lm_]],NonCommutative[DiracMatrix[b_]],NonCommutative[DiracSlash[lm_]],c___]:=2FV[lm,b]*DTr[a,NonCommutative[DiracSlash[lm]],c]-
SP[lm,lm]*DTr[a,NonCommutative[DiracMatrix[b]],c];
DTr[NonCommutative[DiracSlash[lm_]],a___,NonCommutative[DiracSlash[lm_]],NonCommutative[DiracMatrix[b_]],NonCommutative[ChiralityProjector[pm_]]]:=
2FV[lm,b]*DTr[a,NonCommutative[DiracSlash[lm]],NonCommutative[ChiralityProjector[-pm]]]-SP[lm,lm]*DTr[a,NonCommutative[DiracMatrix[b]],NonCommutative[ChiralityProjector[-pm]]];
DTr[NonCommutative[a:_DiracMatrix|_DiracSlash],NonCommutative[b:_DiracMatrix|_DiracSlash],NonCommutative[c:_DiracMatrix|_DiracSlash],NonCommutative[ChiralityProjector[pm_]]]:=0;
DTr[NonCommutative[a:_DiracMatrix|_DiracSlash],NonCommutative[ChiralityProjector[pm_]]]:=0;
DTr[NonCommutative[ChiralityProjector[pm_]]]:=2;
(*Only valid in 4 dimension *)
DTr[NonCommutative[DiracMatrix[a_]],NonCommutative[DiracMatrix[b_]],NonCommutative[DiracMatrix[c_]],NonCommutative[DiracMatrix[d_]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(ME[a,b]ME[c,d]-ME[a,c]ME[b,d]+ME[a,d]ME[b,c]+ I pm*LCivita[a,b,c,d]);
DTr[NonCommutative[DiracSlash[a__]],NonCommutative[DiracMatrix[b_]],NonCommutative[DiracMatrix[c_]],NonCommutative[DiracMatrix[d_]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(FV[a,b]ME[c,d]-FV[a,c]ME[b,d]+FV[a,d]ME[b,c]+ I pm*LCivita[a,b,c,d]);
DTr[NonCommutative[DiracMatrix[a_]],NonCommutative[DiracSlash[b__]],NonCommutative[DiracMatrix[c_]],NonCommutative[DiracMatrix[d_]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(FV[b,a]ME[c,d]-ME[a,c]FV[b,d]+ME[a,d]FV[b,c]+ I pm*LCivita[a,b,c,d]);
DTr[NonCommutative[DiracMatrix[c_]],NonCommutative[DiracMatrix[d_]],NonCommutative[DiracSlash[a__]],NonCommutative[DiracMatrix[b_]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(FV[a,b]ME[c,d]-FV[a,c]ME[b,d]+FV[a,d]ME[b,c]+ I pm*LCivita[a,b,c,d]);
DTr[NonCommutative[DiracMatrix[c_]],NonCommutative[DiracMatrix[d_]],NonCommutative[DiracMatrix[a_]],NonCommutative[DiracSlash[b__]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(FV[b,a]ME[c,d]-ME[a,c]FV[b,d]+ME[a,d]FV[b,c]+ I pm*LCivita[a,b,c,d]);
DTr[NonCommutative[DiracSlash[a__]],NonCommutative[DiracSlash[b_]],NonCommutative[DiracMatrix[c_]],NonCommutative[DiracMatrix[d_]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(SP[a,b]ME[c,d]-FV[a,c]FV[b,d]+FV[a,d]FV[b,c]+ pm*I LCivita[a,b,c,d])/;FreeQ[a,Internal]||FreeQ[b,Internal];
DTr[NonCommutative[DiracMatrix[a_]],NonCommutative[DiracSlash[b__]],NonCommutative[DiracSlash[c_]],NonCommutative[DiracMatrix[d_]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(FV[b,a]FV[c,d]-FV[c,a]FV[b,d]+ME[a,d]SP[b,c]+ pm*I LCivita[a,b,c,d])/;FreeQ[c,Internal]||FreeQ[b,Internal];
DTr[NonCommutative[DiracMatrix[c_]],NonCommutative[DiracMatrix[d_]],NonCommutative[DiracSlash[a__]],NonCommutative[DiracSlash[b_]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(SP[a,b]ME[c,d]-FV[a,c]FV[b,d]+FV[a,d]FV[b,c]+ pm*I LCivita[a,b,c,d])/;FreeQ[a,Internal]||FreeQ[b,Internal];
DTr[NonCommutative[DiracSlash[c_]],NonCommutative[DiracMatrix[d_]],NonCommutative[DiracMatrix[a_]],NonCommutative[DiracSlash[b__]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(FV[b,a]FV[c,d]-FV[c,a]FV[b,d]+ME[a,d]SP[b,c]+ pm*I LCivita[a,b,c,d])/;FreeQ[c,Internal]||FreeQ[b,Internal];
DTr[NonCommutative[DiracSlash[a__]],NonCommutative[DiracMatrix[c_]],NonCommutative[DiracSlash[b_]],NonCommutative[DiracMatrix[d_]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(-SP[a,b]ME[c,d]+FV[a,c]FV[b,d]+FV[a,d]FV[b,c]- pm*I LCivita[a,b,c,d])/;FreeQ[a,Internal]||FreeQ[b,Internal];
DTr[NonCommutative[DiracMatrix[a_]],NonCommutative[DiracSlash[b__]],NonCommutative[DiracMatrix[d_]],NonCommutative[DiracSlash[c_]],NonCommutative[ChiralityProjector[pm_]]]:=
2*(FV[b,a]FV[c,d]+FV[c,a]FV[b,d]-ME[a,d]SP[b,c]- pm*I LCivita[a,b,c,d])/;FreeQ[c,Internal]||FreeQ[b,Internal];
DTr[NonCommutative[DiracMatrix[a_]],NonCommutative[DiracMatrix[b_]],NonCommutative[ChiralityProjector[pm_]]]:=2*(ME[b,a]);
DTr[NonCommutative[DiracMatrix[a_]],NonCommutative[DiracSlash[b_]],NonCommutative[ChiralityProjector[pm_]]]:=2*(FV[b,a]);
DTr[NonCommutative[DiracSlash[b_]],NonCommutative[DiracMatrix[a_]],NonCommutative[ChiralityProjector[pm_]]]:=2*(FV[b,a]);
DTr[NonCommutative[DiracSlash[a_]],NonCommutative[DiracSlash[b_]],NonCommutative[ChiralityProjector[pm_]]]:=2*SP[a,b];/;FreeQ[a,Internal]||FreeQ[b,Internal];
(* ::Subsubtitle::Closed:: *)
(*Fermion Chain*)
FV::usage="Chain with gamma matices between two spinors"
FCh[a___,NonCommutative[DiracSlash[b__]+Mass[yy__]],c___]:=FCh[a,NonCommutative[DiracSlash[b]],c]+Mass[yy]FCh[a,c];
FCh[a___,NonCommutative[DiracSlash[b__]]+Mass[yy__],c___]:=FCh[a,NonCommutative[DiracSlash[b]],c]+Mass[yy]FCh[a,c];
FCh[a___,NonCommutative[DiracSlash[b_]],NonCommutative[DiracSlash[b_]],c___]:=FCh[a,c]SP[b,b];
FCh[a___,NonCommutative[DiracMatrix[b_]],NonCommutative[DiracMatrix[b_]],c___]:=FCh[a,c]M$dim;
FCh[a___,NonCommutative[DiracSlash[d_?(FreeQ[#,FourMomentum]&)*b__]],c___]:=d*FCh[a,NonCommutative[DiracSlash[b]],c];
FCh[a___,NonCommutative[DiracSlash[d_+b_]],c___]:=FCh[a,NonCommutative[DiracSlash[b]],c]+FCh[a,NonCommutative[DiracSlash[d]],c];
FCh[a___,NonCommutative[DiracSlash[-b_]],c___]:=-FCh[a,NonCommutative[DiracSlash[b]],c];
FCh[a___,NonCommutative[DiracSlash[0]],c___]:=0;
FCh[a___,b_+c_,d___]:=FCh[a,b,d]+FCh[a,c,d];
FCh[a___,b_*c_?(FreeQ[#,NonCommutative]&),d___]:=c*FCh[a,b,d];
FCh[a___,b_*G[k_][l_][m__][n__],d___]:=G[k][l][m][n]*FCh[a,b,d];
FCh[a___,c_?((FreeQ[#,NonCommutative]&&Depth[#]<2)&),d___]:=c*FCh[a,d];
FCh[a___,NonCommutative[b_,c__],d___]:=FCh[a,NonCommutative[b],NonCommutative[c],d];
FCh[a___,NonCommutative[ChiralityProjector[pm_]],NonCommutative[b:_DiracSlash|_DiracMatrix],d___]:=FCh[a,NonCommutative[b],NonCommutative[ChiralityProjector[-pm]],d];
FCh[a___,NonCommutative[ChiralityProjector[1]],NonCommutative[ChiralityProjector[-1]],d___]:=0;
FCh[a___,NonCommutative[ChiralityProjector[-1]],NonCommutative[ChiralityProjector[1]],d___]:=0;
FCh[a___,NonCommutative[ChiralityProjector[pm_]],NonCommutative[ChiralityProjector[pm_]],d___]:=FCh[a,NonCommutative[ChiralityProjector[pm]],d];
FCh[a___,NonCommutative[DiracSlash[lm_]],NonCommutative[DiracMatrix[b_]],NonCommutative[DiracSlash[lm_]],c___]:=2FV[lm,b]*FCh[a,NonCommutative[DiracSlash[lm]],c]-
SP[lm,lm]*FCh[a,NonCommutative[DiracMatrix[b]],c];
FCh[a___,NonCommutative[DiracSlash[lm_]],NonCommutative[DiracSlash[b_]],NonCommutative[DiracSlash[lm_]],c___]:=2SP[lm,b]*FCh[a,NonCommutative[DiracSlash[lm]],c]-
SP[lm,lm]*FCh[a,NonCommutative[DiracSlash[b]],c];
FCh[a___,NonCommutative[DiracMatrix[l_]],NonCommutative[DiracMatrix[b_]],NonCommutative[DiracMatrix[l_]],c___]:=(2-M$dim)*FCh[a,NonCommutative[DiracMatrix[b]],c];
FCh[a___,NonCommutative[DiracMatrix[l_]],NonCommutative[DiracSlash[b_]],NonCommutative[DiracMatrix[l_]],c___]:=(2-M$dim)*FCh[a,NonCommutative[DiracSlash[b]],c];
(*generic case*)
FCh[a___,NonCommutative[DiracSlash[lm_]],d__,NonCommutative[DiracMatrix[b_]],NonCommutative[DiracSlash[lm_]],c___]:=2FV[lm,b]*FCh[a,NonCommutative[DiracSlash[lm]],d,c]-
FCh[a,NonCommutative[DiracSlash[lm]],d,NonCommutative[DiracSlash[lm]],NonCommutative[DiracMatrix[b]],c];
FCh[a___,NonCommutative[DiracSlash[lm_]],d__,NonCommutative[DiracSlash[b_]],NonCommutative[DiracSlash[lm_]],c___]:=2SP[lm,b]*FCh[a,NonCommutative[DiracSlash[lm]],d,c]-
FCh[a,NonCommutative[DiracSlash[lm]],d,NonCommutative[DiracSlash[lm]],NonCommutative[DiracSlash[b]],c];
FCh[a___,NonCommutative[DiracMatrix[l_]],d__,NonCommutative[DiracMatrix[b_]],NonCommutative[DiracMatrix[l_]],c___]:=2ME[b,l]*FCh[a,NonCommutative[DiracMatrix[l]],d,c]-
FCh[a,NonCommutative[DiracMatrix[l]],d,NonCommutative[DiracMatrix[l]],NonCommutative[DiracMatrix[b]],c];
FCh[a___,NonCommutative[DiracMatrix[l_]],d__,NonCommutative[DiracSlash[b_]],NonCommutative[DiracMatrix[l_]],c___]:=2FV[b,l]*FCh[a,NonCommutative[DiracMatrix[l]],d,c]-
FCh[a,NonCommutative[DiracMatrix[l]],d,NonCommutative[DiracMatrix[l]],NonCommutative[DiracSlash[b]],c];
(* ::Subsubtitle::Closed:: *)
(*ScalarProduct*)
SP::usage="scalar product"
Attributes[SP]=Orderless;
SP[-a_,b_]:=-SP[a,b];
SP[-a_,a_]:=-SP[a,a];
SP[-a_,-a_]:=SP[a,a];
SP[a_,b_+c_]:=SP[a,b]+SP[a,c];
SP[a_,b_*FourMomentum[c__]]:=b*SP[a,FourMomentum[c]];
SP[a_,b_?(FreeQ[#,FourMomentum]&)*c_]:=b*SP[a,c];
(* ::Subtitle:: *)
(*UV Tools*)
(* ::Subsubtitle:: *)
(*AddWf*)
AddWf[vert_]:=Block[{partlist,incr,a,wflist,pos},
partlist=vert[[1,All,1]]/.{V[a_,__]->V[a],F[a_,__]->F[a],S[a_,__]->S[a]}/.{-V[a_]->V[a],-S[a_]->S[a],-F[a_]->F[a]};
wflist=UV$Wftlist[[All,1]]/.{V[a_,__]->V[a],F[a_,__]->F[a],S[a_,__]->S[a]}/.{-V[a_]->V[a],-S[a_]->S[a],-F[a_]->F[a]};
pos=(If[FreeQ[wflist,#],0,Position[wflist,#][[1,1]]]&)/@partlist;
pos = DeleteCases[pos,0];
(*remove part if interaction comes from the kinetic term like VVV, VVVV, FFV, SSV, SSVV since all vector are gauge boson*)
{vert[[1]],vert[[2]],-1/2*vert[[3]]*(Total[UV$Wftlist[[pos,2]]])}
];
(* ::Subsubtitle:: *)
(*MergeVertList*)
MergeVertList[vl1_,vl2_]:=Block[{vsh,vlg,pos,verk},
vsh=If[Length[vl1]>Length[vl2],vl2,vl1];
vlg=If[Length[vl1]>Length[vl2],vl1,vl2];
For[verk=1,verk<=Length[vsh],verk++,
If[Not[FreeQ[vlg,vsh[[verk,1]]]],
pos=Position[vlg[[All,1]],vsh[[verk,1]]][[1]];
vlg[[pos,2]]=vlg[[pos,2]]+vsh[[verk,2]];
vlg[[pos,3]]=vlg[[pos,3]]+vsh[[verk,3]];,
vlg=Append[vlg,vsh[[verk]]];
];
];
vlg
];
(* ::Subsubtitle::Closed:: *)
(*Xintegrate*)
XIntegrate[num_, del_,x_]:=Block[{m1,m2,p2,c0,c1,c2,nolog,mext,withlog,tempo},
m1 = (del/.{x->1})[[1]]/FR$MU;
m2 = (del/.{x->0})[[1]]/FR$MU;
p2 = Coefficient[del,x^2]/FR$MU^2;
tempo=Expand[num];
If[Head[tempo]===Plus,
nolog = Integrate[Total[Cases[tempo,_?(FreeQ[#,Log]&)]],{x,0,1}];
withlog = Total[Cases[tempo,_?(Not[FreeQ[#,Log]]&)]]/.Log[__]->1;
,
If[FreeQ[tempo,Log],
nolog=Integrate[tempo,{x,0,1}];
withlog=0;
,
nolog=0;
withlog=tempo/.Log[__]->1;
];
];
nolog+Sum[IntxnLog[m1,m2,p2,nx]Coefficient[withlog,x,nx],{nx,0,2}]
];
IntxnLog::usage="IntxnLog[m1,m2,p2,n] is the integral over x of x^n Log[m2^2+x(m1^2-m2^2)+p2 x(x-1)], m1>=0,m2>=0,p2>=0,n=0,1 or 2. FR$Re should be set to 0 for
the on-shell scheme and to 1 for the complex mass scheme."
IntxnLog[m_/FR$MU,m_/FR$MU,m_^2/FR$MU^2,n_]:=
If[m==0,1,0]IntxnLog2[0,0,0,n]+
If[m==0,0,1]IntxnLog2[m/FR$MU,m/FR$MU,m^2/FR$MU^2,n]/;FreeQ[m,Mass];
IntxnLog[m_,m_,p2_,n_]:=
If[m==0,1,0]If[p2==0,1,0]IntxnLog2[0,0,0,n]+
If[m==0,1,0]If[p2==0,0,1]IntxnLog2[0,0,p2,n]+
If[m==0,0,1]If[p2==0,1,0]IntxnLog2[m,m,0,n]+
If[m==0,0,1]If[p2==0,0,1](If[m==p2^(1/2),0,1]IntxnLog2[m,m,p2,n]+If[m==p2^(1/2),1,0]IntxnLog2[m,m,m^2,n])/;(FreeQ[m,Mass]&&FreeQ[p2,FourMomentum]&&(Not[FreeQ[p2,FR$MU]]||p2===0));
IntxnLog[m1_/FR$MU,0,m1_^2/FR$MU^2,n_]:=
If[m1==0,1,0]IntxnLog2[0,0,0,n]+
If[m1==0,0,1](IntxnLog2[m1/FR$MU,0,m1^2/FR$MU^2,n])/;FreeQ[m1,Mass];
IntxnLog[m1_/FR$MU,m2_/FR$MU,m1_^2/FR$MU^2,n_]:=
If[m1==0,1,0]If[m2==0,1,0]IntxnLog2[0,0,0,n]+
If[m1==0,1,0]If[m2==0,0,1]IntxnLog2[0,m2/FR$MU,0,n]+
If[m1==0,0,1]If[m2==0,1,0](IntxnLog2[m1/FR$MU,0,m1^2/FR$MU^2,n])+
If[m1==0,0,1]If[m2==0,0,1](If[m1==m2,1,0]IntxnLog2[m1/FR$MU,m1/FR$MU,m1^2/FR$MU^2,n]+If[m1==m2,0,1]IntxnLog2[m1/FR$MU,m2/FR$MU,m1^2/FR$MU^2,n])/;FreeQ[m1,Mass]&&FreeQ[m2,Mass];
IntxnLog[0,m2_/FR$MU,m2_^2/FR$MU^2,n_]:=
If[m2==0,1,0]IntxnLog2[0,0,0,n]+
If[m2==0,0,1]IntxnLog2[0,m2/FR$MU,m2^2/FR$MU^2,n]/;FreeQ[m2,Mass];
IntxnLog[m1_/FR$MU,m2_/FR$MU,m2_^2/FR$MU^2,n_]:=
If[m1==0,1,0]If[m2==0,1,0]IntxnLog2[0,0,0,n]+
If[m1==0,1,0]If[m2==0,0,1]IntxnLog2[0,m2/FR$MU,m2^2/FR$MU^2,n]+
If[m1==0,0,1]If[m2==0,1,0](IntxnLog2[m1/FR$MU,0,0,n])+
If[m1==0,0,1]If[m2==0,0,1](If[m1==m2,1,0]IntxnLog2[m1/FR$MU,m1/FR$MU,m1^2/FR$MU^2,n]+If[m1==m2,0,1]IntxnLog2[m1/FR$MU,m2/FR$MU,m2^2/FR$MU^2,n])/;FreeQ[m1,Mass]&&FreeQ[m2,Mass];
IntxnLog[m1_,m2_,p2_,n_]:=
If[m1==0,1,0]If[m2==0,1,0]If[p2==0,1,0]IntxnLog2[0,0,0,n]+
If[m1==0,1,0]If[m2==0,1,0]If[p2==0,0,1]IntxnLog2[0,0,p2,n]+
If[m1==0,1,0]If[m2==0,0,1]If[p2==0,1,0]IntxnLog2[0,m2,0,n]+
If[m1==0,1,0]If[m2==0,0,1]If[p2==0,0,1](If[m2==p2^(1/2),0,1]IntxnLog2[0,m2,p2,n]+If[m2==p2^(1/2),1,0]IntxnLog2[0,m2,m2^2,n])+
If[m1==0,0,1]If[m2==0,1,0]If[p2==0,1,0]IntxnLog2[m1,0,0,n]+
If[m1==0,0,1]If[m2==0,1,0]If[p2==0,0,1](If[m1==p2^(1/2),0,1]IntxnLog2[m1,0,p2,n]+If[m1==p2^(1/2),1,0]IntxnLog2[m1,0,m1^2,n])+
If[m1==0,0,1]If[m2==0,0,1]If[p2==0,1,0](If[m1==m2,1,0]IntxnLog2[m1,m1,0,n]+If[m1==m2,0,1]IntxnLog2[m1,m2,0,n])+
If[m1==0,0,1]If[m2==0,0,1]If[p2==0,0,1]If[m1==m2,1,0](If[m1==p2^(1/2),0,1]IntxnLog2[m1,m1,p2,n]+If[m1==p2^(1/2),1,0]IntxnLog2[m1,m1,m1^2,n])+
If[m1==0,0,1]If[m2==0,0,1]If[p2==0,0,1]If[m1==m2,0,1](If[p2^(1/2)==m1,0,1]If[p2^(1/2)==m2,0,1]IntxnLog2[m1,m2,p2,n]+If[p2^(1/2)==m1,0,1]If[p2^(1/2)==m2,1,0]IntxnLog2[m1,m2,m2^2,n]+
If[p2^(1/2)==m1,1,0]If[p2^(1/2)==m2,0,1]IntxnLog2[m1,m2,m1^2,n])/;(FreeQ[m1,Mass]&&FreeQ[m2,Mass]&&FreeQ[p2,FourMomentum]&&(Not[FreeQ[p2,FR$MU]]||p2===0));
IntxnLog2[0,0,0,n_Integer]:=-2/FR$Eps*FR$IR/(n+1);
(*p2=mass^2, cannot be on the negative real axix*)
IntxnLog2[0,0,p2_,0]:=(-2 (*+ If[p2>0,0,1]*Log[-p2]*) + (*If[p2>0,1,0]*)(-I*Pi*FR$Re + Log[p2]))/;FreeQ[p2,FourMomentum];
IntxnLog2[0,0,p2_,1]:=(-2 + ((*If[p2>0,0,1]*Log[-p2] +*) (*If[p2>0,1,0]*)(-I*Pi*FR$Re + Log[p2])))/2/;FreeQ[p2,FourMomentum];
IntxnLog2[0,0,p2_,2]:=(-13 + 6*((*If[p2>0,0,1]*Log[-p2] +*) (*If[p2>0,1,0]*)(-I*Pi*FR$Re + Log[p2])))/18/;FreeQ[p2,FourMomentum];
IntxnLog2[0,m2_,0,0]:=(-1 + 2*Log[m2])/;FreeQ[m2,Mass];
IntxnLog2[0,m2_,0,1]:=(-3/4 + Log[m2])/;FreeQ[m2,Mass];
IntxnLog2[0,m2_,0,2]:=(-11/18 + (2*Log[m2])/3)/;FreeQ[m2,Mass];
IntxnLog2[m1_,0,0,0]:=(-1 + 2*Log[m1])/;FreeQ[m1,Mass];
IntxnLog2[m1_,0,0,1]:=(-1/4 + Log[m1])/;FreeQ[m1,Mass];
IntxnLog2[m1_,0,0,2]:=((-1 + 6*Log[m1])/9)/;FreeQ[m1,Mass];
IntxnLog2[m_,m_,0,0]:=Log[m^2]/;FreeQ[m,Mass];
IntxnLog2[m_,m_,0,1]:=Log[m]/;FreeQ[m,Mass];
IntxnLog2[m_,m_,0,2]:=(2*Log[m])/3/;FreeQ[m,Mass];
IntxnLog2[m_/FR$MU,0,m_^2/FR$MU^2,0]:=2*(-1 + Log[m/FR$MU])/;FreeQ[m,Mass];
IntxnLog2[m_/FR$MU,0,m_^2/FR$MU^2,1]:=(-1/2 + Log[m/FR$MU])/;FreeQ[m,Mass];
IntxnLog2[m_/FR$MU,0,m_^2/FR$MU^2,2]:=(2*(-1 + 3*Log[m/FR$MU]))/9/;FreeQ[m,Mass];
IntxnLog2[0,m_/FR$MU,m_^2/FR$MU^2,0]:=2*(-1 + Log[m/FR$MU])/;FreeQ[m,Mass];
IntxnLog2[0,m_/FR$MU,m_^2/FR$MU^2,1]:=(-3/2 + Log[m/FR$MU])/;FreeQ[m,Mass];
IntxnLog2[0,m_/FR$MU,m_^2/FR$MU^2,2]:=(-11 + 6*Log[m/FR$MU])/9/;FreeQ[m,Mass];
IntxnLog2[m1_,m2_,0,0]:=(-m1^2 + m2^2 + 2*m1^2*Log[m1] - 2*m2^2*Log[m2])/(m1^2 - m2^2)/;Not[m1===m2]&&FreeQ[m1,Mass]&&FreeQ[m2,Mass];
IntxnLog2[m1_,m2_,0,1]:=(-m1^4 + 4*m1^2*m2^2 - 3*m2^4 + 4*(m1^4 - 2*m1^2*m2^2)*Log[m1] + 4*m2^4*Log[m2])/(4*(m1^2 - m2^2)^2)/;Not[m1===m2]&&FreeQ[m1,Mass]&&FreeQ[m2,Mass];
IntxnLog2[m1_,m2_,0,2]:=(-2*m1^6 + 9*m1^4*m2^2 - 18*m1^2*m2^4 + 11*m2^6 + 12*(m1^6 - 3*m1^4*m2^2 + 3*m1^2*m2^4)*Log[m1] - 12*m2^6*Log[m2])/(18*(m1^2 - m2^2)^3)/;Not[m1===m2]&&FreeQ[m1,Mass]&&FreeQ[m2,Mass];
IntxnLog2[m1_,0,p2_,0]:=(-2*p2 + 2*m1^2*Log[m1] + (-m1^2 + p2)*(If[NLO$CMS||m1^2>p2,0,1]*(Log[-m1^2 + p2]+I Pi*FR$Re)+If[NLO$CMS||m1^2>p2,1,0]*Log[m1^2 - p2]))/p2/;FreeQ[p2,FourMomentum];
IntxnLog2[m1_,0,p2_,1]:=1/2/p2(m1^2(2Log[m1]-1)-IntxnLog2[m1,0,p2,0](m1^2-p2))/;FreeQ[m1,Mass]&&FreeQ[p2,FourMomentum];
IntxnLog2[m1_,0,p2_,2]:=((m1^2-p2/3)/2-2(m1^2-p2)IntxnLog2[m1,0,p2,1]-m1^2(1-2Log[m1]))/3/p2/;FreeQ[m1,Mass]&&FreeQ[p2,FourMomentum];
IntxnLog2[0,m2_,p2_,0]:=(-2*p2 + 2*m2^2*Log[m2] + (-m2^2 + p2)*(If[NLO$CMS||m2^2>p2,0,1]*(Log[-m2^2 + p2]+I Pi*FR$Re)+If[NLO$CMS||m2^2>p2,1,0]*Log[m2^2 - p2]))/p2/;FreeQ[p2,FourMomentum];
IntxnLog2[0,m2_,p2_,1]:=1/2/p2(-m2^2(2Log[m2]-1)-IntxnLog2[0,m2,p2,0](-m2^2-p2))/;FreeQ[m2,Mass]&&FreeQ[p2,FourMomentum];
IntxnLog2[0,m2_,p2_,2]:=((m2^2-p2/3)/2-m2^2 IntxnLog2[0,m2,p2,0]-2(-m2^2-p2)IntxnLog2[0,m2,p2,1])/3/p2/;FreeQ[m2,Mass]&&FreeQ[p2,FourMomentum];
IntxnLog2[m_/FR$MU,m_/FR$MU,m_^2/FR$MU^2,0]:=-2 + Pi/Sqrt[3] + 2*Log[m/FR$MU]/;FreeQ[m,Mass];
IntxnLog2[m_/FR$MU,m_/FR$MU,m_^2/FR$MU^2,1]:=-1 + Pi/(2*Sqrt[3]) + Log[m/FR$MU]/;FreeQ[m,Mass];
IntxnLog2[m_/FR$MU,m_/FR$MU,m_^2/FR$MU^2,2]:=-1/18 + (2*Log[m/FR$MU])/3/;FreeQ[m,Mass];
IntxnLog2[m_,m_,p2_,0]:=-2 + Log[m^2] - (Sqrt[p2*(-4*m^2 + p2)]*(If[NLO$CMS||p2<4m^2,1,0]*Log[(2*m^2 - p2 + Sqrt[p2*(-4*m^2 + p2)])/(2*m^2)]+
If[NLO$CMS||m>0&&p2<4m^2,0,1](Log[-(2*m^2 - p2 + Sqrt[p2*(-4*m^2 + p2)])/(2*m^2)]+I Pi*FR$Re)))/p2/;FreeQ[p2,FourMomentum];
IntxnLog2[m1_/FR$MU,m2_/FR$MU,m1_^2/FR$MU^2,0]:= If[NLO$CMS||m2>2m1,1,0](-2 + (-1 + m2^2/m1^2)*Log[m2/m1] + Log[(m1*m2)/FR$MU^2] - (Sqrt[-4*m1^2*m2^2 + m2^4]*
Log[(m2^2 + Sqrt[-4*m1^2*m2^2 + m2^4])/(2*m1*m2)])/m1^2)+If[NLO$CMS||m2>2m1,0,1](-2 + (-1 + m2^2/m1^2)*Log[m2/m1] + Log[(m1*m2)/FR$MU^2] - Re[(Sqrt[-4*m1^2*m2^2 + m2^4]*
Log[(m2^2 + Sqrt[-4*m1^2*m2^2 + m2^4])/(2*m1*m2)])]/m1^2)/;FreeQ[m1,Mass]&&FreeQ[m2,Mass];
IntxnLog2[m1_/FR$MU,m2_/FR$MU,m2_^2/FR$MU^2,0]:=IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,0];
IntxnLog2[m1_/FR$MU,m2_/FR$MU,m2_^2/FR$MU^2,1]:=IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,0]-IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,1];
IntxnLog2[m1_/FR$MU,m2_/FR$MU,m2_^2/FR$MU^2,2]:=IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,0]-2 IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,1]+IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,2];
IntxnLog2[m1_,m2_,p2_,0]:=-2 - ((m1^2 - m2^2)*Log[m2/m1])/p2 + Log[(m1*m2)] +
(m1*m2*(-(m1^2 + m2^2 + Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2] - p2)/(2*m1*m2) - (-m1^2 - m2^2 + Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2] + p2)/(2*m1*m2))*
(If[NLO$CMS||p2<(m1-m2)^2,1,0]Log[(m1^2 + m2^2 + Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2] - p2)/(2*m1*m2)]+
If[NLO$CMS||p2<=(m1+m2)^2,0,1](Log[-(m1^2 + m2^2 + Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2] - p2)/(2*m1*m2)]+I Pi*FR$Re)))/p2+
If[Not[NLO$CMS]&&p2>=(m1-m2)^2&&p2<(m1+m2)^2,1,0]Re[m1*m2*(-(m1^2 + m2^2 + Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2] - p2)/(2*m1*m2) -
(-m1^2 - m2^2 + Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2] + p2)/(2*m1*m2))*Log[(m1^2 + m2^2 + Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2] - p2)/(2*m1*m2)]]/p2/;FreeQ[m1,Mass]&&FreeQ[m2,Mass]&&FreeQ[p2,FourMomentum];
IntxnLog2[m1_,m2_,p2_,1]:=1/2/p2(-m2^2(2Log[m2]-1)+m1^2(2Log[m1]-1)-IntxnLog2[m1,m2,p2,0](-m2^2+m1^2-p2))/;FreeQ[m1,Mass]&&FreeQ[m2,Mass]&&
FreeQ[p2,FourMomentum];
IntxnLog2[m1_,m2_,p2_,2]:=((m1^2+m2^2-p2/3)/2-m2^2 IntxnLog2[m1,m2,p2,0]-2(-m2^2+m1^2-p2)IntxnLog2[m1,m2,p2,1]-m1^2(1-2Log[m1]))/3/p2/;
FreeQ[m1,Mass]&&FreeQ[m2,Mass]&&FreeQ[p2,FourMomentum];
UVLog[0]:=0;(*from the tadpole from x Log[x], x->0*)
UVLog[x_?(Not[Head[#]===Mass]&)^2/FR$MU^2]:=Log[x^2/FR$MU^2];
(* ::Subsubtitle::Closed:: *)
(*Dp2IntxnLog*)
Dp2IntxnLog::usage="Dp2IntxnLog[m1,m2,p2,n] is the derivative with respect to p2 of the real part of the integral over x of x^n Log[m2^2+x(m1^2-m2^2)+p2x(x-1)],
m1>=0,m2>=0,p2>=0,n=0,1 or 2"
(*warning d=4+eps almost until the end*)
Dp2IntxnLog[m_/FR$MU,m_/FR$MU,m_^2/FR$MU^2,n_]:=
If[m==0,1,0]Dp2IntxnLog2[0,0,0,n]+
If[m==0,0,1]Dp2IntxnLog2[m/FR$MU,m/FR$MU,m^2/FR$MU^2,n]/;FreeQ[m,Mass];
Dp2IntxnLog[m_,m_,p2_,n_]:=
If[m==0,1,0]If[p2==0,1,0]Dp2IntxnLog2[0,0,0,n]+
If[m==0,1,0]If[p2==0,0,1]Dp2IntxnLog2[0,0,p2,n]+
If[m==0,0,1]If[p2==0,1,0]Dp2IntxnLog2[m,m,0,n]+
If[m==0,0,1]If[p2==0,0,1](If[m==p2^(1/2),0,1]Dp2IntxnLog2[m,m,p2,n]+If[m==p2^(1/2),1,0]Dp2IntxnLog2[m,m,m^2,n])/;FreeQ[m,Mass]&&FreeQ[p2,FourMomentum];
Dp2IntxnLog[m1_/FR$MU,0,m1_^2/FR$MU^2,n_]:=
If[m1==0,1,0]Dp2IntxnLog2[0,0,0,n]+
If[m1==0,0,1](Dp2IntxnLog2[m1/FR$MU,0,m1^2/FR$MU^2,n])/;FreeQ[m1,Mass];
Dp2IntxnLog[m1_/FR$MU,m2_/FR$MU,m1_^2/FR$MU^2,n_]:=
If[m1==0,1,0]If[m2==0,1,0]Dp2IntxnLog2[0,0,0,n]+
If[m1==0,1,0]If[m2==0,0,1]Dp2IntxnLog2[0,m2/FR$MU,0,n]+
If[m1==0,0,1]If[m2==0,1,0](Dp2IntxnLog2[m1/FR$MU,0,m1^2/FR$MU^2,n])+
If[m1==0,0,1]If[m2==0,0,1](If[m1==m2,1,0]Dp2IntxnLog2[m1/FR$MU,m1/FR$MU,m1^2/FR$MU^2,n]+If[m1==m2,0,1]Dp2IntxnLog2[m1/FR$MU,m2/FR$MU,m1^2/FR$MU^2,n])/;FreeQ[m1,Mass]&&FreeQ[m2,Mass];
Dp2IntxnLog[0,m2_/FR$MU,m2_^2/FR$MU^2,n_]:=
If[m2==0,1,0]Dp2IntxnLog2[0,0,0,n]+
If[m2==0,0,1]Dp2IntxnLog2[0,m2/FR$MU,m2^2/FR$MU^2,n]/;FreeQ[m2,Mass];
Dp2IntxnLog[m1_/FR$MU,m2_/FR$MU,m2_^2/FR$MU^2,n_]:=
If[m1==0,1,0]If[m2==0,1,0]Dp2IntxnLog2[0,0,0,n]+
If[m1==0,1,0]If[m2==0,0,1]Dp2IntxnLog2[0,m2/FR$MU,m2^2/FR$MU^2,n]+
If[m1==0,0,1]If[m2==0,1,0](Dp2IntxnLog2[m1/FR$MU,0,0,n])+
If[m1==0,0,1]If[m2==0,0,1](If[m1==m2,1,0]Dp2IntxnLog2[m1/FR$MU,m1/FR$MU,m1^2/FR$MU^2,n]+If[m1==m2,0,1]Dp2IntxnLog2[m1/FR$MU,m2/FR$MU,m2^2/FR$MU^2,n])/;FreeQ[m1,Mass]&&FreeQ[m2,Mass];
Dp2IntxnLog[m1_,m2_,p2_,n_]:=
If[m1==0,1,0]If[m2==0,1,0]If[p2==0,1,0]Dp2IntxnLog2[0,0,0,n]+
If[m1==0,1,0]If[m2==0,1,0]If[p2==0,0,1]Dp2IntxnLog2[0,0,p2,n]+
If[m1==0,1,0]If[m2==0,0,1]If[p2==0,1,0]Dp2IntxnLog2[0,m2,0,n]+
If[m1==0,1,0]If[m2==0,0,1]If[p2==0,0,1](If[m2==p2^(1/2),0,1]Dp2IntxnLog2[0,m2,p2,n]+If[m2==p2^(1/2),1,0]Dp2IntxnLog2[0,m2,m2^2,n])+
If[m1==0,0,1]If[m2==0,1,0]If[p2==0,1,0]Dp2IntxnLog2[m1,0,0,n]+
If[m1==0,0,1]If[m2==0,1,0]If[p2==0,0,1](If[m1==p2^(1/2),0,1]Dp2IntxnLog2[m1,0,p2,n]+If[m1==p2^(1/2),1,0]Dp2IntxnLog2[m1,0,m1^2,n])+
If[m1==0,0,1]If[m2==0,0,1]If[p2==0,1,0](If[m1==m2,1,0]Dp2IntxnLog2[m1,m1,0,n]+If[m1==m2,0,1]Dp2IntxnLog2[m1,m2,0,n])+
If[m1==0,0,1]If[m2==0,0,1]If[p2==0,0,1]If[m1==m2,1,0](If[m1==p2^(1/2),0,1]Dp2IntxnLog2[m1,m1,p2,n]+If[m1==p2^(1/2),1,0]Dp2IntxnLog2[m1,m1,m1^2,n])+
If[m1==0,0,1]If[m2==0,0,1]If[p2==0,0,1]If[m1==m2,0,1](If[p2^(1/2)==m1,0,1]If[p2^(1/2)==m2,0,1]Dp2IntxnLog2[m1,m2,p2,n]+If[p2^(1/2)==m1,0,1]If[p2^(1/2)==m2,1,0]Dp2IntxnLog2[m1,m2,m2^2,n]+
If[p2^(1/2)==m1,1,0]If[p2^(1/2)==m2,0,1]Dp2IntxnLog2[m1,m2,m1^2,n])/;FreeQ[m1,Mass]&&FreeQ[m2,Mass]&&FreeQ[p2,FourMomentum];
Dp2IntxnLog2[0,0,0,n_]:=0*FR$testdp2000;
Dp2IntxnLog2[m_,0,0,n_Integer]:=-1/m^2/(n+2)/(n+1)/;FreeQ[m,Mass]&&n>=0;
Dp2IntxnLog2[0,m_,0,n_Integer]:=-1/m^2/(n+2)/;FreeQ[m,Mass]&&n>=0;
Dp2IntxnLog2[0,0,p2_,0]:=1/p2/;FreeQ[p2,FourMomentum];
Dp2IntxnLog2[0,0,p2_,1]:=1/2/p2/;FreeQ[p2,FourMomentum];
Dp2IntxnLog2[0,0,p2_,2]:=1/3/p2/;FreeQ[p2,FourMomentum];
Dp2IntxnLog2[m1_/FR$MU,0,m1_^2/FR$MU^2,0]:=-1(1/FR$Eps*FR$IR/m1^2+(-1+Log[m1/FR$MU])/m1^2)FR$MU^2/;FreeQ[m1,Mass];(*Infared divergent*)
Dp2IntxnLog2[m1_/FR$MU,0,m1_^2/FR$MU^2,1]:=-1/2/m1^2*FR$MU^2/;FreeQ[m1,Mass];
Dp2IntxnLog2[m1_/FR$MU,0,m1_^2/FR$MU^2,2]:=-1/m1^2/6*FR$MU^2/;FreeQ[m1,Mass];
Dp2IntxnLog2[0,m2_/FR$MU,m2_^2/FR$MU^2,0]:=-(1/FR$Eps*FR$IR/m2^2+(-1+Log[m2/FR$MU])/m2^2)*FR$MU^2/;FreeQ[m2,Mass];
Dp2IntxnLog2[0,m2_/FR$MU,m2_^2/FR$MU^2,1]:=-(1/FR$Eps*FR$IR/m2^2+(-3/2+Log[m2/FR$MU])/m2^2)*FR$MU^2/;FreeQ[m2,Mass];
Dp2IntxnLog2[0,m2_/FR$MU,m2_^2/FR$MU^2,2]:=-(1/FR$Eps*FR$IR/m2^2+(-11/6+Log[m2/FR$MU])/m2^2)*FR$MU^2/;FreeQ[m2,Mass];
Dp2IntxnLog2[m1_,0,p2_,0]:=(p2 - 2*m1^2*Log[m1] + m1^2*(If[NLO$CMS||m1^2>p2,0,1]*(Log[-m1^2 + p2]+I Pi*FR$Re)+If[NLO$CMS||m1^2>p2,1,0]*Log[m1^2 - p2]))/p2^2/;FreeQ[p2,FourMomentum];
Dp2IntxnLog2[m1_,0,p2_,1]:=-IntxnLog[m1,0,p2,1]/p2+(IntxnLog[m1,0,p2,0]-(m1^2-p2)Dp2IntxnLog2[m1,0,p2,0])/2/p2/;FreeQ[m1,Mass]&&
FreeQ[p2,FourMomentum];
Dp2IntxnLog2[m1_,0,p2_,2]:=-IntxnLog[m1,0,p2,2]/p2+(-1/6+2IntxnLog[m1,0,p2,1]-2(m1^2-p2)Dp2IntxnLog2[m1,0,p2,1])/3/p2/;
FreeQ[m1,Mass]&&FreeQ[p2,FourMomentum];
Dp2IntxnLog2[0,m2_,p2_,0]:=Dp2IntxnLog2[m2,0,p2,0]/;FreeQ[p2,FourMomentum];
Dp2IntxnLog2[0,m2_,p2_,1]:=- IntxnLog[0,m2,p2,1]/p2+(IntxnLog[0,m2,p2,0]-(-m2^2-p2)Dp2IntxnLog2[0,m2,p2,0])/2/p2/;FreeQ[m2,Mass]&&
FreeQ[p2,FourMomentum];
Dp2IntxnLog2[0,m2_,p2_,2]:=-IntxnLog[0,m2,p2,2]/p2+(-1/6-m2^2 Dp2IntxnLog2[0,m2,p2,0]+2IntxnLog[0,m2,p2,1]-2(-m2^2-p2)Dp2IntxnLog2[0,m2,p2,1])/3/p2/;
FreeQ[m2,Mass]&&FreeQ[p2,FourMomentum];
Dp2IntxnLog2[m_/FR$MU,m_/FR$MU,0,n_Integer]:=-1/m^2*FR$MU^2/(n+2)/(n+3)/;FreeQ[m,Mass];
Dp2IntxnLog2[m_/FR$MU,m_/FR$MU,m_^2/FR$MU^2,0]:=(9 - 2*Sqrt[3]*Pi)/(9*m^2)*FR$MU^2/;FreeQ[m,Mass];
Dp2IntxnLog2[m_/FR$MU,m_/FR$MU,m_^2/FR$MU^2,1]:=(9 - 2*Sqrt[3]*Pi)/(18*m^2)*FR$MU^2/;FreeQ[m,Mass];
Dp2IntxnLog2[m_/FR$MU,m_/FR$MU,m_^2/FR$MU^2,2]:=(-6 + Sqrt[3]*Pi)/(9*m^2)*FR$MU^2/;FreeQ[m,Mass];
Dp2IntxnLog2[m1_,m2_,0,0]:=(-m1^4 + m2^4 + 4*m1^2*m2^2*Log[m1/m2])/(2*(m1^2 - m2^2)^3)/;Not[m1===m2]&&FreeQ[m1,Mass]&&FreeQ[m2,Mass];
Dp2IntxnLog2[m1_,m2_,0,1]:=-(m1^6 - 6*m1^4*m2^2 + 3*m1^2*m2^4 + 2*m2^6 - 12*m1^2*m2^4*Log[m2/m1])/(6*(m1^2 - m2^2)^4)/;Not[m1===m2]&&FreeQ[m1,Mass]&&FreeQ[m2,Mass];
Dp2IntxnLog2[m1_,m2_,0,2]:=(-m1^8 + 6*m1^6*m2^2 - 18*m1^4*m2^4 + 10*m1^2*m2^6 + 3*m2^8 + 24*m1^2*m2^6*Log[m1/m2])/(12*(m1^2 - m2^2)^5)/;Not[m1===m2]&&FreeQ[m1,Mass]&&FreeQ[m2,Mass];
Dp2IntxnLog2[m_,m_,p2_,0]:=(Sqrt[p2*(-4*m^2 + p2)] - 2*m^2*(
If[NLO$CMS||p2<4m^2,1,0]*Log[(2*m^2 - p2 + Sqrt[p2*(-4*m^2 + p2)])/(2*m^2)]+
If[NLO$CMS||p2<=4m^2,0,1](Log[-(2*m^2 - p2 + Sqrt[p2*(-4*m^2 + p2)])/(2*m^2)]+I Pi*FR$Re))+
If[p2==4m^2,1,0]*Sqrt[p2*(-4*m^2 + p2)] )/(p2*Sqrt[p2*(-4*m^2 + p2)])/;FreeQ[p2,FourMomentum];
Dp2IntxnLog2[m1_/FR$MU,m2_/FR$MU,m1_^2/FR$MU^2,0]:= If[NLO$CMS||m2>2m1,1,0]*(FR$MU^2*((m1^2*Sqrt[-4*m1^2*m2^2 + m2^4] + (m1^2 - m2^2)*Sqrt[-4*m1^2*m2^2 + m2^4]*Log[m2/m1] +
(-3*m1^2*m2^2 + m2^4)*Log[(m2^2 + Sqrt[-4*m1^2*m2^2 + m2^4])/(2*m1*m2)])/(m1^4*Sqrt[-4*m1^2*m2^2 + m2^4])))+If[NLO$CMS||m2>2m1,0,1]*Re[(FR$MU^2*((m1^2*Sqrt[-4*m1^2*m2^2 + m2^4] + (m1^2 - m2^2)*Sqrt[-4*m1^2*m2^2 + m2^4]*Log[m2/m1] +
(-3*m1^2*m2^2 + m2^4)*Log[(m2^2 + Sqrt[-4*m1^2*m2^2 + m2^4])/(2*m1*m2)])/(m1^4*Sqrt[-4*m1^2*m2^2 + m2^4])))]/;FreeQ[m1,Mass]&&FreeQ[m2,Mass];
Dp2IntxnLog2[m1_/FR$MU,m2_/FR$MU,m2_^2/FR$MU^2,0]:=Dp2IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,0];
Dp2IntxnLog2[m1_/FR$MU,m2_/FR$MU,m2_^2/FR$MU^2,1]:=Dp2IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,0]-Dp2IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,1];
Dp2IntxnLog2[m1_/FR$MU,m2_/FR$MU,m2_^2/FR$MU^2,2]:=Dp2IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,0]-2 Dp2IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,1]+Dp2IntxnLog2[m2/FR$MU,m1/FR$MU,m2^2/FR$MU^2,2];
Dp2IntxnLog2[m1_,m2_,p2_,0]:=((If[Not[NLO$CMS]&&p2>(m1-m2)^2&&p2<(m1+m2)^2,0,1]*p2*Sqrt[m1^4 + (-m2^2 + p2)^2 - 2*m1^2*(m2^2 + p2)] +
If[Not[NLO$CMS]&&p2>(m1-m2)^2&&p2<(m1+m2)^2,0,1]*(m1^2 - m2^2)*Sqrt[m1^4 + (-m2^2 + p2)^2 - 2*m1^2*(m2^2 + p2)]*Log[m2/m1] +
(m1^4 + m2^2*(m2^2 - p2) - m1^2*(2*m2^2 + p2))*
(If[NLO$CMS||p2<(m1-m2)^2,1,0]Log[(m1^2 + m2^2 + Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2] - p2)/(2*m1*m2)]+
If[NLO$CMS||p2<(m1-m2)^2||p2<(m1+m2)^2,0,1](Log[-(m1^2 + m2^2 + Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2] - p2)/(2*m1*m2)]+I Pi FR$Re)))/
(Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2]*p2^2))+ If[Not[NLO$CMS]&&p2>(m1-m2)^2&&p2<(m1+m2)^2,1,0]*
Re[((p2*Sqrt[m1^4 + (-m2^2 + p2)^2 - 2*m1^2*(m2^2 + p2)] + (m1^2 - m2^2)*Sqrt[m1^4 + (-m2^2 + p2)^2 - 2*m1^2*(m2^2 + p2)]*Log[m2/m1] +
(m1^4 + m2^2*(m2^2 - p2) - m1^2*(2*m2^2 + p2))*Log[(m1^2 + m2^2 + Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2] - p2)/(2*m1*m2)]))/
(Sqrt[-4*m1^2*m2^2 + (m1^2 + m2^2 - p2)^2]*p2^2)]/;Not[m1^2===p2]&&Not[m2^2===p2]&&FreeQ[m1,Mass]&&FreeQ[m2,Mass]&&FreeQ[p2,FourMomentum];
Dp2IntxnLog2[m1_,m2_,p2_,1]:=(- IntxnLog2[m1,m2,p2,1]/p2+(IntxnLog2[m1,m2,p2,0]-(m1^2-m2^2-p2)Dp2IntxnLog2[m1,m2,p2,0])/2/p2)/;FreeQ[m1,Mass]&&FreeQ[m2,Mass]&&
FreeQ[p2,FourMomentum];
Dp2IntxnLog2[m1_,m2_,p2_,2]:=-IntxnLog2[m1,m2,p2,2]/p2+(-1/6-m2^2 Dp2IntxnLog2[m1,m2,p2,0]+2IntxnLog2[m1,m2,p2,1]-2(m1^2-m2^2-p2)Dp2IntxnLog2[m1,m2,p2,1])/3/p2/;
FreeQ[m1,Mass]&&FreeQ[m2,Mass]&&FreeQ[p2,FourMomentum];
(* ::Subsubtitle:: *)
(*SolveDelta*)
(*Remove dZ that do not correspond to the vertex*)
RemovedZ[vtx_]:=Block[{dZtmp,dZrule},
dZtmp=DeleteCases[(vtx[[1,All,1]]/.-x_->x),Index[Colour|Gluon,_],\[Infinity]]/.x_[a_,{}]->x[a]/.(FR$ClassesTranslation/.Rule->dZrule/.dZrule[a_,b_]:>Rule[b,a]);
dZtmp=Cases[Union[Cases[vtx,_FR$deltaZ,\[Infinity]]],_?(FreeQ[#,dZtmp[[1]]]||FreeQ[#,dZtmp[[2]]]&)];
If[Length[dZtmp]>0,
Print[Style["Warning : The following deltaZ are going to be put to zero in the "<>ToString[vtx[[1,All,1]]]<>" vertex",Orange]];
Print[dZtmp];];
vtx/.((Rule[#,0]&)/@dZtmp)
];
(*Consecutive solving*)
ConsSolve[eq_,var_]:=Block[{cssol={},cstmpeq,cstmpsol,csincr,csekk,csvar,totvar},
totvar=var;
For[csekk=1,csekk<=Length[var],csekk++,
If[Not[FreeQ[ eq, Conjugate[ var[[csekk]] ] ]](*not*),
totvar=Append[totvar,Conjugate[var[[csekk]] ] ];(*append*)
];(*if*)
];(*for*)
For[csekk=1,csekk<=Length[eq],csekk++,
cstmpeq=Expand[eq[[csekk]]/.cssol];
cstmpsol={};csincr=1;
If[Not[cstmpeq===0],
While[Length[cstmpsol]<1&&csincr<=Length[Intersection[Cases[cstmpeq,_FR$delta|_FR$deltaZ,{0,\[Infinity]}],var]],
csvar = Intersection[Cases[cstmpeq,_FR$delta|_FR$deltaZ,{0,\[Infinity]}],totvar][[csincr]];
If[Simplify[Coefficient[cstmpeq,csvar,1],TimeConstraint->0.1]=!=0,
cstmpsol=csvar->Expand[-Coefficient[cstmpeq,csvar,0]/
Simplify[Coefficient[cstmpeq,csvar,1],TimeConstraint->0.1]];
];
csincr++;
];
If[Length[cstmpsol]>0,cssol=Append[cssol/.cstmpsol,cstmpsol];]
];
];
cssol
];
(*vertex list ordering*)
Ordered2VertQ[v1_,v2_]:=Block[{vert1,vert2},
vert1=Sort[(v1[[1]]/.-x_->x)[[All,1,1]]];
vert2=Sort[(v2[[1]]/.-x_->x)[[All,1,1]]];
If[vert1[[1]]<vert2[[1]],True,If[vert1[[1]]==vert2[[1]],vert1[[2]]<vert2[[2]],False]]];
(*check color conservation for 2 point*)
ColCons2Pt[arg_]:=If[Not[FreeQ[arg,Index[Colour,Ext[_]]]&&FreeQ[arg,Index[Gluon,Ext[_]]]],
Print[Style["Error : two point function not propotional to a delta for external SU(3) indices",Red]];Abort[]];
SolveDelta[vertCT_,vertUV_,verttype_,assumlist_,complex_]:=Module[{fullUV,fl,fr,fsr,fsl,kuv,eqlist,deq,varlist,realvar,res,tRule,Cond,extra, su3rep,interres,
EpsSerie},
su3rep = {IndexDel[Index[Colour, Ext[1]], Index[Colour, Ext[2]]]->1,IndexDel[Index[Gluon, Ext[1]], Index[Gluon, Ext[2]]]->1};
para=False;
(*Cond avoid the replacement of if by piecewice or so*)
EpsSerie[arg_] := Block[{EStmp,ESkk,ESres,ESexp},
ESexp=Expand[arg];
If[Head[ESexp]=!=Plus,ESexp={ESexp};];
If[para,
ESres=Table[EStmp=ESexp[[ESkk]];
ParallelSubmit[{ESkk,EStmp},Normal[Series[(((EStmp/.If->Cond)/.Cond[test_,ca_,cb_]:>Cond[Simplify[(test/.Sqrt[x_^2/FR$MU^2]->x/FR$MU),
Assumptions->Join[{FR$MU>0,FR$IR>0,FR$Eps>0},assumlist], TimeConstraint->1],ca,cb])/.
{Cond[True,ca_,cb_]->ca,Cond[False,ca_,cb_]->cb}),{FR$Eps,0,0}]]],{ESkk,Length[ESexp]}];
Plus@@(WaitAll[ESres])
,
ESres=(Normal[Series[(((#/.If->Cond)/.Cond[test_,ca_,cb_]:>Cond[Simplify[(test/.Sqrt[x_^2/FR$MU^2]->x/FR$MU),
Assumptions->Join[{FR$MU>0,FR$IR>0,FR$Eps>0},assumlist], TimeConstraint->1]/.Sqrt[x_^2]->x,ca,cb])/.
{Cond[True,ca_,cb_]->ca,Cond[False,ca_,cb_]->cb}),{FR$Eps,0,0}]]&)/@ESexp;
If[Head[ESres]=!=Plus,ESres=Plus@@ESres;];
ESres
]];
fullUV=MergeVertList[RemovedZ/@vertCT,vertUV][[All,{1,3}]];
(*remove p1 using momentum conservation*)
fullUV=fullUV/.{TensDot[a___,SlashedP[FourMomentum[1]], b___][Index[Spin, Ext[1]], Index[Spin, Ext[2]]]->
-TensDot[a,SlashedP[FourMomentum[2]], b][Index[Spin, Ext[1]], Index[Spin, Ext[2]]]};
fullUV=fullUV/.{FourMomentum[1]->-FourMomentum[2]};
fullUV=Sort[fullUV,Ordered2VertQ];
res={};
For[kuv=1,kuv<=Length[fullUV]-0,kuv++,
(*Print[ToString[kuv]<>" is "<>ToString[fullUV[[kuv,1]]]<>" at "<>ToString[SessionTime[]]];Print[fullUV[[kuv,2]]];*)
If[kuv==1||Not[Sort[(fullUV[[kuv,1]]/.-x_->x)[[All,1,1]]]===Sort[(fullUV[[kuv-1,1]]/.-x_->x)[[All,1,1]]]],eqlist={};];
Switch[verttype,
{F,F},
(*fermions*)
fl=Coefficient[fullUV[[kuv,2]],TensDot[SlashedP[FourMomentum[2]], ProjM][Index[Spin, Ext[1]], Index[Spin, Ext[2]]]];
fr=Coefficient[fullUV[[kuv,2]],TensDot[SlashedP[FourMomentum[2]], ProjP][Index[Spin, Ext[1]], Index[Spin, Ext[2]]]];
fsl=Coefficient[fullUV[[kuv,2]],ProjM[Index[Spin, Ext[1]], Index[Spin, Ext[2]]]];
fsr=Coefficient[fullUV[[kuv,2]],ProjP[Index[Spin, Ext[1]], Index[Spin, Ext[2]]]];
(*check a piori on the form of the vertex*)
On[Simplify::time];
If[Not[Simplify[fullUV[[kuv,2]]-fl*TensDot[SlashedP[FourMomentum[2]], ProjM][Index[Spin, Ext[1]], Index[Spin, Ext[2]]]-
fr*TensDot[SlashedP[FourMomentum[2]], ProjP][Index[Spin, Ext[1]], Index[Spin, Ext[2]]]-
fsl ProjM[Index[Spin, Ext[1]], Index[Spin, Ext[2]]]- fsr ProjP[Index[Spin, Ext[1]], Index[Spin, Ext[2]]],TimeConstraint->0.2]===0],
Print["warning: FF vertex does not seem match expected form, further simplification may be needed"]];
Off[Simplify::time];
interres = If[TheMass[fullUV[[kuv,1,1,1]]]===0&&TheMass[fullUV[[kuv,1,2,1]]]===0,fl,fl*TheMass[fullUV[[kuv,1,2,1]]]+fsr]/.su3rep;
ColCons2pt[interres];
interres = EpsSerie[interres/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,2,1]]]^2];
eqlist=Append[eqlist,interres];
interres = If[TheMass[fullUV[[kuv,1,1,1]]]===0&&TheMass[fullUV[[kuv,1,2,1]]]===0,fr,fr*TheMass[fullUV[[kuv,1,2,1]]]+fsl]/.su3rep;
ColCons2pt[interres];
interres = EpsSerie[interres/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,2,1]]]^2];
eqlist=Append[eqlist,interres];
(*If[Not[FreeQ[fullUV[[kuv,1,1]],fullUV[[kuv,1,2,1]]]], be careful for non diagonal piece*)
deq=Simplify[D[(TheMass[fullUV[[kuv,1,1,1]]](fr+fl)+fsl+fsr),SP[FourMomentum[2], FourMomentum[2]]],TimeConstraint->0.01];
deq=(deq/.Derivative[0, 0, 1, 0][IntxnLog][aa_, bb_, cc_, dd_]:>Dp2IntxnLog[aa,bb,cc,dd]);
deq=2*TheMass[fullUV[[kuv,1,1,1]]]*deq+(fr+fl)/.su3rep;
ColCons2pt[deq];
deq=EpsSerie[deq/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,1,1]]]^2];
If[DeleteCases[fullUV[[kuv,1,1,1]],Index[Gluon|Colour,_],\[Infinity]]===DeleteCases[fullUV[[kuv,1,2,1]],Index[Gluon|Colour,_],\[Infinity]]||
DeleteCases[fullUV[[kuv,1,1,1]],Index[Gluon|Colour,_],\[Infinity]]===-DeleteCases[fullUV[[kuv,1,2,1]],Index[Gluon|Colour,_],\[Infinity]](*Same particle or particle and antiparticle*),
eqlist=Append[eqlist,deq];
];
(*Print[InputForm[{eqlist}]];*)
,
{S,S},
If[DeleteCases[fullUV[[kuv,1,1,1]],Index[Gluon|Colour,_],\[Infinity]]===DeleteCases[fullUV[[kuv,1,2,1]],Index[Gluon|Colour,_],\[Infinity]]||
DeleteCases[fullUV[[kuv,1,1,1]],Index[Gluon|Colour,_],\[Infinity]]===-DeleteCases[fullUV[[kuv,1,2,1]],Index[Gluon|Colour,_],\[Infinity]](*Same particle or particle and antiparticle*),
If[FreeQ[FR$GoldstoneList,fullUV[[kuv,1,1,1]]]&&FreeQ[FR$GoldstoneList,-fullUV[[kuv,1,1,1]]](*Not a goldstone boson*),
interres=fullUV[[kuv,2]]/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,1,1]]]^2;
eqlist=Append[eqlist,EpsSerie[interres]];
];
deq=D[(fullUV[[kuv,2]]),SP[FourMomentum[2], FourMomentum[2]]];
deq=EpsSerie[(deq/.Derivative[0, 0, 1, 0][IntxnLog][aa_, bb_, cc_, dd_]:>Dp2IntxnLog[aa,bb,cc,dd])/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,1,1]]]^2];
eqlist=Append[eqlist,deq];,
(*different scalars*)
interres = EpsSerie[(fullUV[[kuv,2]]/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,1,1]]]^2)];
eqlist=Append[eqlist,interres];
interres = EpsSerie[(fullUV[[kuv,2]]/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,2,1]]]^2)];
eqlist=Append[eqlist,interres];
];,
{V,V},
If[FreeQ[DeleteCases[fullUV[[kuv,1,1,1]],Index[Gluon|Colour,xx_],\[Infinity]],DeleteCases[fullUV[[kuv,1,2,1]],Index[Gluon|Colour,xx_],\[Infinity]]],
(*different particles*)
deq = Coefficient[fullUV[[kuv,2]],ME[Index[Lorentz,Ext[1]],Index[Lorentz,Ext[2]]]];
eqlist=Append[eqlist,(EpsSerie[deq/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,1,1]]]^2])];
eqlist=Append[eqlist,(EpsSerie[deq/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,2,1]]]^2])];
,
(*Same particle*)
deq = Coefficient[fullUV[[kuv,2]],ME[Index[Lorentz,Ext[1]],Index[Lorentz,Ext[2]]]];
If[Not[TheMass[fullUV[[kuv,1,1,1]]]===0],
(*Massive*)
eqlist=Append[eqlist,(EpsSerie[deq/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,1,1]]]^2])];
];
deq=D[deq,SP[FourMomentum[2], FourMomentum[2]]];
deq=(deq/.Derivative[0, 0, 1, 0][IntxnLog][aa_, bb_, cc_, dd_]:>Dp2IntxnLog[aa,bb,cc,dd]);
deq=deq/.SP[FourMomentum[2],FourMomentum[2]]->TheMass[fullUV[[kuv,1,1,1]]]^2;
deq=EpsSerie[deq];
eqlist=Append[eqlist,deq];
];
];(*end switch*)
varlist=Union[If[TheMass[fullUV[[kuv,1,1,1]]]===TheMass[fullUV[[kuv,1,2,1]]],Cases[eqlist,FR$delta[{TheMass[fullUV[[kuv,1,1,1]]]},{}],\[Infinity]],{}],Cases[eqlist,_FR$deltaZ,\[Infinity]]];
realvar=If[complex,{},Cases[varlist,FR$deltaZ[{x_,x_},b__]]];
extra=Complement[Union[Cases[fullUV[[kuv,2]],_FR$deltaZ,\[Infinity]]],varlist];
eqlist=(Refine[#/.((Rule[Conjugate[#],#]&)/@realvar)(*/.FR$IR->1*),Assumptions->Append[assumlist,FR$MU>0],TimeConstraint->0.0002]&)/@eqlist;
If[Length[varlist]+Length[extra]<1&&Not[And@@((#==0&)/@eqlist)===True],
Print[Style["Warning : no counterterms for this vertex "<>ToString[fullUV[[kuv,1]]] <> ", the following terms should vanish",Red]];
Print[InputForm[eqlist]];
,
(*Ignore conjugate vertex for boson since they give the same renormalisation condition*)
If[kuv<Length[fullUV]&&(Sort[(fullUV[[kuv,1]]/.-x_->x)[[All,1,1]]]===Sort[(fullUV[[kuv+1,1]]/.-x_->x)[[All,1,1]]]&&Not[verttype==={F,F}]),kuv++;];
If[kuv==Length[fullUV]||Not[Sort[(fullUV[[kuv,1]]/.-x_->x)[[All,1,1]]]===Sort[(fullUV[[kuv+1,1]]/.-x_->x)[[All,1,1]]]],
res=Join[res,ConsSolve[eqlist/.{If->Cond,FR$IR->1},varlist],If[Length[extra]>0,(#->0&)/@extra,{}]]; (*set to zero no usefull delta(Z)*)
];
];
(*Print["before join"];Print[InputForm[If[Length[extra]>0,(#->0&)/@extra,{}]]];*)
];(*end for*)
res=Flatten[res/.Rule->tRule/.{tRule[FR$deltaZ[{a_,b_},xx__],-Conjugate[FR$deltaZ[{b_,a_},xx__]]]->{tRule[FR$deltaZ[{a,b},xx],0],tRule[FR$deltaZ[{b,a},xx],0]}}]/.
tRule->Rule;
(Refine[#,Assumptions->Append[assumlist,FR$MU>0],TimeConstraint->0.001]&)/@(res/.{Cond->If,If[complex,FR$Re->1,FR$Re->0]})
];
(* ::Subtitle:: *)
(*R2*)
(*Performs q integration*)
(* ::Subsubtitle::Closed:: *)
(*Tadpoles*)
R2Tadpoles::usage="compute the R2 for a Tadpole amplitude after the non contributing terms have been removed"
R2Tadpoles[num_,del_,next_,UVcounter_] := Block[{tmp, coef},
coef = Times @@ Cases[num, _?((FreeQ[#, MatrixTrace] && FreeQ[#, MetricTensor] && FreeQ[#, FourVector]) &)];
tmp = num/coef;
tmp = Expand[tmp /. {MatrixTrace -> DTr, MetricTensor -> ME, FourVector -> FV}];
Simplify[-2 I \[Pi]^2*coef*del*Coefficient[Normal[Series[tmp /. {M$dim -> 4 + M$eps}, {M$eps, 0, 1}]], M$eps]]*FR$R2-2 I \[Pi]^2*coef*del*Simplify[(FR$UV(1/FR$Eps*
Normal[Series[(tmp(1-FR$Eps/2)/.M$dim->4+FR$Eps),{FR$Eps,0,If[next<=2&&UVcounter,1,0]}]]+ If[next<=2&&UVcounter,1,0]*UVLog[del/FR$MU^2]/2*tmp/.{M$dim->4}))] /. {DTr -> MatrixTrace, ME -> MetricTensor,
FV -> FourVector,LCivita->LeviCivita}
];
(* ::Subsubtitle::Closed:: *)
(*Bubbles*)
R2BubblesF::usage="compute the R2 for a bubble amplitude with no occurence of the loop momentum on the numerator after the non contributing terms have
been removed"
R2BubblesQ2::usage="compute the R2 for a bubble amplitude with two occurence of the loop momentum on the numerator after the non contributing terms have
been removed"
R2BubblesF[num_,del_,next_,UVcounter_]:=Block[{tmp,coef},
coef=Times@@Cases[num,_?((FreeQ[#,MatrixTrace]&&FreeQ[#,MetricTensor]&&FreeQ[#,FourVector]&&FreeQ[#,FermionChain])&)];
tmp=num/coef;
tmp=Expand[tmp/.{MatrixTrace->DTr,MetricTensor->ME,FourVector->FV,FermionChain->FCh}];
tmp=-2I \[Pi]^2*(Simplify[Coefficient[Normal[Series[tmp/.{M$dim->4+M$eps},{M$eps,0,1}]],M$eps]]FR$R2 +
FR$UV*Simplify[1/FR$Eps*Normal[Series[(tmp/.M$dim->4+FR$Eps),{FR$Eps,0,If[next===2&&UVcounter,1,0]}]]+ If[next===2&&UVcounter,1,0]*(Normal[Series[Log[del/FR$MU^2]/2*tmp/.{M$dim->4+FR$Eps},{FR$Eps,0,1}]])]/.
{DTr->MatrixTrace,ME->MetricTensor,FV->FourVector,FCh->FermionChain,LCivita->LeviCivita});
coef*tmp
];
R2BubblesQ2[num_,lm_,del_,next_,UVcounter_]:=Block[{tmp,coef},
coef=Times@@Cases[num,_?((FreeQ[#,MatrixTrace]&&FreeQ[#,MetricTensor]&&FreeQ[#,FourVector]&&FreeQ[#,FermionChain])&)];
tmp=num/coef;
tmp=Expand[tmp/.{MatrixTrace->DTr,MetricTensor->ME,FourVector->FV,FermionChain->FCh}];
tmp=tmp/.red2v[lm];
tmp=Simplify[-4I \[Pi]^2*Coefficient[Normal[Series[tmp/.{M$dim->4+M$eps},{M$eps,0,1}]],M$eps]-I \[Pi]^2tmp/.{M$dim->4}]*del*FR$R2 -
I \[Pi]^2*del FR$UV*Simplify[(1/FR$Eps*Normal[Series[((4-FR$Eps)tmp/.M$dim->4+FR$Eps),{FR$Eps,0,If[next===2&&UVcounter,1,0]}]]+
If[next===2&&UVcounter,1,0]*Normal[Series[(4-FR$Eps)Log[del/FR$MU^2]/2*tmp/.{M$dim->4+FR$Eps},{FR$Eps,0,1}]])]/.
{SP[lm,lm]->1}/.{DTr->MatrixTrace,ME->MetricTensor,FV->FourVector,FCh->FermionChain,LCivita->LeviCivita};
coef*tmp
];
(* ::Subsubtitle::Closed:: *)
(*Triangles*)
R2FTriangles::usage="compute the R2 for a Triangle amplitude with only fermions in the loop after the non contributing terms have been removed"
R2FBTriangles::usage="compute the R2 for a Triangle amplitude with both fermions and bosons in the loop after the non contributing terms have been removed"
R2BTriangles::usage="compute the R2 for a Triangle amplitude with only bosons in the loop after the non contributing terms have been removed"
R2FTriangles[num_,lm_]:=Block[{tmp,coef},
tmp=Cases[num,_MatrixTrace][[1]];
coef=Times@@Cases[num,Except[_MatrixTrace]];
tmp=tmp/.{MatrixTrace->DTr};
tmp=Expand[Expand[tmp]/.red2v[lm]];
I \[Pi]^2*coef (Simplify[-2Coefficient[Normal[Series[tmp/.{M$dim->4+M$eps},{M$eps,0,1}]],M$eps]-1/2(tmp/.M$dim->4)]FR$R2-
2 FR$UV*Simplify[(tmp/.{M$dim->4})]/FR$Eps)/.SP[lm,lm]->1/.{ME->MetricTensor,DTr->MatrixTrace,FV->FourVector,LCivita->LeviCivita}
];
R2FBTriangles[num_,lm_]:=Block[{tmp,coef},
tmp=Times@@Cases[num,_?(Not[FreeQ[#,lm]]&)];
coef=num/tmp;
tmp=Times@@Cases[coef,_?(Not[FreeQ[#,MetricTensor]]&)]*tmp;
coef=num/tmp;
tmp=Expand[tmp/.{FermionChain->FCh,MetricTensor->ME,FourVector->FV}];
tmp=Expand[Expand[tmp]/.red2v[lm]];
I \[Pi]^2*coef (Simplify[-2Coefficient[Normal[Series[tmp/.{M$dim->4+M$eps},{M$eps,0,1}]],M$eps]-1/2(tmp/.M$dim->4)]FR$R2-
2 FR$UV*Simplify[(tmp/.{M$dim->4})]/FR$Eps)/.SP[lm,lm]->1/.{ME->MetricTensor,DTr->MatrixTrace,FV->FourVector,FCh->FermionChain,LCivita->LeviCivita}
];
R2BTriangles[num_,lm_]:=Block[{coef, tmp},
tmp=Times@@Cases[num,_?(Not[FreeQ[#,lm]]&)];
coef=num/tmp;
tmp=Times@@Cases[coef,_?(Not[FreeQ[#,MetricTensor]]&)]*tmp;
coef=num/tmp;
tmp=Expand[tmp]/.{MetricTensor->ME}/.{FourVector->FV};
tmp=Expand[tmp]/.red2v[lm];
tmp=Expand[tmp];
I \[Pi]^2*coef (Simplify[-2Coefficient[Normal[Series[tmp/.{M$dim->4+M$eps},{M$eps,0,1}]],M$eps]-1/2(tmp/.M$dim->4)]FR$R2-
2 FR$UV*Simplify[(tmp/.{M$dim->4})]/FR$Eps)/.SP[lm,lm]->1/.{ME->MetricTensor,DTr->MatrixTrace,FV->FourVector,LCivita->LeviCivita}
];
(* ::Subsubtitle::Closed:: *)
(*Boxes*)
R2FBoxes::usage="compute the R2 for a boxe amplitude with only fermions in the loop after the non contributing terms have been removed"
R2BBoxes::usage="compute the R2 for a boxe amplitude with only bosons in the loop after the non contributing terms have been removed"
R2FBoxes[num_,lm_]:=Block[{tmp,coef},
tmp=Cases[num,_MatrixTrace][[1]];
coef=Times@@Cases[num,Except[_MatrixTrace]];
tmp=tmp/.{MatrixTrace->DTr};
tmp=Simplify[Expand[Expand[tmp]/.red4v[lm]/.red2v[lm]]];
I \[Pi]^2*coef (Simplify[-2Coefficient[Normal[Series[tmp/.{M$dim->4+M$eps},{M$eps,0,1}]],M$eps]-5/6(tmp/.M$dim->4)]FR$R2-
2 FR$UV*Simplify[(tmp/.{M$dim->4})]/FR$Eps)/.SP[lm,lm]->1/.{ME->MetricTensor,FV->FourVector,LCivita->LeviCivita}
];
R2BBoxes[num_,lm_]:=Block[{coef, tmp},
tmp=Times@@Cases[num,_?(Not[FreeQ[#,lm]]&)];
coef=num/tmp;
tmp=Times@@Cases[coef,_?(Not[FreeQ[#,MetricTensor]]&)]*tmp;
coef=num/tmp;
tmp=Expand[tmp]/.{MetricTensor->ME}/.{FourVector->FV}/.red4v[lm]/.red2v[lm];
tmp=Expand[tmp];
I \[Pi]^2*coef (Simplify[-2Coefficient[Normal[Series[tmp/.{M$dim->4+M$eps},{M$eps,0,1}]],M$eps]-5/6(tmp/.M$dim->4)]FR$R2-
2 FR$UV*Simplify[(tmp/.{M$dim->4})]/FR$Eps)/.SP[lm,lm]->1/.{ME->MetricTensor,FV->FourVector,LCivita->LeviCivita}
];
(* ::Subtitle::Closed:: *)
(*GetR2*)
GetR2::usage="compute the R2 for a FeynArts amplitude at the generic level"
GetR2[amp_,next_,UVfin_]:=Block[{temp,loopmom,nden,den,num,kk,extmom,intmom,lmcoef,DisFC,DisMT,DisDS,DisNC,nlmom,x,y,z,rl,lr,delta},
loopmom=amp[[2,1]];
den=Cases[amp[[3]],_PropagatorDenominator,\[Infinity]];
den=Cases[den,_?(Not[FreeQ[#,loopmom]]&),1];
nden=Length[den];
num=amp[[3]]/.{FeynAmpDenominator[__]->1}/.LeviCivita->LCivita;
Switch[nden,
1,
num=num/.{NonCommutative[DiracSlash[loopmom] + Mass[yy_,Loop]]->Mass[yy,Loop],NonCommutative[DiracSlash[-loopmom] + Mass[yy_,Loop]]->Mass[yy,Loop]}/.
{loopmom->0,FourVector[0,x_]->0};
num=R2Tadpoles[num,den[[1,2]]^2,next,UVfin];
,
2,
extmom=(Coefficient[#,loopmom]&/@Cases[den,\!\(TraditionalForm\`PropagatorDenominator\)[a_,b_]->a]).Cases[den,\!\(TraditionalForm\`PropagatorDenominator\)[a_,b_]->a]-2loopmom;
delta=SP[extmom,extmom]x*(x-1)+Cases[den,_?(Not[FreeQ[#,extmom]]&)][[1,2]]^2*x+Cases[den,_?(FreeQ[#,extmom]&)][[1,2]]^2*(1-x);
If[FreeQ[num,F],
lmcoef=Cases[num,_?(Not[FreeQ[#,loopmom]]&)];
If[Length[lmcoef]==2,
num={num/Times@@lmcoef*(Times@@lmcoef/.{loopmom->intmom}/.{_FourMomentum->0}/.{intmom->loopmom}), num/.{loopmom->-x*extmom}};
,
If[Length[lmcoef]==1,
num={0,num/.{loopmom->-x*extmom}};
,
num={0,num};
];
];
,
If[Count[num,Mass[F[__],Loop],\[Infinity]]==2,
num={num/.{NonCommutative[DiracSlash[xx_] + Mass[yy__,Loop]]:>NonCommutative[DiracSlash[loopmom]]},(x (x-1)num/.
{NonCommutative[DiracSlash[xx_] + Mass[yy_,Loop]]:>NonCommutative[DiracSlash[extmom] ]})+num/.
{NonCommutative[DiracSlash[xx_] + Mass[yy_,Loop]]:> Mass[yy,Loop]}};
,
num={0,(num/.{NonCommutative[DiracSlash[xx_] + Mass[yy_,Loop]]:>NonCommutative[DiracSlash[xx/.{loopmom->0}] + Mass[yy,Loop]]})-
(x*num/.{NonCommutative[DiracSlash[xx_] + Mass[yy_,Loop]]:>NonCommutative[DiracSlash[Coefficient[xx,loopmom]*extmom]]})};
];
];
num=R2BubblesQ2[num[[1]],loopmom,delta,next,UVfin]+R2BubblesF[num[[2]],delta,next,UVfin];
num=If[next===2,XIntegrate[num,delta,x],Integrate[num,{x,0,1}]];
,
3,
extmom=(Coefficient[#,loopmom]&/@Cases[den,\!\(TraditionalForm\`PropagatorDenominator\)[a_,b_]->a])*Cases[den,\!\(TraditionalForm\`PropagatorDenominator\)[a_,b_]->a]-loopmom;
extmom=DeleteCases[extmom,0].{x,y};
If[FreeQ[num,F],
lmcoef=Cases[num,_?(Not[FreeQ[#,loopmom]]&)];
If[Length[lmcoef]==3,
num=num/Times@@lmcoef*
((Times@@lmcoef[[1;;2]]/.{loopmom->intmom}/.{_FourMomentum->0}/.{intmom->loopmom})*(lmcoef[[3]]/.{loopmom->-extmom})+
(Times@@lmcoef[[2;;3]]/.{loopmom->intmom}/.{_FourMomentum->0}/.{intmom->loopmom})*(lmcoef[[1]]/.{loopmom->-extmom})+
(Times@@lmcoef[[{1,3}]]/.{loopmom->intmom}/.{_FourMomentum->0}/.{intmom->loopmom})*(lmcoef[[2]]/.{loopmom->-extmom}));
num=R2BTriangles[num,loopmom];
num=2*Integrate[num,{x,0,1},{y,0,1-x}];
,
If[Length[lmcoef]==2,
num=num/Times@@lmcoef*(Times@@lmcoef/.{loopmom->intmom}/.{_FourMomentum->0}/.{intmom->loopmom});
num=R2BTriangles[num,loopmom];
num=2*Integrate[num,{x,0,1},{y,0,1-x}];
,
num=0;
];
];
,
If[Count[num,Mass[F[_],Loop],\[Infinity]]==3,
lmcoef=Cases[num,NonCommutative[DiracSlash[xx_] + Mass[yy_,Loop]],\[Infinity]];
num=Table[num/.{lmcoef[[kk]]->(lmcoef[[kk]]/.(NonCommutative[DiracSlash[xx_] + Mass[yy__,Loop]]:>NonCommutative[DiracSlash[Coefficient[xx,loopmom]*loopmom]])),
lmcoef[[Mod[kk,3]+1]]->(lmcoef[[Mod[kk,3]+1]]/.(NonCommutative[DiracSlash[xx_] + Mass[yy__,Loop]]:>NonCommutative[DiracSlash[Coefficient[xx,loopmom]*loopmom]])),
lmcoef[[Mod[kk+1,3]+1]]->(lmcoef[[Mod[kk+1,3]+1]]/.{loopmom->-extmom})},{kk,1,3}];
num=Total[(R2FTriangles[#,loopmom]&)/@num];
num=2*Integrate[num,{x,0,1},{y,0,1-x}];
,
If[Count[num,Mass[F[_],Loop],\[Infinity]]==2,
num=num/.{NonCommutative[DiracSlash[xx_] + Mass[yy__,Loop]]:>NonCommutative[DiracSlash[Coefficient[xx,loopmom]*loopmom]]};
num=R2FBTriangles[num,loopmom];
num=2*Integrate[num,{x,0,1},{y,0,1-x}];
,
lmcoef=Cases[num,_?((Not[FreeQ[#,loopmom]]&&FreeQ[#,FermionChain])&)];
If[Length[lmcoef]==1,
num=num/lmcoef[[1]]*(lmcoef[[1]]/.{loopmom->intmom}/.{_FourMomentum->0}/.{intmom->loopmom})/.
{NonCommutative[DiracSlash[xx_] + Mass[yy__,Loop]]:>NonCommutative[DiracSlash[Coefficient[xx,loopmom]*loopmom]]};
num=R2FBTriangles[num,loopmom];
num=2*Integrate[num,{x,0,1},{y,0,1-x}];
,
num=0;
];
];
];
];
,
4,
If[FreeQ[num,F],
lmcoef=Cases[num,_?((Not[FreeQ[#,loopmom]])&)];
If[Length[lmcoef]==4,
num=num/Times@@lmcoef*(Times@@lmcoef/.{loopmom->intmom}/.{_FourMomentum->0}/.{intmom->loopmom});
num=R2BBoxes[num,loopmom];
,
num=0;
];
,
If[Count[num,Mass[F[_],Loop],\[Infinity]]==4,
num=num/.{NonCommutative[DiracSlash[xx_] + Mass[yy__,Loop]]:>NonCommutative[DiracSlash[Coefficient[xx,loopmom]*loopmom]]};
num=R2FBoxes[num,loopmom];
,
num=0;
];
];
,
_,
Print[Style["Warning : More that 4 propagators, this diagram is discarded ",Orange]];
];(*end of Switch*)
num
];(*end of getR2*)
(* ::Subtitle:: *)
(*Get Several R2*)
(* from generic to class in FR format*)
(* ::Subsubtitle:: *)
(*R2atClass*)
R2atClass::usage="compute the R2 for a FeynArts amplitude #1 and a topology #2 at the class level. All the contributions are summed but the wave functions keep track of the external particles.
#3 is the list of the generic external particles (F,S,V). If #4 is True, each contribution is multiplyed by IPL[list of the particles in the loop]. The fifth argument is the list of indices to
be kept in IPL like generation. Only qcd corrections are kept if the 6th argument is true and the finite part of the UV counterterms is drop if the last argument is False"
R2atClass[Ampl_,INTopo_,verttype_,lab_,kept_,qcd_,UVfinite_]:=Block[{res,tmp,tmp2,top,gen,rf,rl,fc,scalar,intern,nExtC,ll},
res=0;
For[kk=1,kk<=Length[Ampl],kk++,
top=Ampl[[kk,1,1,2]];
gen=Ampl[[kk,1,2,2]];
tmp=GetR2[Ampl[[kk]],Length[verttype],UVfinite];
If[Not[tmp===0],