build.gradle

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7.3'
    }
}

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'idea'
apply plugin: 'com.jfrog.bintray'
apply plugin: 'maven-publish'

group = 'com.spaceshift'
version = '5.1.0'

sourceCompatibility = 1.10
targetCompatibility = 1.10

compileTestJava {
    sourceCompatibility = 1.10
    targetCompatibility = 1.10
    options.compilerArgs += '-parameters'
}

ext.junitJupiterVersion = "5.2.0"
ext.log4jVersion = '2.6.2'
ext.bintrayVersion = version

repositories {
    mavenCentral()
    mavenLocal()
    maven {
        url 'https://jitpack.io'
    }
    maven {
        url  "https://dl.bintray.com/javasabr/maven"
    }
}

publishing {
    publications {
        RlibFXArtifact(MavenPublication) {
            from components.java
            groupId group
            artifactId 'rlib.fx'
            version bintrayVersion
            artifact sourcesJar
            artifact javadocJar
        }
    }
}

bintray {
    user = System.getProperty('bintrayUser')
    key = System.getProperty('bintrayKey')
    publications = ['RlibFXArtifact']
    pkg {
        repo = 'maven'
        name = 'com.spaceshift.rlib.fx'
        licenses = ['Apache-2.0']
        websiteUrl = 'https://github.com/JavaSaBr/RlibFX'
        vcsUrl = 'https://github.com/JavaSaBr/RlibFX.git'
        issueTrackerUrl = 'https://github.com/JavaSaBr/RlibFX/issues'
        githubRepo = 'JavaSaBr/RlibFX'
        githubReleaseNotesFile = 'README.md'
        version {
            name = bintrayVersion
            desc = bintrayVersion
            released  = new Date()
        }
    }
}

dependencies {
    compile 'com.spaceshift:rlib.common:7.3.0'
    compile group: 'org.jetbrains', name: 'annotations', version: '15.0'

    testCompile group: 'org.jetbrains', name: 'annotations', version: '15.0'

    testCompile "org.junit.jupiter:junit-jupiter-api:$junitJupiterVersion"
    testRuntime "org.junit.jupiter:junit-jupiter-engine:$junitJupiterVersion"
}

test {
    useJUnitPlatform()

    testLogging {
        events "passed", "skipped", "failed"
    }

    reports {
        html.enabled = true
    }
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

task wrapper(type: Wrapper) {
    gradleVersion = '4.9'
}