home-manager-base.nix

{ config, pkgs, ... }:

let

  hexmode = pkgs.vimUtils.buildVimPlugin {
    name = "hexmode";
    src = pkgs.fetchFromGitHub {
      owner = "fidian";
      repo = "hexmode";
      rev = "72190318f03a999de357984df72714114e52f6af";
      sha256 = "9vPMIBNmxeBmajMFOXO14yBKzfO+f2+duXXOqg6hwHE=";
    };
  };
  colorscheme = pkgs.vimUtils.buildVimPlugin {
    name = "colorscheme";
    src = vim/vim-colorscheme;
  };
  earthly-vim = pkgs.vimUtils.buildVimPlugin {
    name = "earthly";
    src = pkgs.fetchFromGitHub {
      owner = "earthly";
      repo = "earthly.vim";
      rev = "9402908f41c5165fa69317da9fe1c47ea5f9e5dd";
      sha256 = "KOlYUXasMYHMUY8uthiwPh2uLZaQSI76anJD0W1+qes=";
    };
  };

in

{
  imports = [
    ./vscode
  ];

  # Packages to install
  home.packages = with pkgs;
    [
      nix
      ripgrep
      xclip
      update-nix-fetchgit
      nodejs
      rustup
      clang
      cargo-edit
      pijul
      nixpkgs-fmt
      docker-compose
      delta
      black
      python310Packages.pipx
    ];

  home.sessionVariables = {
    EDITOR = "nvim";
  };

  home.shellAliases = {
    vim = "nvim -p";
    nvim = "nvim -p";
    cdnix = "cd ~/.config/home-manager";
  };

  xdg.enable = true;

  programs.git = {
    enable = true;
    userName = "Ben Lipton";
    extraConfig = {
      merge.conflictstyle = "diff3";
      pull.rebase = false;
      push.default = "current";
      push.autosetupremote = true;
    };
    delta = {
      enable = true;
    };
  };

  programs.bash.enable = true;

  modules.home.editors.vscode = {
    enable = true;
    mutable = true;
  };

  programs.zsh = {
    enable = true;
    enableCompletion = true;
    autosuggestion.enable = true;
    syntaxHighlighting.enable = true;
    plugins = import zsh/zsh-plugins.nix { inherit pkgs; };
    oh-my-zsh = {
      enable = true;
      plugins = [ "history-substring-search" "copypath" "copybuffer" ];
      #theme = "dst";
    };
  };

  programs.tmux = {
    enable = true;
    prefix = "C-a";
    keyMode = "vi";
    shell = "${pkgs.zsh}/bin/zsh";
    plugins = with pkgs.tmuxPlugins; [
      pain-control
      {
        plugin = yank;
        extraConfig = "set -g @yank_selection_mouse 'clipboard'";
      }
      logging
      sensible
      better-mouse-mode
      fingers
    ];
    extraConfig = builtins.concatStringsSep "\n" [
      "set -g mouse on"
      (builtins.readFile tmux/extra.tmux)
    ];
  };

  programs.fzf = {
    enable = true;
  };

  programs.neovim = {
    enable = true;
    coc = {
      enable = true;
      settings = {
        coc.preferences.formatOnSaveFiletypes = [ "rust" ];
      };
    };
    plugins = with pkgs.vimPlugins; [
      # General
      vim-repeat
      vim-surround
      vim-unimpaired
      bclose-vim
      #vim-better-whitespace
      #vim-autoformat
      #neoformat
      vim-lastplace

      # Coding style
      vim-sleuth
      #editorconfig-vim

      # Movement
      vim-matchup

      # IDE
      fzf-vim
      vim-peekaboo
      copilot-vim

      # Airline
      {
        plugin = vim-airline;
        config = builtins.readFile vim/vim-pluginrc/plugin/vim-airline.vim;
      }
      vim-airline-themes
      {
        plugin = tmuxline-vim;
        config = builtins.readFile vim/vim-pluginrc/plugin/tmuxline.vim;
      }

      # Completion & Snippets
      {
        plugin = coc-nvim;
        config = builtins.readFile vim/vim-pluginrc/plugin/coc.vim;
      }
      coc-git
      coc-html
      coc-json
      coc-yaml
      coc-yank
      coc-lists
      coc-tsserver
      coc-rust-analyzer

      # Programming
      nerdcommenter

      # Syntax
      vim-polyglot
      vim-helm
      vim-graphql
      hexmode

      # Colorschemes
      colorscheme

      earthly-vim
    ];
    extraConfig = builtins.concatStringsSep "\n" [
      (builtins.readFile vim/vimrc)
    ];
  };

  # This value determines the Home Manager release that your
  # configuration is compatible with. This helps avoid breakage
  # when a new Home Manager release introduces backwards
  # incompatible changes.
  #
  # You can update Home Manager without changing this value. See
  # the Home Manager release notes for a list of state version
  # changes in each release.
  home.stateVersion = "22.05";

  # Let Home Manager install and manage itself.
  programs.home-manager.enable = true;
}