Issues with making predictions using the expression selected using the function passed to selection_method

[MrChewi]

Hi Everyone,

I'm thrilled and very excited about using SymbolicRegression.jl tool. I'm quite new so I'm trying to learn the bits ans peaces that offers the package. I have used a simple example where I have some experimental data and tried to recover the equation behind it.
it is based on an article I'm working on which describes The heat capacity of water ice in interstellar or interplanetary conditions.

It worked quite nicely and fitted pretty much the experimental data I had. Nevertheless, I had 2 issues : one of which was with using the selection_method to select an expression.
I used the same expression as described in : https://astroautomata.com/SymbolicRegression.jl/dev/
which is :

mach.model.selection_method = Returns(2)
predict(mach, X)

but the output result kept being the same as the best_indx expression function weirdly I don't know why (see the model below).

using SymbolicRegression
using MLJ
using CSV
using DataFrames
using Plots

# Loading the dataset from a CSV file
data = DataFrame(CSV.File("/Users/tahahaithem/Desktop/Mars project/data.csv"))


# Extract input features and target variable
X = select(data, Not(:Cp))  # input features
y = data.Cp  #  "target_column" 

# Define functions
exp_sqrt(x) = exp(sqrt(abs(x)))
T_sqr(x)    = x^2 
T_six(x)    = x^6
T_four(x)   = x^4

# Load the symbolic regression model
SRRegressor = @load SRRegressor pkg=SymbolicRegression

# Create the model
model = SRRegressor(binary_operators=[+, -, *], unary_operators=[exp, exp_sqrt, T_sqr, T_six, T_four], 
                    niterations=20000, 
                    populations=30, 
                    turbo=true,
                    );

# Create a machine
mach = machine(model, X, y)

# Train the model
fit!(mach)

# Let's look at the expressions discovered:
report(mach)
predict(mach, X)  # This will make predictions using the expression selected using the function passed to selection_method. 

# Example of making predictions using expression 2 with:
mach.model.selection_method = Returns(2)
y_hat= predict(mach, X)

# Plotting the experimental and predicted expressions using T as data
scatter(y[:, 1], y_hat[:, 1], xlabel="Truth", ylabel="Prediction")

plot(data.T, data.Cp, label="Experimental Data",xlabel="Temperature,T[K]", ylabel="Heat Capacity, Cp(T)[Jkg-1K-1]", seriestype=:scatter)
plot!(data.T, y_hat, label="Prediction", lw=3)

plot(data.T, (y[:, 1]./data.T), label="Experimental Data",xlabel="Temperature,T[K]", ylabel="Heat Capacity, Cp(T)/T [Jkg-1K-1]", seriestype=:scatter)
plot!(data.T, (y_hat[:, 1]./data.T), label="Prediction", lw=3)`

The second issue I had was how badly the equation found fitted the experimental data between a given range of data and that after different attempt with number of population and constraints. that I assume it is physically understandable as between T=0K and T=2.5 K there is another equation that governs that area. That being said, I don't know if there is a possibility to incorporate that as a constraints or maybe something else to improve the prediction ? (See Below the plot)

Thank you all for your future response, hope that they will be helpful. Have a good day

Haithem.

[MilesCranmer]

Thanks @MrChewi. It's weird the mach.model.selection_method = Returns(2) doesn't work... I will have a look.

For the question about the constraint that heat capacity = 0 when temperature = 0, what I like to do for asymptotic constraints is weight points according to how important they are to fit. For example, you could do

weights = ones(size(y))

# If y[end] is the C=0, T=0 point, then
weights[end] = 10_000

mach = machine(model, X, y, weights)

So when you fit, it will emphasize the C=0,T=0 point a lot more. Simply increase the weighting of that point as needed.

[MrChewi]

Hi Miles ! Thank you for your quick response. I did try to increase the weighting and the method worked fine. Nevertheless, the mach.model.selection_method = Returns(...) still don't work for me weirdly.

for information I'm using Julia 1.9 and SymbolicRegression v0.23.1

[MilesCranmer]

I confirm that setting selection_method in a fitted model does not work; sorry about that.

I made a pull request here: MilesCranmer/SymbolicRegression.jl#289 to enable the following syntax:

model = SRRegressor()
mach = machine(model, X, y)
fit!(mach)

# Predict with 3rd equation:
predict(mach, (data=X, idx=3))

# Predict with most complex equation:
r = report(mach)
predict(mach, (data=X, idx=lastindex(r.equations)))

which is similar to how PySRRegressor works on the Python side.

This is also nice because it works for multi-output equations (pass an array for idx).

Would be great if you could try it out and let me know if it gets the job done!

---

Edit: this is live on SymbolicRegression 0.23.2!