build.gradle

plugins {
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.6-SNAPSHOT" apply false
}

architectury {
    minecraft = project.minecraft_version
}

subprojects {
    apply plugin: "dev.architectury.loom"

    loom {
        silentMojangMappingsLicense()
    }

    configurations {
        modLocalRuntime.extendsFrom modCompileOnly
    }

    def lwjglNatives
    switch (org.gradle.internal.os.OperatingSystem.current()) {
        case org.gradle.internal.os.OperatingSystem.LINUX:
            lwjglNatives = "natives-linux"
            break
        case org.gradle.internal.os.OperatingSystem.MAC_OS:
            lwjglNatives = "natives-macos"
            break
        case org.gradle.internal.os.OperatingSystem.WINDOWS:
            lwjglNatives = "natives-windows"
            break
    }

    dependencies {
        minecraft "com.mojang:minecraft:${project.minecraft_version}"
        mappings loom.officialMojangMappings()

        modCompileOnly "io.github.moremcmeta:moremcmeta-${project.name}:${project.moremcmeta_version}"

        testImplementation "junit:junit:${project.junit_version}"
        testImplementation "org.lwjgl:lwjgl:${rootProject.lwjglVersion}"
        testImplementation "org.lwjgl:lwjgl-stb:${rootProject.lwjglVersion}"
        testRuntimeOnly "org.lwjgl:lwjgl:${rootProject.lwjglVersion}:${lwjglNatives}"
        testRuntimeOnly "org.lwjgl:lwjgl-stb::${lwjglNatives}"
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    def final SNAPSHOT_SUFFIX = "-prerelease"

    project.ext.mod_version = System.getenv("MOD_VERSION") ?: "DEV"
    project.ext.is_snapshot = project.mod_version.endsWith(SNAPSHOT_SUFFIX)

    archivesBaseName = project.archives_base_name
    version = "${project.minecraft_version}-${project.mod_version}"
    group = project.maven_group

    project.ext.maven_artifact_id = "${archivesBaseName}-${project.name}"
    project.ext.maven_version = is_snapshot
            ? "${version.substring(0, version.length() - SNAPSHOT_SUFFIX.length())}-SNAPSHOT"
            : version

    repositories {
        maven {
            url "https://maven.pkg.github.com/moremcmeta/*/"
            credentials {
                username System.getenv("MOREMCMETA_MAVEN_USER") ?: project.moremcmeta_maven_user
                password System.getenv("MOREMCMETA_MAVEN_PASS") ?: project.moremcmeta_maven_pass
            }
        }
    }

    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
        options.release = project.java_version.toInteger()
    }

    java {
        withSourcesJar()
    }

    publishing {
        publications {
            maven(MavenPublication) {
                artifactId = project.maven_artifact_id
                version = project.maven_version
                from components.java
            }
        }

        repositories {
            maven {
                name = "GitHubPackages"
                url = "https://maven.pkg.github.com/MoreMcmeta/animation-plugin"
                credentials {
                    username = System.getenv("GITHUB_ACTOR")
                    password = System.getenv("GITHUB_TOKEN")
                }
            }
        }
    }
}