Module request: haiku-icon-theme

[dominic-espo]

Description

An icon theme I've been seeing around new desktops is the Haiku theme from HaikuOS. They're low-poly and isometric, giving them a unique look. I think they would be a valuable addition to the nix repository.

Someone here has already exported the icons to SVG, PNG, and HVIF. Though the repository hasn't been updated since 8 months ago.

[luftmensch-luftmensch]

I'm currently using another one (the one also used by the AUR). I've packaged on my own repository like this:

{
  lib,
  stdenvNoCC,
  fetchFromGitHub,
  gtk3,
  adwaita-icon-theme,
  breeze-icons,
  hicolor-icon-theme,
}:
let
  pname = "haiku-icon-theme";
  version = "0-unstable-2024-12-24";
in
stdenvNoCC.mkDerivation {
  inherit pname version;

  src = fetchFromGitHub {
    owner = "tallero";
    repo = "haiku-icon-theme";
    rev = "7577be42c717faace2c5a4db5cc92850d76df42b";
    hash = "sha256-3CRz0zRwDtZF1MgPG1+xyiimxG4RLZshW92hjk+TjRA=";
  };

  nativeBuildInputs = [
    gtk3
  ];

  propagatedBuildInputs = [
    adwaita-icon-theme
    breeze-icons
    hicolor-icon-theme
  ];

  dontDropIconThemeCache = true;

  installPhase = ''
    runHook preInstall

    mkdir -p $out/share/icons
    cp -a Haiku $out/share/icons/

    for theme in $out/share/icons/*; do
      gtk-update-icon-cache -f $theme
    done

    runHook postInstall
  '';

  meta = {
    description = "Haiku icon theme";
    homepage = "https://github.com/tallero/haiku-icon-theme";
    license = lib.licenses.mit;
    platforms = lib.platforms.linux;
    maintainers = [ lib.maintainers.luftmensch-luftmensch ];
  };
}

I could make a PR later if you want

[dominic-espo]

I got them working with your configuration, but the icons don't always scale well. Here's a screenshot from my file picker.

Is this something on my end?

[luftmensch-luftmensch]

I got them working with your configuration, but the icons don't always scale well. Here's a screenshot from my file picker.

Is this something on my end?

Never had this problem in my configuration