build.gradle

plugins {
    id 'java'

    id 'org.springframework.boot' version '2.7.4'
    id 'io.spring.dependency-management' version '1.0.12.RELEASE'

    id "org.asciidoctor.jvm.convert" version "3.3.2"

    id 'jacoco'
}

group = 'com.projectboated'
version = '0.0.1-SNAPSHOT'

ext {
    // For Spring Rest Docs
    snippetsDir = file('build/generated-snippets')
}

repositories {
    mavenCentral()
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
    asciidoctorExtensions
}


dependencies {
    // Web
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-validation'

    // WebFlux
    implementation 'org.springframework.boot:spring-boot-starter-webflux'

    // WebSocket
    implementation 'org.springframework.boot:spring-boot-starter-websocket'
    implementation 'org.springframework.security:spring-security-messaging'

    // Cloud
    implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE'

    // Spring Security
    implementation 'org.springframework.boot:spring-boot-starter-security'
    testImplementation 'org.springframework.security:spring-security-test'

    // Test
    testImplementation 'org.mockito:mockito-inline'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    implementation 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310'
    implementation 'com.fasterxml.jackson.core:jackson-databind'

    // Database
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    runtimeOnly 'mysql:mysql-connector-java'
    testImplementation 'com.h2database:h2'
    implementation 'org.flywaydb:flyway-core'
    implementation "org.flywaydb:flyway-mysql"

    // Thymeleaf
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation 'org.thymeleaf.extras:thymeleaf-extras-springsecurity5'

    // Lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'

    // Spring Rest Docs
    testImplementation 'org.springframework.restdocs:spring-restdocs-restassured'
    testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'
    asciidoctorExtensions 'org.springframework.restdocs:spring-restdocs-asciidoctor'

    // Utils
    implementation 'com.google.guava:guava:31.1-jre'

    // Querydsl
    implementation 'com.querydsl:querydsl-core'
    implementation 'com.querydsl:querydsl-jpa'
    annotationProcessor("com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jpa")
    annotationProcessor("jakarta.persistence:jakarta.persistence-api")
    annotationProcessor("jakarta.annotation:jakarta.annotation-api")
}

test {
    outputs.dir snippetsDir
    useJUnitPlatform()
}

// Jacoco 시작
jacoco{
    toolVersion = "0.8.8"
}

jacocoTestReport {
    dependsOn test
    reports {
        html.enabled true
        xml.enabled false
        csv.enabled false
    }

    afterEvaluate {
        classDirectories.setFrom(files(classDirectories.files.collect {
            fileTree(dir: it, exclude: [
                    // QFile, 테스트 불필요.
                    "com/projectboated/backend/**/Q*.*",
                    // Spring MVC 예외관련 테스트, 자동화 테스트가 아닌, 직접 테스트
                    "com/projectboated/backend/web/exception/**",
                    // Infra, 자동화 테스트 불가
                    "com/projectboated/backend/infra/**/*",
                    // Spring Security : 테스트 작성해야함 (현재 단위 테스트를 어떻게 해야하나 고민중)
                    "com/projectboated/backend/security/**/*",
                    // Domain: Project Chatting, 기능을 완성하지 못함
                    "com/projectboated/backend/project/projectchatting/**"
            ])
        }))
    }
}

jacocoTestCoverageVerification {
    dependsOn jacocoTestReport

    violationRules {
        rule {
            element = 'CLASS'

            limit {
                counter = 'LINE'
                value = 'COVEREDRATIO'
                minimum = 0.0
            }
        }
    }
}
// Jacoco 끝

// Spring Rest Docs 시작
asciidoctor {
    dependsOn jacocoTestReport
    baseDirFollowsSourceDir()
    configurations 'asciidoctorExtensions'
    inputs.dir snippetsDir
}

asciidoctor.doFirst {
    delete file('src/main/resources/static/docs')
}

//task copyDocument(type: Copy) {
//    dependsOn asciidoctor
//    from file("${asciidoctor.outputDir}")
//    into file("src/main/resources/static/docs")
//}

bootJar {
    dependsOn asciidoctor
    from ("${asciidoctor.outputDir}") {
        into 'BOOT-INF/classes/static/docs'
    }
}
// Spring Rest Docs 끝

// Compiler 추가 옵션 시작
allprojects {
    gradle.projectsEvaluated {
        tasks.withType(JavaCompile) {
            options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
            // Graal Compiler setting
            //<< "-XX:+UnlockExperimentalVMOptions" << "-XX:+EnableJVMCI" << "-XX:+EnableJVMCI"
        }
    }
}
// Compiler 추가 옵션 끝