forked from CTU-Bern/stata_secutrial
-
Notifications
You must be signed in to change notification settings - Fork 0
/
xvarlabel.ado
278 lines (236 loc) · 7.59 KB
/
xvarlabel.ado
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
*!1.0.3 22Jan2008
capture program drop xvarlabel
program define xvarlabel
syntax [varlist], [VARinfo(str) erase] /*
*/ [VFIELDnames(str)] [NOMODify] [MAXLENgth(str)]/*
*/ [omit(varlist)] [savedo(str)] [replace]
********************************************
local includelist `"`varlist'"'
* if varlist not specified: _all will be automatically assumed (by STATA)
* check if varlist is not specified
gettoken piece : 0,parse(",")
if `"`piece'"' == "" | `"`piece'"' == "," local hasvarlist = 0
else local hasvarlist = 1
local piece ""
*expected names: varname file: "var" = varname, "text" = var label
local vvn_var "var"
local vvn_cat "text"
********************************************
*syntax / option checks
* remark: omit(varlist) means that varlabel(s) will be deleted
* remark: savedo(do-filename) means that no changes will be performed in
* STATA working dataset (no label var). Only
* writing label define commands in specified do-file.
*option varinfo compulsory unless option erase speified
if `"`varinfo'"' == "" & `"`erase'"' == "" {
di as err "option varinfo() required"
exit 198
}
* erase may not be combined with other options
if `"`erase'"' != "" & ///
(`"`vfieldnames'"' != "" | `"`nomodify'"' != "" | `"`maxlength'"' != "" ///
| `"`omit'"' != "" | `"`varinfo'"' != "" | `"`savedo'"' != "") {
di as err "option erase may not be combined with other options"
exit 198
}
* savedo may not be combined with ...
if `"`savedo'"' != "" {
if `"`nomodify'"' != "" {
di as err "option savedo() may not be combined with option nomodify"
exit 198
}
if `"`omit'"' != "" {
di as err "option savedo() may not be combined with option omit"
exit 198
}
if `"`erase'"' != "" {
di as err "option savedo() may not be combined with option erase"
exit 198
}
if `hasvarlist' == 1 {
di as err "varlist (list of to include variables) outside the options"
di as err "not allowed in combination with option savedo()"
exit 198
}
}
*replace only possible with savedo
if `"`replace'"' != "" & `"`savedo'"' == "" {
di as err "option replace only possible in combination with option savedo()"
exit 198
}
*********************************************
* maxlength >0 <81
if `"`maxlength'"' != "" {
local maxl = real("`maxlength'")
if `maxl' < 1 | `maxl' > 80 | `maxl' == . {
di as err "value out of range in option maxlength()"
di as err "must be between 1 and 80"
exit 198
}
}
else local maxl = 80 //up to 80 chars are allowed for variable labels
*********************************************
if `"`vfieldnames'"' != "" {
*must contain 1 ";"
local vfield `"`vfieldnames'"'
local part = 1 //before 1st ";"
while `"`vfield'"' != "" { //get token before and after ; (if present)
gettoken piece vfield : vfield,parse(";,") //qed(hadquotes)
if `"`piece'"' == ";" | `"`piece'"' == "," {
local part = `part' + 1
}
else {
local v`part' `"`piece'"'
}
}
if `part' != 2 {
di as err "syntax error in option vfieldnames()"
di as err "must contain 1 semikolon"
exit 198
}
if `"`v1'"' != "" {
local vvn_var `"`v1'"'
}
if `"`v2'"' != "" {
local vvn_cat `"`v2'"'
}
}
*******************************************
* if erase: "erase" variable labels from variables on includelist
if `"`erase'"' != "" {
foreach var of varlist `includelist' {
capture label var `var' ""
}
exit 0 // exit program
}
********************************************
* save dataset
preserve
*******************************************
*** Load table with varnames and variable labels
capture use `"`varinfo'"',clear
if _rc ! = 0 {
di as err `"Error reading file `varinfo'"'
exit 603
}
*names of fields in vn_var and vn_cat
capture confirm variable `vvn_var', exact
if _rc != 0 {
di as err "variable `vvn_var' in varinfo file not found"
di as err "use option vfieldnames() if variable has a different name"
exit 111
}
local tp:type `vvn_var'
if substr("`tp'",1,3) != "str" {
di as err "`vvn_var' must be string variable"
exit 109
}
capture confirm variable `vvn_cat', exact
if _rc != 0 {
di as err "variable `vvn_cat' in varinfo file not found"
di as err "use option vfieldnames() if variable has a different name"
exit 111
}
local tp:type `vvn_cat'
if substr("`tp'",1,3) != "str" {
di as err "`vvn_cat' must be string variable"
exit 109
}
*** save varnames and variable labels in local macros
local k = 1
qui count
forval i=1/`r(N)' {
*colum names are varname and labelname
if `vvn_var'[`i'] != "" {
local vname`k'=`vvn_var'[`i']
local lab`k'=`vvn_cat'[`i']
local k = `k' + 1
}
}
local totallabs = `k' - 1
*macro list
*** if savedo: open (create or erase) do-file for write
if `"`savedo'"' != "" {
*qui sort `vvn_var'
tempname WBT
*open do_file for write
cap file open `WBT' using `"`savedo'"' , write text `replace' // not append
if _rc ! = 0 {
qui capture confirm file `"`savedo'"'
if _rc == 0 & `"`replace'"' == "" {
di as err "error writing label variable commands in do-file"
di as err "not able to write file `savedo'"
di as err "file already exists - use option replace"
exit 602
}
else {
di as err "error writing label variable commands in do-file"
di as err "not able to write file `savedo'"
exit 603
}
}
* write header
local line "*****************************************"
file write `WBT' `"`line'"'
file write `WBT' _newline(1)
local line "* do-file for defining variable labels"
file write `WBT' `"`line'"'
file write `WBT' _newline(1)
local line "* built according to information in datafile:"
file write `WBT' `"`line'"'
file write `WBT' _newline(1)
local line "* `varinfo'"
file write `WBT' `"`line'"'
file write `WBT' _newline(1)
local line "* do-file created date: `c(current_date)' time: `c(current_time)'"
file write `WBT' `"`line'"'
file write `WBT' _newline(1)
local line "*****************************************"
file write `WBT' `"`line'"'
file write `WBT' _newline(2)
}
if `"`savedo'"' != "" {
forval x=1/`totallabs' {
local lb=substr(`"`lab`x''"',1,`maxl')
local line `"capture label var `vname`x'' `"`lb'"'"'
*local line `"capture label var `vname`x'' `"`lab`x''"'"'
file write `WBT' `"`line'"'
file write `WBT' _newline(1)
}
file close `WBT'
disp ""
disp "{col 1}{txt} no changes in current STATA dataset"
disp "{col 1}{txt} label variable commands only saved in do-file"
disp "{col 1}{txt} file name: {res}`savedo'{txt}"
disp ""
}
*************************************************
*** restore Stata File with required data
restore
*************************************************
if `"`savedo'"' != "" exit 0
*************************************************
*** define variable labels
foreach var of varlist `includelist' {
local olb:variable label `var'
if `"`nomodify'"' == "" | `"`olb'"' == "" {
forval x=1/`totallabs' {
local doval = 1
if "`var'" == "`vname`x''" {
* is variable on "omit-list"?
if `"`omit'"' != "" {
foreach o of local omit {
if `"`o'"' == `"`vname`x''"' {
local doval = 0 // omit
continue, break
}
}
}
local lb=substr(`"`lab`x''"',1,`maxl')
if `doval' == 1 capture label variable `var' `"`lb'"'
}
}
}
}
end
exit