forked from Slicer/Slicer
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathSlicerConfigureVersionHeaderTarget.cmake
156 lines (142 loc) · 4.96 KB
/
SlicerConfigureVersionHeaderTarget.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
################################################################################
#
# Program: 3D Slicer
#
# Copyright (c) Kitware Inc.
#
# See COPYRIGHT.txt
# or http://www.slicer.org/copyright/copyright.txt for details.
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
# This file was originally developed by Jean-Christophe Fillion-Robin, Kitware Inc.
# and was partially funded by NIH grant 3P41RR013218-12S1
#
################################################################################
#
# This module will add a target named 'SlicerConfigureVersionHeader'.
#
# It has been designed to be included in the build system of Slicer.
#
# The following variables are expected to be defined in the including scope:
#
# GIT_EXECUTABLE
# Slicer_BINARY_DIR
# Slicer_CMAKE_DIR
#
# Slicer_MAIN_PROJECT_APPLICATION_NAME
# Slicer_MAIN_PROJECT_SOURCE_DIR
# Slicer_MAIN_PROJECT_VERSION_MAJOR
# Slicer_MAIN_PROJECT_VERSION_MINOR
# Slicer_MAIN_PROJECT_VERSION_PATCH
#
# Slicer_RELEASE_TYPE
#
# Slicer_SOURCE_DIR
# Slicer_VERSION_MAJOR
# Slicer_VERSION_MINOR
# Slicer_VERSION_PATCH
#
# Optionally, these variable can also be set:
#
# Slicer_FORCED_REVISION (default "")
# Slicer_REVISION_TYPE
# Slicer_FORCED_WC_LAST_CHANGED_DATE (default ""): Format YYYY-MM-DD
# Slicer_WC_COMMIT_COUNT_OFFSET
#
# Slicer_MAIN_PROJECT_FORCED_REVISION (default "")
# Slicer_MAIN_PROJECT_REVISION_TYPE
# Slicer_MAIN_PROJECT_FORCED_WC_LAST_CHANGED_DATE (default ""): Format YYYY-MM-DD
# Slicer_MAIN_PROJECT_WC_COMMIT_COUNT_OFFSET
#
# --------------------------------------------------------------------------
# Sanity checks
# --------------------------------------------------------------------------
set(expected_defined_vars
GIT_EXECUTABLE
Slicer_BINARY_DIR
Slicer_CMAKE_DIR
Slicer_MAIN_PROJECT_APPLICATION_NAME # Used by SlicerVersion.cmake
Slicer_MAIN_PROJECT_SOURCE_DIR
Slicer_MAIN_PROJECT_VERSION_MAJOR
Slicer_MAIN_PROJECT_VERSION_MINOR
Slicer_MAIN_PROJECT_VERSION_PATCH
Slicer_RELEASE_TYPE
Slicer_SOURCE_DIR
Slicer_VERSION_MAJOR
Slicer_VERSION_MINOR
Slicer_VERSION_PATCH
)
foreach(var ${expected_defined_vars})
if(NOT DEFINED ${var})
message(FATAL_ERROR "${var} is mandatory")
endif()
endforeach()
if(NOT DEFINED SLICER_CONFIGURE_VERSION_HEADER)
set(SLICER_CONFIGURE_VERSION_HEADER 0)
endif()
# --------------------------------------------------------------------------
# Add SlicerConfigureVersionHeader target
# --------------------------------------------------------------------------
if(NOT SLICER_CONFIGURE_VERSION_HEADER)
set(script_args)
foreach(var IN LISTS expected_defined_vars)
list(APPEND script_args "-D${var}:STRING=${${var}}")
endforeach()
if(NOT DEFINED Slicer_FORCED_REVISION)
set(Slicer_FORCED_REVISION "")
endif()
if(NOT DEFINED Slicer_FORCED_WC_LAST_CHANGED_DATE)
set(Slicer_FORCED_WC_LAST_CHANGED_DATE "")
endif()
add_custom_target(SlicerConfigureVersionHeader ALL
COMMAND ${CMAKE_COMMAND}
${script_args}
-DSlicer_FORCED_REVISION:STRING=${Slicer_FORCED_REVISION}
-DSlicer_REVISION_TYPE:STRING=${Slicer_REVISION_TYPE}
-DSlicer_FORCED_WC_LAST_CHANGED_DATE:STRING=${Slicer_FORCED_WC_LAST_CHANGED_DATE}
-DSlicer_WC_COMMIT_COUNT_OFFSET:STRING=${Slicer_WC_COMMIT_COUNT_OFFSET}
-DSlicer_MAIN_PROJECT_FORCED_REVISION:STRING=${Slicer_MAIN_PROJECT_FORCED_REVISION}
-DSlicer_MAIN_PROJECT_REVISION_TYPE:STRING=${Slicer_MAIN_PROJECT_REVISION_TYPE}
-DSlicer_MAIN_PROJECT_FORCED_WC_LAST_CHANGED_DATE:STRING=${Slicer_MAIN_PROJECT_FORCED_WC_LAST_CHANGED_DATE}
-DSlicer_MAIN_PROJECT_WC_COMMIT_COUNT_OFFSET:STRING=${Slicer_MAIN_PROJECT_WC_COMMIT_COUNT_OFFSET}
-DSLICER_CONFIGURE_VERSION_HEADER=1
-P ${CMAKE_CURRENT_LIST_FILE}
COMMENT "Configuring vtkSlicerVersionConfigure.h"
)
return()
endif()
# --------------------------------------------------------------------------
# Configure header
# --------------------------------------------------------------------------
include(${Slicer_CMAKE_DIR}/SlicerVersion.cmake)
# Variables expected to be set by 'SlicerVersion' module.
set(expected_defined_vars
Slicer_BUILDDATE
Slicer_VERSION
Slicer_VERSION_FULL
Slicer_REVISION
Slicer_WC_REVISION
Slicer_WC_REVISION_HASH
Slicer_WC_URL
Slicer_MAIN_PROJECT_BUILDDATE
Slicer_MAIN_PROJECT_VERSION
Slicer_MAIN_PROJECT_VERSION_FULL
Slicer_MAIN_PROJECT_REVISION
Slicer_MAIN_PROJECT_WC_REVISION
Slicer_MAIN_PROJECT_WC_REVISION_HASH
Slicer_MAIN_PROJECT_WC_URL
)
foreach(var ${expected_defined_vars})
if(NOT DEFINED ${var})
message(FATAL_ERROR "${var} is mandatory")
endif()
endforeach()
configure_file(
${Slicer_SOURCE_DIR}/CMake/vtkSlicerVersionConfigure.h.in
${Slicer_BINARY_DIR}/vtkSlicerVersionConfigure.h
)