build.gradle

plugins {
    id 'de.dfki.mary.component' version '0.3.1'
    id 'maven-publish'
    id 'signing'
}

group 'de.dfki.mary'
version '0.2.0-SNAPSHOT'
description 'Lower Sorbian language component for MaryTTS'
ext {
    url = 'https://github.com/marytts/marytts-lang-dsb'
    isReleaseVersion = !version.endsWith("SNAPSHOT")
}

marytts {
    component {
        name = 'LowerSorbian'
        packageName = 'marytts.language.dsb'
        configBaseClass = 'LanguageConfig'
        config from: 'component.yaml'
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation group: 'org.apache.commons', name: 'commons-csv', version: '1.9.0'
    runtimeOnly group: 'de.dfki.mary', name: 'marytts-lexicon-dsb', version: '0.1.1'
}

java {
    withSourcesJar()
    withJavadocJar()
}

tasks.register('run', JavaExec) {
    classpath = sourceSets.main.runtimeClasspath
    mainClass.set 'marytts.server.Mary'
    systemProperties << ['log4j.logger.marytts': 'DEBUG,stderr']
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            pom {
                name = project.name
                description = project.description
                url = project.url
                licenses {
                    license {
                        name = 'GNU Lesser General Public License v3.0 only'
                        url = 'https://spdx.org/licenses/LGPL-3.0-only.html'
                    }
                }
                developers {
                    developer {
                        id = 'psibre'
                        name = 'Ingmar Steiner'
                    }
                    developer {
                        id = 'aStereoID'
                        name = 'Astrid Schmiedel'
                    }
                    developer {
                        id = 'JMK-CB'
                        name = 'Jan Meschkank'
                    }
                }
                scm {
                    connection = 'scm:git:https://github.com/marytts/marytts-lang-dsb.git'
                    developerConnection = 'scm:git:ssh://git@github.com:marytts/marytts-lang-dsb.git'
                    url = project.url
                }
            }
        }
    }
    repositories {
        maven {
            name 'OSSRH'
            url isReleaseVersion ? 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
                    : 'https://oss.sonatype.org/content/repositories/snapshots'
            credentials(PasswordCredentials)
        }
    }
}

signing {
    required { isReleaseVersion }
    sign publishing.publications.mavenJava
}

tasks.withType(Sign).configureEach {
    onlyIf { isReleaseVersion }
}