build.gradle

buildscript {
    repositories {
        gradlePluginPortal()
        mavenCentral()
    }

    dependencies {
        classpath 'com.palantir.gradle.externalpublish:gradle-external-publish-plugin:1.11.0'
        classpath 'com.palantir.javaformat:gradle-palantir-java-format:1.0.1'
        classpath 'com.palantir.gradle.consistentversions:gradle-consistent-versions:2.21.0'
        classpath 'com.palantir.gradle.conjure:gradle-conjure:4.27.0'
        classpath 'com.palantir.gradle.gitversion:gradle-git-version:0.12.3'
        classpath 'com.palantir.launchconfig:gradle-launch-config-plugin:1.2.0'
        classpath 'gradle.plugin.org.inferred:gradle-processors:3.7.0'
    }
}

apply plugin: 'com.palantir.external-publish'
apply plugin: 'com.palantir.consistent-versions'
apply plugin: 'com.palantir.git-version'

allprojects {
    apply plugin: 'com.palantir.java-format'
    group 'com.palantir.conjure.examples'
    version gitVersion()

    repositories {
        mavenCentral()
    }

}

configure(subprojects - project(':recipe-example-api')) {
    apply plugin: 'java'
    apply plugin: 'org.inferred.processors'

    sourceCompatibility = 11

    tasks.withType(JavaCompile) {
        options.compilerArgs += ['-Werror']
    }

    test {
        useJUnitPlatform()
    }
}