settings.gradle

pluginManagement {
    // Include the build-logic project first, otherwise the settings plugin from BunnyAndroidApi will mess with the classpath of build-logic
    // and break composite builds for it.
    includeBuild('build-logic')

    repositories {
        mavenCentral()
        google()
        gradlePluginPortal()

        maven {
            url "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
}

plugins {
    id "com.gradle.develocity" version "3.18.1"
}

develocity {
    buildScan {
        def isCi = providers.environmentVariable("CI").isPresent() ||
                providers.systemProperty("CI").isPresent() ||
                providers.gradleProperty("CI").isPresent()

        if (isCi) {
            publishing.onlyIf { true }
            uploadInBackground = false
        }

        termsOfUseUrl = "https://gradle.com/terms-of-service"
        termsOfUseAgree = "yes"
    }
}

rootProject.name = 'kotlin-inject-anvil'

include ':compiler'
include ':compiler-utils'
include ':runtime'
include ':runtime-optional'
include ':sample:app'
include ':sample:lib'