build.gradle

plugins {
    id 'base'
    id 'fabric-loom' version '1.8-SNAPSHOT'
    id 'maven-publish'
    id 'com.modrinth.minotaur' version '2.+'
}

version = project.mod_version
group = project.maven_group

if (stonecutter.current.isActive) {
    rootProject.tasks.register("buildActive") {
        group = "project"
        dependsOn(tasks.named("build"))
    }

    rootProject.tasks.register("runClientActive") {
        group = "project"
        dependsOn(tasks.named("runClient"))
    }
}

modrinth {
    token = project.modrinth_token
    projectId = 'TBQr8ROh'
    versionNumber = "${project.version}+${stonecutter.current.version}"
    versionName = project.version
    changelog = rootProject.file("CHANGELOG.md").text
    uploadFile = remapJar
    gameVersions = Arrays.asList(supported_versions.split(','))
    dependencies {
        required.project 'fabric-api'
        required.version 'cloth-config', "${clothconfig_version}+fabric"
        required.version 'noxesium', noxesium_version
        optional.version 'modmenu', modmenu_version
    }
    syncBodyFrom = rootProject.file("README.md").text
    debugMode = project.version.contains("-dev")
}

base {
    archivesName = project.archives_base_name
}

repositories {
    // Add repositories to retrieve artifacts from in here.
    // You should only use this when depending on other mods because
    // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
    // See https://docs.gradle.org/current/userguide/declaring_repositories.html
    // for more information about repositories.

    maven { url "https://maven.shedaniel.me/" }
    maven { url "https://maven.terraformersmc.com/releases/" }
    maven { url "https://maven.noxcrew.com/public/" }
    maven { url "https://maven.enginehub.org/repo/" }

    exclusiveContent {
        forRepository {
            maven {
                name = "Modrinth"
                url = "https://api.modrinth.com/maven"
            }
        }
        filter {
            includeGroup "maven.modrinth"
        }
    }
}

loom {
    accessWidenerPath = getRootProject().file("src/main/resources/mccinametagmod.accesswidener")

    runConfigs.all {
        ideConfigGenerated true // Run configurations are not created for subprojects by default
    }
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API. This is technically optional, but you probably want it anyway.
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    modApi "me.shedaniel.cloth:cloth-config-fabric:${clothconfig_version}"
    modApi "com.terraformersmc:modmenu:${modmenu_version}"
    modApi "com.noxcrew.noxesium:fabric:${noxesium_version}"
}

processResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

def targetJavaVersion = 21
tasks.withType(JavaCompile).configureEach {
    it.options.release = 21
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"
}

java {
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    // withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.base.archivesName.get()}" }
    }
}

remapJar {
    afterEvaluate {
        archiveFileName = "${project.base.archivesName.get()}-${project.version}+${stonecutter.current.version}.jar"
    }
}

// configure the maven publication
publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archives_base_name
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.
    }
}