-
-
Notifications
You must be signed in to change notification settings - Fork 47
/
Copy pathsmudge.el
207 lines (179 loc) · 7.94 KB
/
smudge.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
;;; smudge.el --- Control the Spotify app -*- lexical-binding: t; -*-
;; Copyright (C) 2014-2025 Daniel Martins
;; Keywords: multimedia, music, spotify, smudge
;; Package: smudge
;; Package-Requires: ((emacs "27.1") (simple-httpd "1.5.1") (request "0.3") (oauth2 "0.16"))
;; Version: 1.0.0
;; Homepage: https://github.com/danielfm/smudge
;; SPDX-License-Identifier: GPL-3.0-or-later
;;; Commentary:
;; This mode requires at least GNU Emacs 27.1
;; Before using this mode, first go the Spotify Web API console
;; <https://developer.spotify.com/my-applications> and create a new application,
;; adding <http://localhost:8080/smudge-callback> as the redirect URI (or
;; whichever port you have specified via customize).
;; After requiring `smudge', make sure to define the client id and client
;; secrets, along with some other important settings.
;;; Code:
(when (version< emacs-version "27.1")
(error "Smudge requires at least GNU Emacs 27.1"))
(require 'subr-x)
(require 'json)
(require 'tabulated-list)
(require 'easymenu)
(require 'smudge-api)
(require 'smudge-track)
(require 'smudge-playlist)
(require 'smudge-device-select)
(require 'smudge-controller)
(require 'smudge-remote)
(smudge-when-darwin (require 'smudge-apple))
(smudge-when-gnu-linux (require 'smudge-dbus))
(require 'smudge-connect)
(defgroup smudge nil
"Smudge Spotify client."
:version "0.0.1"
:group 'multimedia)
;;;###autoload
(defun smudge-track-search (query)
"Search for tracks that match the given QUERY string."
(interactive "sSpotify Search (Tracks): ")
(let ((buffer (get-buffer-create (format "*Track Search: %s*" query))))
(with-current-buffer buffer
(smudge-track-search-mode)
(smudge-track-search-update query 1))))
;;;###autoload
(defun smudge-playlist-search (query)
"Search for playlists that match the given QUERY string."
(interactive "sSpotify Search (Playlists): ")
(let ((buffer (get-buffer-create (format "*Playlist Search: %s*" query))))
(with-current-buffer buffer
(smudge-playlist-search-mode)
(smudge-playlist-search-update query 1))))
;;;###autoload
(defun smudge-recently-played ()
"Display recently played tracks."
(interactive)
(let ((buffer (get-buffer-create "*Recently Played*")))
(with-current-buffer buffer
(smudge-track-search-mode)
(smudge-track-recently-played-tracks-update 1))))
;;;###autoload
(defun smudge-my-library ()
"Display the songs saved in the current user's Liked Songs."
(interactive)
(let ((buffer (get-buffer-create "*Liked Songs*")))
(with-current-buffer buffer
(smudge-track-search-mode)
(smudge-track-my-library-update 1))))
;;;###autoload
(defun smudge-my-playlists ()
"Display the current user's playlists."
(interactive)
(smudge-api-current-user
(lambda (user)
(smudge-user-playlists (smudge-api-get-item-id user)))))
;;;###autoload
(defun smudge-user-playlists (user-id)
"Display the public playlists of the given user with USER-ID."
(interactive "sSpotify User ID: ")
(let ((buffer (get-buffer-create (format "*Playlists: %s*" user-id))))
(with-current-buffer buffer
(smudge-playlist-search-mode)
(smudge-playlist-user-playlists-update user-id 1))))
;;;###autoload
(defun smudge-create-playlist (name public)
"Create an empty playlist owned by the current user.
Prompt for the NAME and whether it should be made PUBLIC."
(interactive
(list (read-string "Playlist name: ")
(y-or-n-p "Make the playlist public? ")))
(if (string= name "")
(message "Playlist name not provided; aborting")
(smudge-api-current-user
(lambda (user)
(smudge-api-playlist-create
(smudge-api-get-item-id user)
name
public
(lambda (new-playlist)
(if new-playlist
(message "Playlist '%s' created" (smudge-api-get-item-name new-playlist))
(message "Error creating the playlist"))))))))
(defalias 'smudge-command-map
(let ((map (make-sparse-keymap)))
(define-key map (kbd "SPC") '("smudge/play-pause" . smudge-controller-toggle-play))
(define-key map (kbd "b") '("smudge/previous-track" . smudge-controller-previous-track))
(define-key map (kbd "n") '("smudge/next-track" . smudge-controller-next-track))
(define-key map (kbd "d") '("smudge/select-device" . smudge-select-device))
(define-key map (kbd "r") '("smudge/toggle-repeat" . smudge-controller-toggle-repeat))
(define-key map (kbd "s") '("smudge/toggle-shuffle" . smudge-controller-toggle-shuffle))
(define-key map (kbd "p") '("smudge/playlists" . smudge-playlists))
(define-key map (kbd "t") '("smudge/tracks" . smudge-tracks))
(define-key map (kbd "v") '("smudge/volume" . smudge-volume))
map)
"Keymap for Spotify commands after \\='smudge-keymap-prefix\\='.")
(defalias 'smudge-playlists
(let ((map (make-sparse-keymap)))
(define-key map (kbd "m") '("smudge/my-playlists" . smudge-my-playlists))
(define-key map (kbd "u") '("smudge/user-playlists" . smudge-user-playlists))
(define-key map (kbd "s") '("smudge/search-playlists" . smudge-playlist-search))
(define-key map (kbd "c") '("smudge/create-playlists" . smudge-create-playlist))
map)
"Playlist-related bindings.")
(defalias 'smudge-tracks
(let ((map (make-sparse-keymap)))
(define-key map (kbd "s") '("smudge/search-tracks" . smudge-track-search))
(define-key map (kbd "r") '("smudge/recently-played" . smudge-recently-played))
(define-key map (kbd "l") '("smudge/save-to-library" . smudge-save-playing-track-to-library))
(define-key map (kbd "k") '("smudge/remove-from-library" . smudge-remove-playing-track-from-library))
map)
"Track-related bindings.")
(defalias 'smudge-volume
(let ((map (make-sparse-keymap)))
(define-key map (kbd "m") '("smudge/mute-unmute" . smudge-controller-volume-mute-unmute))
(define-key map (kbd "u") '("smudge/volume-up" . smudge-controller-volume-up))
(define-key map (kbd "d") '("smudge/volume-down" . smudge-controller-volume-down))
map)
"Spotify player volume bindings.")
(easy-menu-add-item nil '("Tools")
'("Smudge"
["Play/Pause" smudge-controller-toggle-play]
["Previous Track" smudge-controller-previous-track]
["Next Track" smudge-controller-next-track]
"--"
["Select Playing Device" smudge-select-device]
["Mute/Unmute" smudge-controller-volume-mute-unmute]
"--"
["Shuffle" smudge-controller-toggle-shuffle]
["Repeat" smudge-controller-toggle-repeat]
"--"
["Search Tracks..." smudge-track-search]
["My Playlists" smudge-my-playlists]
["User Playlists..." smudge-user-playlists]
["Search Playlists..." smudge-playlist-search]
["Create Playlist..." smudge-create-playlist]
"--"
["Smudge Remote Mode" global-smudge-remote-mode :style toggle :selected global-smudge-remote-mode]))
(defun smudge-remote-popup-menu ()
"Popup menu when in smudge-remote-mode."
(interactive)
(popup-menu
'("Smudge"
["Play/Pause" smudge-controller-toggle-play]
["Previous Track" smudge-controller-previous-track]
["Next Track" smudge-controller-next-track]
"--"
["Select Device" smudge-select-device]
["Mute/Unmute" smudge-controller-volume-mute-unmute]
"--"
["Shuffle" smudge-controller-toggle-shuffle]
["Repeat" smudge-controller-toggle-repeat]
"--"
["Search Tracks..." smudge-track-search]
["My Playlists" smudge-my-playlists]
["User Playlists..." smudge-user-playlists]
["Search Playlists..." smudge-playlist-search]
["Create Playlist..." smudge-create-playlist])))
(provide 'smudge)
;;; smudge.el ends here