build.gradle

buildscript {
    repositories {
        jcenter()
        maven { url = "http://files.minecraftforge.net/maven" }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}
apply plugin: 'net.minecraftforge.gradle.forge'

version = "${version}"
group = "com.dizzyd"
archivesBaseName = "coregen"

sourceCompatibility = targetCompatibility = '1.8' // Need this here so eclipse task generates correctly.
compileJava {
    sourceCompatibility = targetCompatibility = '1.8'
}

minecraft {
    version = "1.12.2-14.23.5.2781"
    runDir = "run"
    
    // the mappings can be changed at any time, and must be in the following format.
    // snapshot_YYYYMMDD   snapshot are built nightly.
    // stable_#            stables are built at the discretion of the MCP team.
    // Use non-default mappings at your own risk. they may not always work.
    // simply re-run your setup task after changing the mappings to update your workspace.
    mappings = "snapshot_20171003"
    // makeObfSourceJar = false // an Srg named sources jar is made by default. uncomment this to disable.
}

configurations {
    shade
    compile.extendsFrom shade
}

dependencies {
    shade "com.typesafe:config:1.3.3"
    shade "com.github.davidmoten:rtree:0.8.6"
    shade "com.github.davidmoten:flatbuffers-java:1.3.0.1"
    shade "org.mozilla:rhino:1.7.10"
}

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
        
    // copy everything else except the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

jar {
    configurations.shade.each { dep ->
        from(project.zipTree(dep)) {
            exclude 'META-INF', 'META-INF/**'
            exclude 'org/mozilla/javascript/tools/**'
        }
    }
}

reobfJar {
    addExtraSrgLine "PK: com/typesafe/config coregen/shade/com/typesafe/config"
    addExtraSrgLine "PK: rx coregen/shade/rx"
//    addExtraSrgLine "PK: org/mozilla/javascript coregen/shade/javascript"
//    addExtraSrgLine "PK: org/mozilla/classfile coregen/shade/classfile"
    addExtraSrgLine "PK: com/github/davidmoten/rtree coregen/shade/rtree"
}