Explicit error sets

[jcollie]

OK, I'm not sure if this is cursed or blursed. I can't think of any other way to create a new error set that merges two or more error sets except for one error.

--- a/src/os/TempDir.zig
+++ b/src/os/TempDir.zig
@@ -20,8 +20,25 @@ parent: Dir,
 /// name call the name() function.
 name_buf: [TMP_PATH_LEN:0]u8,

+pub const Error = e: {
+    var count = 0;
+    const errs = std.fs.Dir.OpenError || std.fs.Dir.MakeError;
+    for (@typeInfo(errs).ErrorSet.?) |e| {
+        if (!std.mem.eql(u8, e.name, "PathAlreadyExists")) count += 1;
+    }
+    var s: [count]std.builtin.Type.Error = undefined;
+    var index = 0;
+    for (@typeInfo(errs).ErrorSet.?) |e| {
+        if (!std.mem.eql(u8, e.name, "PathAlreadyExists")) {
+            s[index] = e;
+            index += 1;
+        }
+    }
+    break :e @Type(.{ .ErrorSet = &s });
+};
+
 /// Create the temporary directory.
-pub fn init() !TempDir {
+pub fn init() Error!TempDir {
     // Note: the tmp_path_buf sentinel is important because it ensures
     // we actually always have TMP_PATH_LEN+1 bytes of available space. We
     // need that so we can set the sentinel in the case we use all the

[mitchellh]

That's pretty much what you have to do.

Instead of the double for loops I usually just make an array of worst case size and then maintain a separate var count and then slice it at the end.

[jcollie]

Is this the sort of thing (with the single loop) that you'd like to see in Ghostty if we can get more explicit error returns?

[mitchellh]

Its hard to say without seeing a larger context around it, but I will say that sometimes you do have to jump through some hoops to get explicit error sets working particularly around cross-platform code.

[jcollie]

Yeah, I don't know if this was the best place to start in the code, it just happened to be where I was looking at when I decided to find out how to construct such an error set.