build.gradle

//
// Gradle build for Nearenough
//
// Copyright (c) 2017-2018 int08h LLC. All rights reserved.
//

plugins {
    id 'java'
    id 'eclipse'
    id 'idea'
    id "org.sonarqube" version "2.8"
}

repositories {
    jcenter()
}

dependencies {
    compile 'io.netty:netty-all:4.1.43.Final'

    compile 'net.i2p.crypto:eddsa:0.3.0'

    testCompile 'junit:junit:4.12'
}

// Suppress "Illegal reflective access" warnings on Java 9+
def shouldAddOpens = JavaVersion.current().java9Compatible

// Runs the NIO example
task nioExample(type: JavaExec) {
    classpath = sourceSets.main.runtimeClasspath
    main = 'nearenough.examples.NioClient'

    if (shouldAddOpens) {
        jvmArgs = ['--add-opens', 'java.base/java.nio=ALL-UNNAMED']
    }
}

// Runs the Netty example
task nettyExample(type: JavaExec) {
    classpath = sourceSets.main.runtimeClasspath
    main = 'nearenough.examples.NettyClient'

    if (shouldAddOpens) {
        jvmArgs = [
            '--add-opens', 'java.base/sun.nio.ch=ALL-UNNAMED',
            '--add-opens', 'java.base/java.nio=ALL-UNNAMED'
        ]
    }
}