-
Notifications
You must be signed in to change notification settings - Fork 14
/
Copy pathcfd.PRG
8048 lines (6846 loc) · 258 KB
/
cfd.PRG
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
****************************************************************************
** CFD.PRG
**
** Libreria de clases para generacion del Comprobante Electronico Digital
** en Mexico, segun las indicaciones del SAT
**
** Autores: Victor Espina / Arturo Ramos / Baltazar Moreno
**
** Version: 3.8
**
** Basado en colaboraciones de:
** - Halcon Divino
** - Carlos Figueroa
** - DanielCB
**
**
** NOTA IMPORTANTE #1
** A partir de la version 2.4 de esta libreria, el metodo Sellar() de la clase
** CFDComprobante valida que el certificado sea valido y este vigente. Si el
** certificado no pasa estas pruebas, el metodo no generara el sello y devolvera
** .F., almacenando en la propiedad CFDConf.ultimoError la descripcion de problema.
**
** Se puede obviar esta validacion almacenando .T. en la propiedad CFDConf.modoPruebas
**
**
** NOTA IMPORTANTE #2
** Si esta teniendo problemas con las funciones o metodos que invocan OpenSSL
** y su carpeta SSL esta ubicada en una ruta que contiene nombres largos o
** espacios en blanco, puede que el problema se deba a que la creacion de nombres
** cortos (8.3) esta desactivada a nivel de Windows. Por favor, revise en su
** Register la clave:
**
** HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\FileSystem\NtfsDisable8dot3NameCreation
**
** y asegurese que su valor sea cero. Si esta en "1", haga el cambio y reinicie
** su sistema. Si el valor ya estaba en cero o el problema persiste luego de
** cambiarlo a cero, mueva su carpeta SSL a una ruta que no contenga nombres de
** mas de 8 caracteters ni contenga espacios en blanco.
**
**
** NOTA IMPORTANTE #3
** La libreria OpenSSL requiere de las librerias de runtime de VC++ 2008, la cual
** puede no estar disponible en algunos equipos, causando problemas con el sellado
** de los CFDs (y todas las demas funciones de la libreria que dependan de OpenSSL).
**
** Para solucionar este problema, descargue e instale las librerias necesarias desde
** este link (cortesia de Carlos Omar Figueroa):
**
** http://www.microsoft.com/downloads/en/details.aspx?familyid=9B2DA534-3E03-4391-8A4D-074B9F2BC1BF&displaylang=en
**
**
** NOTA IMPORTANTE #4
** Para generar la representación impresa del CFD se utiliza el procedimiento CFDToCursor() para
** pasar los nodos del XML a cursores y así poder reportarlos. Por regla los saltos de línea y
** retornos de carro no estan permitidos en un XML, entonces que pasa si hay un concepto en el
** comprobante donde sea muy importante mostrar información en líneas adicionales sobre todo para
** coneptos muy largos donde se desglozan condiciones u otra información.
**
** Para solucionar este problema se incluye un parametro adicional a CFDPrint() con el que podemos
** indicar que se va a remplazar los conceptos obtenidos por CFDToCursor() en el cursor QCO por los
** que estan en el entorno de datos; aquí se supone que en el entorno de datos tenemos un cursor
** llamado curConceptos con los conceptos del comprobante tal como se guardaron en la base de datos.
**
**
** NOTA IMPORTANTE #5
** A partir de la version 3.2 la propiedad Addenda de la clase CFDComprobante cambia su funcionamiento
** completamente, por lo que ya no es compatible con su uso en versiones anteriores. Ver archivo
** "ADDENDAS.TXT" para informacion sobre como generar addendas.
**
**
** NOTA IMPORANTE #6
** En algunos casos puede suceder que al intentar utilizar la clase CFD o ejecutar los programas de
** prueba, se obtenga el siguiente mensaje de error:
**
** SCRIPTING.FILESYTEM.OBJECT not found
**
** Este error puede deberse a una actualizacion de Windows que fallo al registrar la libreria
** SCRRUN.DLL. Para solucionar el problema, por favor siga estos pasos (cortesia de Marco Garcia):
**
** a) Abra una ventana de comandos (Inicio->Ejecutar->cmd.exe)
** b) En la ventana de comandos, escriba los siguientes comandos (pulse ENTER luego de escribir cada linea):
** CD \windows\system32
** regsvr32 scrrun.dll
**
**
****************************************************************************
** H I S T O R I A L D E M O D I F I C A C I O N E S
****************************************************************************
**
** ARC Feb 14, 2014 - Correccion al crear comprobante no incluia el nodo CuentaPredial
** - Cambios en CFDtoCursor para guardar el dato de la cuenta predial en cConcepto.nopredio
** - Cambios en CFDToCursor para leer y guardar los datos del complemento iedu:instEducativas en
** los campos ieduNomAl, ieduCURP, ieduNivEd, ieduRVOE, ieduRFCPa del cursor de conceptos
**
** VES Ago 23, 2012 - Correccion al crear el XML cuando no se indica valor en la propiedad opcional "Aduana"
**
** VES Ago 3, 2012 - Correccion al crear el XML con mas de un complemento de concepto
**
** VES Jul 30, 2012 - Nueva version 3.7
** = Nueva funcion CFDCreateQR() basada en el DLL barcodelibrary.dll
**
** VES Jul 27, 2012 - Nuevas columnas IANUMERO, IAFECHA e IAADUANA en cursor QCO
** - Cambios en funcion CFDTOCURSOR para llenar columnas IANUMERO, IAFECHA, IAADUANA e INFOADUANA
** - Se elimino el mensaje de debug "Cached!"
**
** VES Jul 25, 2012 - Inclusion de la libreria Print2PDF de Paul James ([email protected])
** - Nueva propiedad "usarPrint2PDF" en clase CFDConf
** - Cambios en CFDPrint para usar la libreria Print2PDF para generar PDFs
**
** VES Jul 21, 2012 - Cambio en CFDPrint() para que retorne .T. o .F. al mandar a generar un PDF
**
** ARC Jun 13, 2012 - Se modifica CFDToCursor para que reciba CFD 2.2 y CFDI 3.2
** - Se modifica CFDPrint para contener los datos del régimen fiscal dentro
** del cursor general QDG en el campo REGSFIS para la representación impresa
**
** VES Abr 27, 2012 - Nuevos parametros opcionales pcMoneda, pcPrefijo y pcSufijo en funcion
** CFDNTOCESP() (Colaboracion de DanielCB)
** - Nuevas propiedades NTOCMoneda, NTOCPrefijo y NTOCSufijo en objeto CFDConf
**
** VES Feb 2, 2012 - Correccion de error en metodo Validate de CFDVersionsEnum
** - Actualizacion de la propiedad Version de CFDConf
**
** ARC Ene 14, 2012 - Se repara error en CFDVersionsEnum que no permitia generar CFDI 3.0
**
** VES Ene 12, 2012 - Nueva version 3.6
** - Modificacion a la funcion CFDExtraerCadenaOriginal a fin de usar la version
** indicada en el comprobante y NO la indicada en CFDConf.XMLVersion a fin de
** determinar el XSLT a utilizar para generar la cadena original.
** - Nueva propiedad RegimenFiscal en CFDPersona
** - Nuevas clases CFDRegimenFiscalCollection y CFDRegimenFiscal
** - Nueva propiedad Complemento en clase CFDConcepto
** - Cambios en metodo CrearXML() para implementar las nuevas propiedades RegimenFiscal y Complemento (Concepto)
**
** ARC Ene 03, 2012 - nombre de emisor es opcional en 2.2 y 3.2
** - nombre de receptor es opcional en todas las versiones
** - domicilio de receptor es opcional en 3.0, 2.2 y 3.2
**
** VES Dic 30, 2011 - Nueva enumeracion CFDVersions (CFDVersionsEnum)
** - Se cambio el objeto CFDConf de buffer a instancia de clase para poder implementar
** un validador para la propiedad XMLVersion.
** - La propiedad Version de CFDConf ahora es solo-lectura.
** - Evento Assign en propiedad Version de CFDComprobante y XMLVersion de CFDConf
** para verificar que el valor indicado sea correcto.
** - Modificacion en constructor de CFDComprobante para asignar por omision el valor
** de CFDConf.XMLVersion a la propiedad Version.
**
**
** ARC Dic 27, 2011 - Beta de la generacion de comprobantes en version 2.2 y 3.2
** - Se modifica CFDExtraerCadenaOriginal para adaptarla a las versiones 2.2 y 3.2
** - Se modifica CFDValidarXML para adaptarla a las versiones 2.2 y 3.2
**
** ARC Dic 20, 2011 - Version 3.5
** - Inician los cambios para adaptar a las reformas 'no oficiales' para los formatos
** de comprobantes 2.2 y 3.2
** - Se cambia la condicion para validar si se crea el nodo DomiciolioFiscal del Emisor,
** se verificaba que exista el atributo calle, este atributo es opcional, puede no estar
** y si requerir el nodo, el unico atributo requerido en el nodo es Pais.
** - Se crea la clase CFDRegimenFiscal para el nodo RegimenFiscal del Emisor requerido en
** las versiones 2.2 y 3.2
**
** VES Nov 21, 2011 - Nuevo metodo getProp() en clase XMLNodeClass
**
** VES Nov 16, 2011 - Cambios en el metodo CrearXML y la funcion CFDToCursor para eliminar
** espacios en blanco dentro del valor RFC
**
** VES Nov 14, 2011 - Cambios en metodo CrearXML para incluir el manejo de addendas
** - Nuevas propiedades nodeName y schemaLocation de la clase ICFDAddenda
**
** VES Nov 12, 2011 - Version 3.4
** - Nuevo uso de la propiedad CFDAddenda de CFDComprobante
** - Eliminacion de la propiedad CFDAddendas y la clase homonima, introducidos en Oct 10, 2011
** - Mejoras en el metodo CrearXML() para incluir la generacion del nodo Addenda y/o Comprobante
** - Nueva funcion CFDBuffer()
**
** VES Nov 11, 2011 - Version 3.3
** - Nuevas propiedades nameSpace, nodeName y createNodeLInks en clase XMLNOdeClass
** - Nueva propiedad createNodeLinks en clase XMLParser, para permitir multiples nodos hermanos con el mismo nombre
** - Nuevo metodo ToString() en clase XMLParser
** - Mejoras en metodos Open(), Save() e iSaveNode() en clase XMLParser para manejar NameSpaces
** - Mejoras en metodo AddNode() de XMLNodeClass para manejar NameSpaces
** - Mejoras en el metodo CrearXML() de la clase CFD para implementar las mejoras en las clases XMLParser y XMLNodeClass
**
** VES Oct 10, 2011 - Nueva clase ICFDAddenda
** - Nueva clase CFDAddendas
** - Nueva propiedad Addendas en CFDComprobante
** - Cambio en CFDPrint() para sustituir uso de clausula READWRITE para matener la compatibilidad con versiones anteriores de VFP
**
** BMJ Oct 7, 2011 - Nueva función CFDGoogleQR() que genera un archivo PNG con el QR del CFDI
** Parámetros: tcDato, que es la cadena que contendrá codificada el CBB.
** Ésta función se ayuda de otra: CFDGetEscaped() la cual convierte los
** caracteres recibidos como parámetro recibido que no son soportados en
** una URL por su secuencia de escape.
**
** ARC Oct 7, 2011 - Nueva función CFDEnviarPorCorreoAdjuntos para envier por correo
** Parámetros: pcDestinatario, pcAsunto, pcCuerpo, pcCFD, pcPDF
** Envia CFD y PDF por correo. A diferencia de CFDEnviarPorCorreo esta permite
** adjuntar el PDF ya creado lo cuál es útil cuando se utilizan diferente
** formatos para la representación impresa o para enviar comprobantes
** que no generó nuestro sistema como puede ser el caso de algunos PACs
** que junto con el timbre regresan el PDF
**
** ARC Oct 6, 2011 - Nueva función CFDCadenaCBB(pcArchivoXML) para obtener la cadena
** necesaria para generar el CBB para la representación
** impresa de un CFDI desde un XML timbrado
**
** ARC Ago 7, 2011 - Adaptaciones en CFDValidarXML para poder validar CFDI
**
** ARC Ago 6, 2011 - Nueva propiedad XMLVersion de la clase CFDConf
** - Nueva propiedad incluirBOM de la clase CFDConf
** - Nuevo atributo Moneda de la clase CFDComprobante para CFDI
** - Nuevo atributo TipoCambio de la clase CFDComprobante para CFDI
**
** ARC Jul 13, 2011 - Se modifica en CrearXML() que se incluya el BOM en el XML
**
** VES Ene 10, 2011 - Cambios en formato CFD
**
** VES Ene 6, 2011 - Correcciones varias en funcion CrearFactura().
** - Se incluyeron los atributos opcionales totalImpuestosRetenidos
** y totalImpuestosTrasladados al generar el XML.
**
** VES Ene 5, 2011 - Nueva funcion CFDProbarOpenSSL()
** - Nueva propiedad formatoImpresion de CFDConf
** - Modificaciones varias en la funcion CFDPrint()
** - Mejoras en el metodo Sellar() de CFDComprobante
**
** VES Ene 4, 2011 - Se reprogramo el metodo _GenCadenaOriginal de CFDComprobante
** para utilizar la funcion CFDExtraerCadenaOriginal()
** - Nuevo objeto CFDCertificado
** - Nueva propiedad "ultimoCertificado" de la clase CFDConf
** - Nueva funcion de cache en el metodo LeerCertificado() de la
** clase CFDComprobante.
** - Se incluyo una nueva seccion de retenciones en el formato CFD.FRX
** - Modificaciones para permitir la extraccion de la cadena original
** en modo offline
**
** VES Ene 3, 2011 - Se corrigio un problema en la rutina CFDPrint() que dejaba
** la impresora PDFCreator pre-configurada para auto-save.
** - Se incluyo una descripción por defecto cuando se indica
** un descuento pero no un motivo.
** - Correccion menor en la funcion CFDValidarXML().
** - Modificacion en _FixStr() para eliminar los saltos de linea.
**
** VES Dic 30, 2010 - Se renombre la funcion NTOCESP() por CFDNTOCESP()
** - Nueva clase CFDReporteMensual
** - Nueva propiedad ubicacionRepositorio en CFDConf
**
** VES Dic 29, 2010 - Nueva funcion CFDVigenciaCert().
** - Nueva propiedad UltimoError en CFDConf
** - Nueva propiedad modoPruebas en CFDConf
** - Nueva propiedad Version en CFDConf
** - Nueva funcion CFDLeerCertificado()
** - Cambios en metodo LeerCertificado() de CFDComprobante
** - Cambios en el metodo Sellar() de CFDComprobante para
** verificar la valide del certificado antes de sellar
** - Nueva funcion CFDValidarXML()
** - Nueva funcion CFDGenerarSello()
** - Nueva propiedad "MetodoDigest" de CFDConf
** - Correcciones varias en CFDExtraerCadenaOriginal()
**
** VES Dic 28, 2010 - Cambios en varias rutinas para manejar el tema
** de los nombres de archivo largos
** - Cambios en la funcion NTOCESP() para adaptarla
** a los usos en Mexico
**
** VES Dic 27, 2010 - Nueva Utilidad CFDToCursor()
** - Nueva utilidadd CFDPrint()
** - Correccion en genCadenaOriginal para el caso de
** - importe cero en impuestos
** - Nueva utilidad CFDExtraerCadenaOriginal()\
** - Nuevo procedure CFDInit()
** - Nuevo procedure CFDEnviarPorCorreo()
**
** VES Dic 20, 2010 Version original
**
****************************************************************************
** I N T E R F A C E
****************************************************************************
*!* LEYENDA:
*!* Clase {Clase Base}
*!* ==================
*!* +Atributo-Obligatorio [{Clase-Atributo}]
*!* -Atributo-Opcional
*!* =Propiedad [nota]
*!* @Metodo(parametros) [ = {Tipo-valor-retornado}]
*!* CFDComprobante {Custom}
*!* =======================
*!* +Version = "2.0" && Se sustituye version por Version Requerido en v.3.3 ByVigar.
*!* +Folio && Se sustituye folio por Folio Requerido en v.3.3 ByVigar.
*!* +Fecha && Se sustituye fecha por Fecha Requerido en v.3.3 ByVigar.
*!* +Sello [1] && Se sustituye sello por Sello Requerido en v.3.3 ByVigar.
*!* +noAprobacion
*!* +anoAprobacion
*!* +FormaPago && Se sustituye formadePago por FormaPago Requerido en v.3.3 ByVigar.
*!* +NoCertificado
*!* +SubTotal && Se sustituye subTotal por SubTotal Requerido en v.3.3 ByVigar.
*!* +Total
*!* +TipoDeComprobante && Se sustituye tipoDeComprobante por TipoDeComprobante Requerido en v.3.3 ByVigar.
*!* +Emisor {CFDPersona}
*!* +Receptor {CFDPersona} UsoCFDI && NUEVA PROPIEDAD usar valores del catalago sat c_UsoCFDI Requerido en v.3.3 ByVigar.
*!* +Conceptos {CFDConceptos}
*!* -Serie
*!* -Certificado
*!* -CondicionesDePago && Se sustituye condicionesDePago por CondicionesDePago Requerido en v.3.3 ByVigar.
*!* -Descuento
*!* -motivoDescuento
*!* -MetodoPago && Se sustituye MetodoPago por MetodoPago Requerido en v.3.3 ByVigar.
*!* +Impuestos {CFDImpuestos}
*!* -Addenda {ICFDAddenda}
*!* =cadenaOriginal [2]
*!* =ubicacionOpenSSL [3]
*!* @Sellar(archivo-key, password) [4]
*!* @crearXml(archivo-destino)
*!* @importarXml(archivo-origen) = {True | False}
*!* @exportarDbf(ruta-destino)
*!* @enviarPorCorreo(remitente, destinatario, asunto, texto)
*!* [1] El valor de este atributo sera llenado automaticamente por la clase al invocar el metodo Sellar()
*!* [2] Esta propiedad es de solo lectura y devuelve la cadena original en base al contenido de los atributos de la clase
*!* [3] Esta propiedad contiene la carpeta donde esta instalado el OpenSSL
*!* [4] El metodo devuelve .T. si se pudo sellar el certificado o .F. si no fue posible. La propiedad ultimoError de CFDConf
*!* contendra la explicacion de porque no se pudo sellar
*!* CFDPersona {Custom}
*!* ===================
*!* +Rfc && Se sustituye rfc por Rfc Requerido en v.3.3 ByVigar.
*!* +Nombre
*!* +domicilioFiscal {CFDDireccion} [3]
*!* -expedidoEn {CFDDireccion} [4]
*!* -RegimenFiscal {CFDRegimenFiscalCollection} [5]
*!* -UsoCFDI && Solo para receptor Obligatorio v.3.3 ByVigar.
*!* [3] En el caso del receptor, este atributo se utiliza para el atributo "Domicilio" en el XML
*!* [4] En el caso del receptor, este atrbuto no es tomado en cuenta
*!* [5] En el caso del receptor, este atributo no es tomado en cuenta
*!* CFDDireccion {Custom}
*!* =====================
*!* +Calle
*!* +Municipio
*!* +Estado
*!* +Pais
*!* +codigoPostal
*!* -noExterior
*!* -noInterior
*!* -Colonia
*!* -Localidad
*!* -Referencia
&& Nuevo y Obligatorio en Timbrado de "Pagos"
*!* CFDIRelacionados {Custom}
*!* =====================
*!* =TipoRelacion
*!* CFDIRelacionado {CFDICollection}
*!* ==============================
*!* @Add(UUID, CUUID) = {CfdiRelacionado}
*!* CFDConceptos {CFDCollection}
*!* ============================
*!* @Add(cantidad, descripcion, precioUnitario, importe) = {CFDConcepto}
*!* CFDConcepto {Custom}
*!* ====================
*!* +Cantidad
*!* +Descripcion
*!* +valorUnitario
*!* +Importe
*!* -noIdentificacion
*!* -informacionAduanera {CFDInformacionAduanera}
*!* -cuentaPredial {CFDCuentaPredial}
*!* -Complemento {ICFDAddenda}
*!* CFDInformacionAduanera {Custom}
*!* ===============================
*!* +Numero
*!* +Fecha
*!* +Aduana
*!* CFDCuentaPredial {Custom}
*!* =========================
*!* +Numero
*!* CFDRegimenFiscalCollection {CFDCollection}
*!* ==========================================
*!* @Add(regimenFiscal) = {CFDRegimenFiscal}
*!* CFDRegimenFiscal (Custom)
*!* ============================
*!* +Regimen
*!* CFDImpuestos {Custom}
*!* =====================
*!* =TotalImpuestosRetenidos
*!* =TotalImpuestosTrasladados
*!* -Retenciones {CFDRetenciones}
*!* -Traslados {CFDTraslados}
*!* CFDRetenciones {CFDCollection}
*!* ==============================
*!* @Add(impuesto, importe) = {CFDRetencion}
*!* CFDTraslados {CFDCollection}
*!* ============================
*!* @Add(impuesto, tasa, importe) = {CFDTraslado}
*!* CFDRetencion {Custom}
*!* =====================
*!* +Impuesto
*!* +Importe
*!* CFDTraslado {Custom}
*!* ====================
*!* +Impuesto
*!* +Tasa
*!* +Importe
*!* CFDAddenda {CFDCollection} (Obsoleto)
*!* ==========================
*!* @Add(nombre, valor)
*!* CFDCollection {Custom}
*!* ======================
*!* =Count
*!* =Items[1..Count]
*!* @Add(item)
*!* CFDCertificado (Custom)
*!* =======================
*!* =Valido
*!* =Vigente
*!* =Certificado
*!* ICFDAddenda [Custom]
*!* ===================
*!* -nodeName
*!* -schemaLocation
*!* -NSTag
*!* -NSUrl
*!* @ToString()
****************************************************************************
** U T I L I D A D E S
****************************************************************************
**
** CFDInit()
** Inicializacion de las distintas rutinas contenidas en la libreria. Se debe
** invocar una vez antes de acceder al resto de las clases y funciones. Este
** procedure crea un objeto publico llamado CFDConf, el cual contiene las
** siguiente propiedades configurables:
**
** Version Version actual de la libreria CFD
** OpenSSL Ubicacion del archivo OPENSSL.EXE
** SMTPServer Servidor SMTP a utilizar para el envio de correos
** SMTPPort Puerto a utilizar dentro del servidor SMTP
** SMTPUseSSL Boolean. Indica si se utilizar SSL o no para enviar el correo
** SMTPUserName Nombre del usuario con el que se autenticara la session en el servidor SMTP
** SMTPPassword Contrasena del usuario para autenticacion en el servidor SMTP
** MailSender Direccion electronica del remitente del correo
** ultimoError Contiene el texto del ultimo error ocurrido
** modoPruebas Indica si se esta trabajando en modo de pruebas
** metodoDigest Ultimo metodo utilizado para la firma del sello digital
** ubicacionRepositorio Incia la ubicacion del repositorio de CFDs
** ultimoCertificado Instancia de la clase CFDCertificado con los datos del ultimo certificado utilizado
** formatoImpresion Formato de impresion a utilizar. Por defecto es CFD.FRX
** XMLversion Define la versión del XML a crear. Por defecto es versión 2. (2 = CFD y 3 = CFDI)
** icluirBOM Agrega el BOM correspondiente a los archivos codificados en UTF-8. Por defecto es falso
**
**
** CFDOpenSSL([pcOpenSSL])
** Permite determinar si la libreria OpenSSL esta bien instalada y funciona correctamente. El parametro
** opcional pcOpenSSL permite indicar la ruta donde esta instalada la libreria OpenSSL; si no se
** indica se asume el valor de CFDConf.openSSL. La funcion retorna .T. si la libreria OpenSSL esta
** instalada y funciona correctamente, o .F. en caso contrario. Si la libreria funciona correctamente
** la funcion almacena en CFDConf.ultimoError la version actual de la libreria; si ocurrio algun error
** con la prueba, la descripcion del error ocurrido se almacena tambien en CFDConf.ultimoError.
**
**
** CFDToCursor(pcXML [,pcPrefix])
** Recibe un CFD en formato XML y genera varios cursores contentivos de los
** datos del CFD. El parametro opcion pcPrefix permite indicar el prefijo
** que se desea utilizar para los nombres de los cursores. Si no se indica
** se asume "Q". La funcion crea 5 cursores, a saber:
**
** QDG Datos generales
** QCO Conceptos
** QAD Informacion aduanala
** QRT Retenciones
** QTR Traslados
**
**
** CFDPrint(pcXML [, plPreview, plPDFMode, pcPDFTarget, plReplaceCO])
** Recibe un CFD en formato XML y genera una representacion impresora del
** mismo. El parametro opcion plPreview permite mostrar una vista previa
** del comprobante antes de imprimirlo. El parametro opcional plPDFMode permite
** indicar que se desea generar una representacion del CFD en formato PDF. Si
** se indica .T. en este parametro, se debe indicar el nombre y ubicacion del
** archivo PDF a generar en el parametro pcPDFTarget. El parametro opcional
** plReplaceCO indica que los conceptos sean reemplazados por los almacenados
** en el cursor curConceptos para poder utilizar saltos de línea y retornos
** de carro en la descripción de los conceptos ya que estos no son válidos
** en el XML.
**
** IMPORTANTE: Para utilizar la funcion de generar un CFD en formato PDF se
** requiere instalar el producto gratuito PDFCreator (www.pdfcreator.com).
**
**
** CFDExtraerCadenaOriginal(pcXML, pcRutaOpenSSL)
** Permite extraer la cadena original de un CFD indicado. El parametro
** ocRutaOpenSSL contiana la ruta completa a la carpeta donde este
** instalado el OpenSSL.EXE
**
**
** CFDEnviarPorCorreo(pcDestinatario, pcAsunto, pcTexto, pcCFD [,plAdjuntarPDF])
** Permita enviar por correo un CFD generado. Si se indica .T. en el parametro
** opcion plAdjuntarPDF, se asumira que e parametro pcCFD contiene el nombre
** de un CFD en formato XML, y se utilizara el mismo para generar una representacion
** en PDF del comprobante y se anexara tambien al correo.
**
**
** CFDValidarKeyCer(pcArchivoKEY, pcArchivoCER, pcPassword [, pcOpenSSL])
** Permite determinar si el archivp KEY corresponde con el archivo CER
** indicados. Si no se indica el parametro opcion pcOpenSSL, se asume el
** valor de la propiedad CFDConf.openSSL. La fnucion retorna .T. si los
** archivos KEY y CER son complementarios o .F. si no lo son u ocurrio algun
** error. La descripcion del ultimo error ocurrido se almacena en CFDConf.ultimoError
**
**
** CFDLeerCertificado(pcARchivoCER [,pcOpenSSL])
** Lee un certificado indicado y devuelve un objeto con informacion del mismo.
**
**
** CFDValidarXML(pcArchivoXML, pcArchivoKey, pcPassword, pcMetodo, pcOpenSSL)
** Determina si el XML indicado esta bien formado y cumple con las especificaciones
** del SAT. Adicionalmente valida que el sello este correcto.
**
**
** CFDGenerarSello(pcCadenaOriginal, pcArchivoKey, pcPassword, pcMetodo, pcOpenSSL)
** Permite generar un sello a partir de una cadena original dada.
**
** CFDEnviarPorCorreoAdjuntos(pcDestinatario, pcAsunto, pcCuerpo, pcCFD, pcPDF)
** Permite enviar correo adjuntando XML y PDF (sin regenerarlo)
**
** CFDCadenaCBB(pcArchivoXML)
** Genera la cadena para convertir a QR Code (CBB)
*****************************************************************************
#DEFINE CRLF CHR(13)+CHR(10)
#DEFINE True .T.
#DEFINE False .F.
*-- CFDInit (Procedure)
* Crea el objeto public CFDConf, el cual contiene
* configuraciones generales de uso en varios de
* los metodos y funciones de la libreria
*
* VES Dic 30, 2011
* Se aprovecha para declarar algunas enumeraciones de
* uso en la clase
*
PROCEDURE CFDInit
*
PUBLIC CFDVersions,CFDConf
CFDVersions = CREATE("CFDVersionsEnum")
CFDConf = CREATE("CFDConf")
DECLARE Sleep IN kernel32 INTEGER dwMilliseconds
DECLARE INTEGER GetShortPathName IN kernel32;
STRING lpszLongPath,;
STRING @ lpszShortPath,;
INTEGER cchBuffer
DECLARE INTEGER GenerateFile ;
IN BarCodeLibrary.dll;
STRING cData, ;
STRING cFileName
*
ENDPROC
*-- CFDVersionsEnum (Enumeracion)
* Lista de valores validos para Version
*
DEFINE CLASS CFDVersionsEnum AS Custom
*
CFD_20 = 2
CFD_22 = 22
CFDi_30 = 3
CFDi_32 = 32
CFDi_33 = 33 && Versión 3.3 ByVigar.
validVersionList = "[2][22][3][32][33]"
PROCEDURE ToString(pnVersion)
DO CASE
CASE pnVersion = THIS.CFD_20
RETURN "2.0"
CASE pnVersion = THIS.CFD_22
RETURN "2.2"
CASE pnVersion = THIS.CFDi_30
RETURN "3.0"
CASE pnVersion = THIS.CFDi_32
RETURN "3.2"
CASE pnVersion = THIS.CFDi_33 && Versión 3.3 ByVigar.
RETURN "3.3"
OTHERWISE
RETURN ""
ENDCASE
ENDPROC
PROCEDURE FromString(pcVersion)
DO CASE
CASE pcVersion = "2.0"
RETURN THIS.CFD_20
CASE pcVersion = "2.2"
RETURN THIS.CFD_22
CASE pcVersion = "3.0"
RETURN THIS.CFDi_30
CASE pcVersion = "3.2"
RETURN THIS.CFDi_32
CASE pcVersion = "3.3"
RETURN THIS.CFDi_33 && Versión 3.3 ByVigar.
OTHERWISE
RETURN 0
ENDCASE
ENDPROC
PROCEDURE ToLongString(pcVersion)
DO CASE
CASE pcVersion = THIS.CFD_20
RETURN "CFD 2.0"
CASE pcVersion = THIS.CFD_22
RETURN "CFD 2.2"
CASE pcVersion = THIS.CFDi_30
RETURN "CFDi 3.0"
CASE pcVersion = THIS.CFDi_32
RETURN "CFDi 3.2"
CASE pcVersion = THIS.CFDi_33 && Versión 3.3 ByVigar.
RETURN "CFDi 3.3"
OTHERWISE
RETURN "Valor incorrecto (" + pcVersion + ")"
ENDCASE
ENDPROC
PROCEDURE Validate(vNewVal, puCurValue)
*
LOCAL uValue
IF VARTYPE(m.vNewVal)="N"
m.vNEwVal = CFDVersions.ToString(m.vNewVal)
ENDIF
uValue = CFDVersions.FromString(m.vNewVal)
IF EMPTY(uValue)
uValue = puCurValue
MESSAGEBOX("El valor de version indicado no es correcto.",16,"CFD")
ENDIF
RETURN uValue
*
ENDPROC
*
ENDDEFINE
*-- CFDConf (Clase)
* Configuraciones generales de uso en la libreria
*
DEFINE CLASS CFDConf AS Custom
*
Version = "3.7"
OpenSSL = ""
SMTPServer = ""
SMTPPort = ""
SMTPUseSSL = .T.
SMTPAuthenticate = .T.
SMTPUserName = ""
SMTPPassword = ""
MailSender = ""
UltimoError = ""
modoPruebas = .F.
metodoDigest = "md5"
ubicacionRepositorio = ".\CFD"
ultimoCertificado = NULL
formatoImpresion = "CFD.FRX"
XMLVersion = 0
incluirBOM = .F.
NTOCMoneda = "Pesos"
NTOCPrefijo = ""
nTOCSufijo = "M.N."
usarPrint2PDF = .T.
PROCEDURE Init
THIS.Version = CFDVersions.CFDi_33
THIS.OpenSSL = ADDBS(FULLPATH(".\SSL"))
THIS.XMLVersion = CFDVersions.CFDi_33
ENDPROC
PROCEDURE Version_Assign(vNEwVal)
ENDPROC
PROCEDURE XMLVersion_Assign(vNewVal)
THIS.XMLVersion = CFDVersions.Validate(m.vNewVal, THIS.XMLVersion)
ENDPROC
*
ENDDEFINE
*-- CFDComprobante (Clase)
* Representa a un comprobante digital
*
DEFINE CLASS CFDComprobante AS Custom
*
*-- Atributos requeridos
*
* ARC Dic 20, 2011: Se agregan las nuevas versiones
*
Version = "" && VES Dic 30, 2011: Se elimino el valor por omision para establecerlo en el constructor
Folio = 0 && Versión 3.3 ByVigar.
Fecha = {} && Versión 3.3 ByVigar.
Sello = "" && Versión 3.3 ByVigar.
FormaPago = "" && Versión 3.3 ByVigar. se cambio de formadePago a FormaPago
noAprobacion = 0
anoAprobacion = 0
NoCertificado = "" && Versión 3.3 ByVigar.
SubTotal = 0.00
Total = 0.00
TipoDeComprobante = "" && Se sustituye tipoDeComprobante por TipoDeComprobante Requerido en v.3.3 ByVigar.
Emisor = NULL
Receptor = NULL
Conceptos = NULL
*-- Atributos opcionales
Serie = ""
Certificado = ""
CondicionesDePago = ""
Descuento = 0.00
motivoDescuento = ""
Impuestos = NULL
Addenda = NULL
CfdiRelacionados = NULL && Pagos UUDI Relacionados v.3.3 ByVigar
*-- Atributos CFD 2.2 y CFDI 3.2 opcionales
MontoFolioFiscalOrig = NULL
FechaFolioFiscalOrig = {}
SerieFolioFiscalOrig = NULL
FolioFiscalOrig = NULL
NumCtaPago = NULL
Moneda = NULL
TipoCambio = NULL
*-- Atributos CFD 2.2 y CFDI 3.2 requeridos
LugarExpedicion = NULL
MetodoPago = "" && ARC Dic 20, 2011: es requerido en CFD 2.2 y CFDI 3.2
*-- Propiedades
cadenaOriginal = "" && Solo-lectura
ubicacionOpenSSL = ".\SSL"
*-- Getters / Setters
PROCEDURE cadenaOriginal_Access
RETURN THIS._genCadenaOriginal()
ENDPROC
PROCEDURE cadenaOriginal_Assign(vNewVal)
ENDPROC
*-- Constructor de la clase
*
* VES Dic 30, 2011: Se incluyo el parametro opcional pnVersion
*
PROCEDURE Init(pnVersion)
*
IF PCOUNT() = 0 && Si no se indico una version, se asume la version indicada en CFDConf.XMLVersion
pnVersion = CFDConf.XMLVersion
ENDIF
THIS.Version = pnVersion
THIS.Emisor = CREATEOBJECT("CFDPersona")
THIS.Receptor = CREATEOBJECT("CFDPersona")
THIS.CfdiRelacionados = CREATEOBJECT("CfdiRelacionados")
THIS.Conceptos = CREATEOBJECT("CFDConceptos")
THIS.Impuestos = CREATEOBJECT("CFDImpuestos")
THIS.ubicacionOpenSSL = CFDConf.OpenSSL
*
ENDPROC
*-- Setter para propiedad Version
*
PROCEDURE Version_Assign(vNewVal)
LOCAL nVersion
nVersion = CFDVersions.Validate(m.vNewVal, 0)
IF nVersion > 0
THIS.Version = CFDVersions.ToString(nVersion)
ENDIF
ENDPROC
*-- Metodos
*-- _genCadenaOriginal (Metodo)
* Genera la cadena original que sirve de base para generar el sello digital. El codigo original
* pertenece al amigo Halcon Divino, y fue adaptado para el uso dentro de esta clase.
*
* VES Ene 4, 2011
* Se cambio el codigo para obtener la cadena original directametne del XML aplicando el archivo
* XSLT proporcionado por el SAT. De esta forma nos garantizamos que no haya diferencia entre
* la cadena original generada por la clase y la que genera el SAT a partir del XML, lo cual
* elimina los problemas de sellado por diferencia en la cadena original.
*
PROCEDURE _genCadenaOriginal()
*
LOCAL cTempFile
cTempFile = GetTempFile("XML")
THIS.CrearXML(cTempFile)
LOCAL cStr
cStr = CFDExtraerCadenaOriginal(cTempFile)
ERASE (cTempFile)
RETURN cStr
*
ENDPROC
*-- _fixStr (Metodo)
* Recibe una cadena y realiza los siguientes cambios:
* a) Sustituye cualquier caracter invalido por el caracter "."
* b) Elimina los espacios en blanco al inicio y al final de la cadena
* c) Elimina cualquier secuencia de espacios en blanco repetidos dentro de la cadena
* d) Si la cadena resultante contiene al menos 1 caracter, se le anade la cadena
* indicada en el parametro pcSep
*
* La funcion fue reeacrita a partir de la funcion QtarChrInval() de Halcon Divino, a fin
* de simplificar el codigo y depurarlo. El metodo utilizado por Halcon Divino para incluir
* cada elemento en la cadena original implicaba una doble llamada a QtarChrInval() para
* cada valor en la cadena:
*
* cStr = cStr + Iif(Len(QtarChrInval(valor)) = 0, "" ,QtarChrInval(valor) + "|")
*
* Este codigo se simplifica y mejora haciendo una sola invocacion a fixStr:
*
* cStr = cStr + THIS._fixStr(valor, "|")
*
* Adicionalmente se incluyo codigo para permitir que la funcion reciba cualquier tipo
* de datos, haciendo la conversion adecuada segun el tipo. En los casos donde el parametro
* de entraada no sea un string, no se realiza la verificacion de caracteres invalidos
*
HIDDEN PROCEDURE _fixStr(puValue, pcSep)
*
IF PCOUNT() = 1
pcSep = ""
ENDIF
LOCAL cType
cType = VARTYPE(puValue)
DO CASE
CASE cType = "N"
IF EMPTY(puValue)
RETURN ""
ENDIF
RETURN ALLT(STR(puValue,15,2)) + pcSep
CASE cType = "D"
IF EMPTY(puValue)
RETURN ""
ENDIF
RETURN STR(YEAR(puValue),4) + "-" + PADL(MONTH(puValue),2,"0") + "-" + PADL(DAY(puValue),2,"0") + pcSEP
CASE cType = "T"
IF EMPTY(puValue)
RETURN ""
ENDIF
RETURN STR(YEAR(puValue),4) + "-" + PADL(MONTH(puValue),2,"0") + "-" + PADL(DAY(puValue),2,"0") + "T" + ;
PADL(HOUR(puValue),2,"0") + ":" + PADL(MINUTE(puValue),2,"0") + ":" + PADL(SEC(puValue),2,"0") + pcSEP
CASE cType = "X" && Valor NULL
RETURN ""
ENDCASE
LOCAL cFixed
cFixed = ALLTRIM(puValue)
cFixed = STRT(STRT(STRT(STRT(STRT(cFixed,[&],[&]),[<],[<]),[>],[>]),["],["]),['],['])
cFixed = STRT(cFixed, CHR(13)+CHR(10), "")
DO WHILE AT(SPACE(2), cFixed) <> 0
cFixed = STRTRAN(cFixed,SPACE(2),SPACE(1))
ENDDO
IF LEN(cFixed) > 0 AND !EMPTY(pcSep)
cFixed = cFixed + pcSep
ENDIF
RETURN cFixed
*
ENDPROC
*-- Sellar (Metodo)
* Genera el sello digital del comprobante y actualiza los atributos apropiados
*
PROCEDURE Sellar(pcArchivoKey, pcPassword)
*
CFDConf.ultimoError = ""
*-- Si la fecha del comprobante es igual o posterior al 1-1-2011, se cambia
* el metodo MD5 por SHA-256
*
LOCAL cMetodo
cMetodo = "md5"
IF YEAR(THIS.fecha) > 2010
cMetodo = "sha256"
ENDIF
CFDConf.metodoDigest = cMetodo
*-- Se obtiene la cadena original
*
LOCAL cCadenaOriginal
cCadenaOriginal = THIS.cadenaOriginal
IF EMPTY(cCadenaOriginal)
CFDConf.ultimoError = "No se pudo obtener la cadena original. Utilize CFDProbarOpenSSL() para verificar el funcionamiento de la libreria OpenSSL"
RETURN .F.
ENDIF
*-- Se genera el sello para la cadena original
*
THIS.Sello = CFDGenerarSello(cCadenaOriginal, pcArchivoKey, pcPassword, cMetodo, THIS.ubicacionOpenSSL)
RETURN !EMPTY(THIS.Sello)
*
ENDPROC
*-- leerCertificado
* Lee el archivo de certificado indicado y actualiza
* los atributos apropiados
*
* VES Ene 4, 2011
* Se utiliza la propiedad CFDConf.ultimoCertificado como
* un "cache" para evitar leer innecesariamente el mismo
* certificado varias veces seguidas
*
PROCEDURE leerCertificado(pcArchivoCER)
*
*-- Se lee el certificado (solo si es necesario)
LOCAL oCert
IF ISNULL(CFDConf.ultimoCertificado) OR CFDConf.ultimoCertificado.Archivo <> LOWER(pcArchivoCER)