shape.bah

/////////////////////////////////////////////////////////////
//       Shapes demo using OpenGL and GLUT in Bah.         //
//         To compile, use 'bah ./shape.bah -d'.           //
//                                                         //
//                                     © Aloïs Laurent Boë //
/////////////////////////////////////////////////////////////

#import "iostream.bah"

#import "../vbah.bah"

win = new window
tex rgb

//shape defined by the user
struct userShape {
    //array containing every points of the shape
    shape: []float
    //the texture of the shape
    tex: rgb

    //used for drawing the shape
    draw() {
        drawShape(this.shape, this.tex)
    }

    //used for drawing the points
    drawPoints() {
        i=0; for i < len(this.shape) {
            drawCircle(vec(this.shape[i], this.shape[i+1]), 0.02, rgb(1.0, 0.0, 0.0))
            i += 2
        }
    }

}
shape userShape

display() {
    //Defines triangles point
    triangle = []float{
        -0.5, 0.0, //left point
        0.0, 0.5, //top point
        0.5, 0.0 //right point
    }
    //draws the triangle
    drawShape(triangle, tex)

    //draws the user defined shape
    shape.draw()
    //draws the every points of the shape
    shape.drawPoints()
}

init() {
    //Note: texture from: https://www.vecteezy.com/free-vector/lines
    tex = rgbTexture("./assets/tex.bmp", 1920, 1229)
    
    shape = userShape{}
    shape.tex = tex
}

//when the user clicks the window
click(btn int, pressed bool, x int, y int) {
    //if it is a click and not a click release
    if pressed == true {
        //translate the window coordinates (pixels) to object coordinates
        f = vec(<float>x, <float>y)
        pixelsToCoords(&f)
        //adds the coordinates to the array
        shape.shape[len(shape.shape)] = f.x
        shape.shape[len(shape.shape)] = f.y
    }
}

main(args []str) int {
    //launching the window
    
    win = window(600, 600, "Shape")
    win.display = display
    win.init = init
    win.click = click
    win.launch()

    return 0
}