text.bah

/////////////////////////////////////////////////////////////
//       Shapes demo using OpenGL and GLUT in Bah.         //
//         To compile, use 'bah ./text.bah -d'.            //
//                                                         //
//                                     © Aloïs Laurent Boë //
/////////////////////////////////////////////////////////////

#import "iostream.bah"

#import "../vbah.bah"

win = new window

helloFont font

vbahFont font
m = []textMarkup

const TEXT1 = "VBAH"
const TEXT2 = "Hello World!"
const TEXT3 = "This text is antialiased."

display() {
    textSize = vec(<float>vbahFont.calcWidth(TEXT1), 40.0)
    pixelsDimToCoords(&textSize)
    vbahFont.writeMarkup(vec(0.0 - textSize.x/2.0, textSize.y), m, 0, TEXT1)

    textSize = vec(<float>helloFont.calcWidth(TEXT2), 0.0)
    pixelsDimToCoords(&textSize)    
    helloFont.write(vec(0.0 - textSize.x/2.0 ,0.0), rgb(1.0,1.0,1.0), TEXT2)

    textSize = vec(<float>helloFont.calcWidth(TEXT3), <float>helloFont.getHeight() + 10.0)
    pixelsDimToCoords(&textSize)    
    helloFont.write(vec(0.0 - textSize.x/2.0 , 0.0 - textSize.y), rgb(0.8,0.8,0.8), TEXT3)
}

init() {
    helloFont = font{}
    helloFont.load("./assets/font/DroidSansMono.ttf")
    helloFont.setSize(20)

    vbahFont = font{}
    vbahFont.load("./assets/font/Fast Hand.ttf")
    vbahFont.setSize(50)

    m = []textMarkup{
        textMarkup{
            pos: 0
            color: rgb(1.00,0.00,0.00)
        },
        textMarkup{
            pos: 1
            color: rgb(1.00,1.00,0.00)
        },
        textMarkup{
            pos: 2
            color: rgb(0.00,1.00,0.33)
        },
        textMarkup{
            pos: 3
            color: rgb(0.00,0.80,1.00)
        }
    }
}

main(args []str) int {
    //launching the window
    
    win = window(600, 600, "Text")
    win.autoLoop = false
    win.display = display
    win.init = init
    win.launch()

    return 0
}