ktlint.gradle

repositories {
    mavenCentral()
}

configurations {
    ktlint
}

dependencies {
    ktlint('com.pinterest:ktlint:0.50.0') {
        attributes {
            attribute(Bundling.BUNDLING_ATTRIBUTE, getObjects().named(Bundling, Bundling.EXTERNAL))
        }
    }
}

tasks.register("ktlint", JavaExec) {
    group = "QuoteUnquote"
    description = "Check Kotlin code style."
    classpath = configurations.ktlint
    mainClass.set('com.pinterest.ktlint.Main')
    // see https://pinterest.github.io/ktlint/install/cli/#command-line-usage for more information
    args "src/**/*.kt", "**.kts", "!**/build/**"
}

tasks.named("check") {
    dependsOn tasks.named("ktlint")
}

tasks.register("ktlintFormat", JavaExec) {
    group = "QuoteUnquote"
    description = "Fix Kotlin code style deviations."
    classpath = configurations.ktlint
    mainClass.set('com.pinterest.ktlint.Main')
    jvmArgs "--add-opens=java.base/java.lang=ALL-UNNAMED"
    // see https://pinterest.github.io/ktlint/install/cli/#command-line-usage for more information
    args "-F", "src/**/*.kt", "**.kts", "!**/build/**"
}