forked from RespeQt/RespeQt
-
Notifications
You must be signed in to change notification settings - Fork 1
/
respeqt.pro
84 lines (73 loc) · 2.38 KB
/
respeqt.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
# -------------------------------------------------
# Project created by QtCreator 2009-11-22T14:13:00
# Last Update: Nov 29, 2014
# -------------------------------------------------
#
# Copyright 2015,2016 Joseph Zatarski
#
# This file is copyrighted by either Fatih Aygun, Ray Ataergin, or both.
# However, the years for these copyrights are unfortunately unknown. If you
# know the specific year(s) please let the current maintainer know.
#
#CONFIG(release, debug|release):DEFINES += QT_NO_DEBUG_OUTPUT
PROJECT_VERSION = "5.4.1"
RC_VERSION = "-RC1" ## Begin RC version with minus
DEFINES += VERSION=\\\"v$${PROJECT_VERSION}$${RC_VERSION}\\\"
#debug {
#QMAKE_CXXFLAGS+="-fsanitize=address -fno-omit-frame-pointer"
#QMAKE_LFLAGS+="-fsanitize=address"
#}
SOURCES += src/main.cpp
TARGET = RespeQt
TEMPLATE = app
CONFIG += qt c++11 strict_c++
QT += core gui network widgets printsupport serialport svg
greaterThan(QT_MAJOR_VERSION, 5): QT += core5compat
INCLUDEPATH += $$[QT_INSTALL_HEADERS]/QtZlib include headers tools
# Warnings for Deprecated functions
DEFINES += QT_DEPRECATED_WARNINGS
# Errors for QT4 deprecated functions
DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x050000
# No unknown pragmas
QMAKE_CXXFLAGS += -Wno-unknown-pragmas
include(sources.pri)
OTHER_FILES += \
license.txt \
history.txt \
atascii_read_me.txt \
RespeQt.rc \
about.html \
compile.html
win32 {
LIBS += -lwinmm -lz -lwinspool
}
unix {
LIBS += -lz -lcups
#QMAKE_CXXFLAGS += -Werror
CONFIG -= warn_on
QMAKE_CXXFLAGS += $$QMAKE_CXXFLAGS_WARN_ON -Wno-deprecated-copy
}
macx {
QMAKE_MACOSX_DEPLOYMENT_TARGET=10.7
bundle.files = \
i18n/respeqt_de.qm \
i18n/respeqt_es.qm \
i18n/respeqt_pl.qm \
i18n/respeqt_ru.qm \
i18n/respeqt_sk.qm \
i18n/respeqt_tr.qm
bundle.path = Contents/Resources
QMAKE_BUNDLE_DATA += bundle
deploy.commands = $$PWD/deployment/macdeploy.sh $$PWD $$OUT_PWD "$$VERSION" "$$RC_VERSION"
QMAKE_EXTRA_TARGETS += deploy
}
win32 {
deploy.commands = $$PWD/deployment/windeploy.bat "$$OUT_PWD/release/$$TARGET" "$$QMAKE_QMAKE" "$$PWD" "$${VERSION}$${RC_VERSION}"
QMAKE_EXTRA_TARGETS += deploy
}
linux {
deploy.commands = $$PWD/deployment/lindeploy.sh "$$OUT_PWD/$$TARGET" "$$QMAKE_QMAKE" "$$PWD" "$${PROJECT_VERSION}$${RC_VERSION}"
QMAKE_EXTRA_TARGETS += deploy
}
DISTFILES += \
deployment/lindeploy.sh