meson.build

project('freeciv', 'c', meson_version: '>= 0.36.0')

priv_conf_data = configuration_data()
pub_conf_data = configuration_data()

pub_conf_data.set('FREECIV_AI_MOD_LAST', 3)
priv_conf_data.set('LOCALEDIR',
                   join_paths(get_option('prefix'),
                              get_option('datadir'), 'locale'))
pub_conf_data.set('FREECIV_STORAGE_DIR', '~/.freeciv')
priv_conf_data.set('DATASUBDIR', 'dev')

c_compiler = meson.get_compiler('c')

pub_headers = [
  'locale.h',
  'libintl.h',
  'inttypes.h',
  'stdint.h',
  'ws2tcpip.h',
  'sys/types.h',
  'unistd.h',
  'sys/time.h',
  'sys/socket.h',
  'sys/select.h',
  'netinet/in.h',
  'dirent.h',
  'stdbool.h'
  ]

priv_headers = [
  'arpa/inet.h',
  'bzlib.h',
  'direct.h',
  'dlfcn.h',
  'execinfo.h',
  'fcntl.h',
  'libcharset.h',
  'libgen.h',
  'lzma.h',
  'memory.h',
  'netdb.h',
  'pwd.h',
  'signal.h',
  'stdlib.h',
  'strings.h',
  'string.h',
  'sys/file.h',
  'sys/ioctl.h',
  'sys/signal.h',
  'sys/stat.h',
  'sys/termio.h',
  'sys/uio.h',
  'sys/utsname.h',
  'sys/wait.h',
  'termios.h',
  'vfork.h'
  ]

foreach hdr : pub_headers
  if c_compiler.has_header(hdr)
    pub_conf_data.set('FREECIV_HAVE_' + hdr.underscorify().to_upper(), 1)
  endif
endforeach

foreach hdr : priv_headers
  if c_compiler.has_header(hdr)
    priv_conf_data.set('HAVE_' + hdr.underscorify().to_upper(), 1)
  endif
endforeach

configure_file(input : 'gen_headers/meson_fc_config.h.in',
               output : 'fc_config.h',
               configuration: priv_conf_data)
configure_file(input : 'gen_headers/meson_freeciv_config.h.in',
               output : 'freeciv_config.h',
               configuration: pub_conf_data)

add_global_arguments('-DHAVE_CONFIG_H',
                     language: 'c')

common_inc = include_directories('dependencies/lua-5.3/src',
  'dependencies/tolua-5.2/include', 'dependencies/cvercmp',
  'utility', 'common', 'common/networking', 'common/scriptcore',
  'common/aicore')

server_inc = [common_inc, include_directories('server', 'server/advisors',
              'server/scripting', 'server/generator', 'ai', 'ai/classic')]

client_inc = [common_inc, include_directories('client', 'client/include',
              'client/luascript', 'client/agents')]

tool_inc = [server_inc, include_directories('tools/ruleutil', 'tools/shared')]

verhdr = custom_target('verhdr', output: 'version_gen.h',
              command: ['sh', files('gen_headers/generate_version_header.sh'), '@OUTPUT@'],
              depend_files: files('fc_version'))

specenum = custom_target('specenum_gen.h', output: 'specenum_gen.h',
                         command: ['python', files('utility/generate_specenum.py'),
                                   '@OUTPUT@'])

pack_common = custom_target('packets_common', output: ['packets_gen.h',
                                                       'packets_gen.c'],
                            command: ['python', files('common/generate_packets.py'),
                                      '@OUTPUT0@', '@OUTPUT1@', '', '', '', ''],
                            depend_files: files('common/networking/packets.def'))

pack_server = custom_target('packets_server', output: ['hand_gen.h', 'hand_gen.c'],
                            command: ['python', files('common/generate_packets.py'),
                                      '', '', '', '', '@OUTPUT0@', '@OUTPUT1@'],
                            depend_files: files('common/networking/packets.def'))

pack_client = custom_target('packets_client', output: ['packhand_gen.h',
                                                       'packhand_gen.c'],
                            command: ['python', files('common/generate_packets.py'),
                                      '', '', '@OUTPUT0@', '@OUTPUT1@', '', ''],
                            depend_files: files('common/networking/packets.def'))

tolua_cmd = find_program('tolua')

tolua = generator(tolua_cmd,
                  arguments: ['-n', '@BASENAME@',
                              '-o', '@BUILD_DIR@/@BASENAME@_gen.c',
                              '-H', '@BUILD_DIR@/@BASENAME@_gen.h',
                              '@INPUT@'],
                  output: [ '@BASENAME@_gen.c', '@BASENAME@_gen.h'])

tolua_com_a = custom_target('tolua_custom_a',
                            output: ['tolua_common_a_gen.c',
                                     'tolua_common_a_gen.h'],
                            command: [tolua_cmd, '-n', 'common_a',
                                      '-o', '@OUTPUT0@',
                                      '-H', '@OUTPUT1@',
                                      files('common/scriptcore/tolua_common_a.pkg')])

tolua_com_z = custom_target('tolua_custom_z',
                            output: ['tolua_common_z_gen.c',
                                     'tolua_common_z_gen.h'],
                            command: [tolua_cmd, '-n', 'common_z',
                                      '-o', '@OUTPUT0@',
                                      '-H', '@OUTPUT1@',
                                      files('common/scriptcore/tolua_common_z.pkg')])

tolua_game = custom_target('tolua_game',
                           output: ['tolua_game_gen.c',
                                    'tolua_game_gen.h'],
                           command: [tolua_cmd, '-n', 'game',
                                     '-o', '@OUTPUT0@',
                                     '-H', '@OUTPUT1@',
                                     files('common/scriptcore/tolua_game.pkg')])

tolua_signal = custom_target('tolua_signal',
                             output: ['tolua_signal_gen.c',
                                      'tolua_signal_gen.h'],
                             command: [tolua_cmd, '-n', 'signal',
                                       '-o', '@OUTPUT0@',
                                       '-H', '@OUTPUT1@',
                                       files('common/scriptcore/tolua_signal.pkg')])

fc_deps = static_library('fc_dependencies',
  'dependencies/cvercmp/cvercmp.c',
  'dependencies/lua-5.3/src/lapi.c',
  'dependencies/lua-5.3/src/lauxlib.c',
  'dependencies/lua-5.3/src/lbaselib.c',
  'dependencies/lua-5.3/src/lbitlib.c',
  'dependencies/lua-5.3/src/lcode.c',
  'dependencies/lua-5.3/src/lcorolib.c',
  'dependencies/lua-5.3/src/lctype.c',
  'dependencies/lua-5.3/src/ldblib.c',
  'dependencies/lua-5.3/src/ldebug.c',
  'dependencies/lua-5.3/src/ldo.c',
  'dependencies/lua-5.3/src/ldump.c',
  'dependencies/lua-5.3/src/lfunc.c',
  'dependencies/lua-5.3/src/lgc.c',
  'dependencies/lua-5.3/src/linit.c',
  'dependencies/lua-5.3/src/liolib.c',
  'dependencies/lua-5.3/src/llex.c',
  'dependencies/lua-5.3/src/lmathlib.c',
  'dependencies/lua-5.3/src/lmem.c',
  'dependencies/lua-5.3/src/loadlib.c',
  'dependencies/lua-5.3/src/lobject.c',
  'dependencies/lua-5.3/src/lopcodes.c',
  'dependencies/lua-5.3/src/loslib.c',
  'dependencies/lua-5.3/src/lparser.c',
  'dependencies/lua-5.3/src/lstate.c',
  'dependencies/lua-5.3/src/lstring.c',
  'dependencies/lua-5.3/src/lstrlib.c',
  'dependencies/lua-5.3/src/ltable.c',
  'dependencies/lua-5.3/src/ltablib.c',
  'dependencies/lua-5.3/src/ltm.c',
  'dependencies/lua-5.3/src/lundump.c',
  'dependencies/lua-5.3/src/lutf8lib.c',
  'dependencies/lua-5.3/src/lvm.c',
  'dependencies/lua-5.3/src/lzio.c',
  'dependencies/tolua-5.2/src/lib/tolua_event.c',
  'dependencies/tolua-5.2/src/lib/tolua_is.c',
  'dependencies/tolua-5.2/src/lib/tolua_map.c',
  'dependencies/tolua-5.2/src/lib/tolua_push.c',
  'dependencies/tolua-5.2/src/lib/tolua_to.c',
  'dependencies/luasql/src/luasql.c',
  'dependencies/luasql/src/ls_sqlite3.c',
  sources: verhdr,
  include_directories : common_inc
  )

common_lib = library('freeciv',
  'utility/astring.c',
  'utility/bitvector.c',
  'utility/bugs.c',
  'utility/capability.c',
  'utility/deprecations.c',
  'utility/distribute.c',
  'utility/fcbacktrace.c',
  'utility/fc_cmdline.c',
  'utility/fc_dirent.c',
  'utility/fciconv.c',
  'utility/fcintl.c',
  'utility/fcthread.c',
  'utility/fc_utf8.c',
  'utility/genhash.c',
  'utility/genlist.c',
  'utility/inputfile.c',
  'utility/ioz.c',
  'utility/iterator.c',
  'utility/log.c',
  'utility/md5.c',
  'utility/mem.c',
  'utility/netfile.c',
  'utility/netintf.c',
  'utility/rand.c',
  'utility/registry.c',
  'utility/registry_ini.c',
  'utility/registry_xml.c',
  'utility/section_file.c',
  'utility/shared.c',
  'utility/string_vector.c',
  'utility/support.c',
  'utility/timing.c',
  'common/aicore/aisupport.c',
  'common/aicore/caravan.c',
  'common/aicore/citymap.c',
  'common/aicore/cm.c',
  'common/aicore/path_finding.c',
  'common/aicore/pf_tools.c',
  'common/networking/connection.c',
  'common/networking/dataio_json.c',
  'common/networking/dataio_raw.c',
  'common/networking/packets.c',
  'common/networking/packets_json.c',
  'common/scriptcore/api_common_intl.c',
  'common/scriptcore/api_common_utilities.c',
  'common/scriptcore/api_game_effects.c',
  'common/scriptcore/api_game_find.c',
  'common/scriptcore/api_game_methods.c',
  'common/scriptcore/api_game_specenum.c',
  'common/scriptcore/api_signal_base.c',
  'common/scriptcore/luascript.c',
  'common/scriptcore/luascript_func.c',
  'common/scriptcore/luascript_signal.c',
  'common/achievements.c',
  'common/actions.c',
  'common/ai.c',
  'common/base.c',
  'common/borders.c',
  'common/calendar.c',
  'common/capstr.c',
  'common/citizens.c',
  'common/city.c',
  'common/clientutils.c',
  'common/combat.c',
  'common/culture.c',
  'common/diptreaty.c',
  'common/disaster.c',
  'common/effects.c',
  'common/events.c',
  'common/extras.c',
  'common/fc_cmdhelp.c',
  'common/fc_interface.c',
  'common/featured_text.c',
  'common/game.c',
  'common/government.c',
  'common/idex.c',
  'common/improvement.c',
  'common/map.c',
  'common/mapimg.c',
  'common/metaknowledge.c',
  'common/movement.c',
  'common/multipliers.c',
  'common/nation.c',
  'common/player.c',
  'common/reqtext.c',
  'common/requirements.c',
  'common/research.c',
  'common/rgbcolor.c',
  'common/road.c',
  'common/server_settings.c',
  'common/spaceship.c',
  'common/specialist.c',
  'common/style.c',
  'common/team.c',
  'common/tech.c',
  'common/terrain.c',
  'common/tile.c',
  'common/traderoutes.c',
  'common/unit.c',
  'common/unitlist.c',
  'common/unittype.c',
  'common/version.c',
  'common/victory.c',
  'common/vision.c',
  'common/workertask.c',
  'common/worklist.c',
  include_directories : common_inc,
  sources: [specenum, pack_common,
            tolua_com_a, tolua_com_z, tolua_game, tolua_signal],
  link_whole: fc_deps,
  dependencies: [c_compiler.find_library('libicuuc'),
                 c_compiler.find_library('m'),
                 c_compiler.find_library('z'),
                 c_compiler.find_library('libcurl'),
                 c_compiler.find_library('libsqlite3'),
                 dependency('threads')]
  )

ais = static_library('fc_ai',
  'ai/classic/classicai.c',
  'ai/default/aiair.c',
  'ai/default/aicity.c',
  'ai/default/aidata.c',
  'ai/default/aidiplomat.c',
  'ai/default/aiferry.c',
  'ai/default/aiguard.c',
  'ai/default/aihand.c',
  'ai/default/aihunt.c',
  'ai/default/ailog.c',
  'ai/default/aiparatrooper.c',
  'ai/default/aiplayer.c',
  'ai/default/aisettler.c',
  'ai/default/aitech.c',
  'ai/default/aitools.c',
  'ai/default/aiunit.c',
  'ai/default/daidiplomacy.c',
  'ai/default/daidomestic.c',
  'ai/default/daieffects.c',
  'ai/default/daimilitary.c',
  include_directories: [server_inc, include_directories('ai/default')]
  )

server_lib = static_library('libfc_server',
  'ai/aitraits.c',
  'ai/difficulty.c',
  'ai/handicaps.c',
  'server/advisors/advbuilding.c',
  'server/advisors/advchoice.c',
  'server/advisors/advcity.c',
  'server/advisors/advdata.c',
  'server/advisors/advgoto.c',
  'server/advisors/advruleset.c',
  'server/advisors/advspace.c',
  'server/advisors/advtools.c',
  'server/advisors/autoexplorer.c',
  'server/advisors/autosettlers.c',
  'server/advisors/infracache.c',
  'server/generator/fracture_map.c',
  'server/generator/height_map.c',
  'server/generator/mapgen.c',
  'server/generator/mapgen_topology.c',
  'server/generator/mapgen_utils.c',
  'server/generator/startpos.c',
  'server/generator/temperature_map.c',
  'server/scripting/api_fcdb_auth.c',
  'server/scripting/api_fcdb_base.c',
  'server/scripting/api_server_base.c',
  'server/scripting/api_server_edit.c',
  'server/scripting/api_server_game_methods.c',
  'server/scripting/api_server_luadata.c',
  'server/scripting/api_server_notify.c',
  'server/scripting/script_fcdb.c',
  'server/scripting/script_server.c',
  'server/actiontools.c',
  'server/aiiface.c',
  'server/animals.c',
  'server/auth.c',
  'server/barbarian.c',
  'server/citizenshand.c',
  'server/cityhand.c',
  'server/citytools.c',
  'server/cityturn.c',
  'server/commands.c',
  'server/connecthand.c',
  'server/console.c',
  'server/diplhand.c',
  'server/diplomats.c',
  'server/edithand.c',
  'server/fcdb.c',
  'server/gamehand.c',
  'server/handchat.c',
  'server/maphand.c',
  'server/meta.c',
  'server/mood.c',
  'server/notify.c',
  'server/plrhand.c',
  'server/report.c',
  'server/rscompat.c',
  'server/rssanity.c',
  'server/ruleset.c',
  'server/sanitycheck.c',
  'server/savecompat.c',
  'server/savegame2.c',
  'server/savegame3.c',
  'server/savegame.c',
  'server/score.c',
  'server/sernet.c',
  'server/settings.c',
  'server/spacerace.c',
  'server/srv_log.c',
  'server/srv_main.c',
  'server/stdinhand.c',
  'server/techtools.c',
  'server/unithand.c',
  'server/unittools.c',
  'server/voting.c',
  include_directories: server_inc,
  sources: [ pack_server,
             tolua.process('server/scripting/tolua_fcdb.pkg',
                           'server/scripting/tolua_server.pkg')]
  )

executable('freeciv-server',
  'server/civserver.c',
  include_directories: server_inc,
  link_with: [server_lib, common_lib, ais],
  dependencies: [c_compiler.find_library('m')]
  )

client_common = static_library('fc_client_common',
  'client/agents/agents.c',
  'client/agents/cma_core.c',
  'client/agents/cma_fec.c',
  'client/agents/sha.c',
  'client/luascript/api_client_base.c',
  'client/luascript/script_client.c',
  'client/attribute.c',
  'client/audio.c',
  'client/audio_none.c',
  'client/audio_sdl.c',
  'client/chatline_common.c',
  'client/citydlg_common.c',
  'client/cityrepdata.c',
  'client/client_main.c',
  'client/climap.c',
  'client/climisc.c',
  'client/clinet.c',
  'client/colors_common.c',
  'client/connectdlg_common.c',
  'client/control.c',
  'client/editor.c',
  'client/global_worklist.c',
  'client/goto.c',
  'client/helpdata.c',
  'client/luaconsole_common.c',
  'client/mapctrl_common.c',
  'client/mapview_common.c',
  'client/messagewin_common.c',
  'client/music.c',
  'client/options.c',
  'client/overview_common.c',
  'client/packhand.c',
  'client/plrdlg_common.c',
  'client/repodlgs_common.c',
  'client/reqtree.c',
  'client/servers.c',
  'client/text.c',
  'client/themes_common.c',
  'client/tilespec.c',
  'client/unitselect_common.c',
  'client/update_queue.c',
  'client/voteinfo.c',
  'client/zoom.c',
  sources: [pack_client,
            tolua.process('client/luascript/tolua_client.pkg')],
  include_directories: client_inc,
  link_with: [common_lib],
  dependencies: [c_compiler.find_library('m'),
                 c_compiler.find_library('libSDL2_mixer')]
  )

tool_lib = static_library('libfc_toolutil',
  'tools/ruleutil/comments.c',
  'tools/ruleutil/rulesave.c',
  'tools/shared/tools_fc_interface.c',
  include_directories: server_inc
  )

executable('freeciv-ruleup',
  'tools/ruleup.c',
  link_with: [common_lib, server_lib, tool_lib, ais],
  include_directories: tool_inc,
  dependencies: [c_compiler.find_library('m')]
  )

executable('freeciv-manual',
  'tools/civmanual.c',
  'client/helpdata.c',
  link_with: [common_lib, server_lib, tool_lib, ais],
  include_directories: [tool_inc,
                        include_directories('client', 'client/include')],
  dependencies: [c_compiler.find_library('m')]
  )