ABAGEL.HPB

100 REM GUESS A THREE LETTER WORD
110	DIM W$[10],G$[10]
200 REM PRINT INSTRUCTIONS
205 PRINT "ALL THE WORDS I KNOW HAVE THREE LETTERS IN THEM."
210 PRINT "I WILL THINK OF A WORD, AND YOU TRY TO GUESS IT."
215 PRINT "EACH TIME, JUST TYPE A THREE LETTER WORD (OF YOUR OWN)"
220 PRINT "AND SEE WHAT I SAY."
225 PRINT
230 PRINT "'BAGELS' MEANS NONE OF YOUR LETTERS ARE IN MY WORD."
235 PRINT "BUT FOR EACH LETTER THAT IS IN MY WORD TOO, I WILL SAY,"
240 PRINT "'FERMI' IF IT'S IN THE RIGHT POSITION, OR 'PICO'"
245 PRINT "IF IT'S IN A DIFFERENT POSITION."
250 PRINT
255 PRINT "BUT I WON'T TELL YOU WHICH LETTERS I MEAN - YOU HAVE TO"
260 PRINT "USE YOUR HEAT TO FIGURE THAT OUT !"
300 REM READ THE WORD TO BE GUESSED
302 RESTORE
304 READ N
306 LET R=INT(N*RND(0))+1
307 FOR K=1 TO R
308 READ W$
309 NEXT K
310 READ W$
320 IF W$[1,1]=W$[2,2] THEN 302
340 IF W$[1,1]=W$[3,3] THEN 302
350 IF W$[2,2]=W$[3,3] THEN 302
360 PRINT
370 PRINT "O.K. I HAVE A WORD."
380 PRINT
400 REM INPUT A GUESS
410 PRINT
420 PRINT "WHAT IS YOUR GUESS";
430 INPUT G$
440 IF LEN(G$)=3 THEN 470
450 PRINT "MY WORD HAS THREE LETTERS."
460 GOTO 410
470 IF G$[1,1]=G$[2,2] THEN 510
480 IF G$[1,1]=G$[3,3] THEN 510
490 IF G$[2,2]=G$[3,3] THEN 510
500 GOTO 600
510 PRINT "NO TWO LETTERS ARE THE SAME."
520 GOTO 410
600 REM COMPARE GUESS WITH COMPUTER'S WORD
610 LET F=0
620 LET P=0
630 FOR J=1 TO 3
640 FOR K=1 TO 3
650 IF G$[J,J]<>W$[K,K] THEN 720
660 IF J=K THEN 700
670 PRINT "PICO ";
680 LET P=P+1
690 GOTO 720
700 PRINT "FERMI ";
710 LET F=F+1
720 NEXT K
730 NEXT J
740 IF P+P> THEN 770
750 PRINT "BAGLES ";
755 PRINT
760 GOTO 400
770 IF F=3 THEN 800
780 PRINT
790 GOTO 400
800 REM HUMAN HAS GUESSED THE WORD
810 PRINT
820 PRINT "YOU GOT IT! MY WORD IS ";W$
830 PRINT
840 GOTO 300
900 REM HERE ARE THE WORDS
910 DATA 47
920 DATA "POT","APT","WIN","RUN","LIP","PET","ART","CUP"
930 DATA "PUN","CAT","MAP","LAP","OUT","DOT","ARE","FOR"
940 DATA "AND","BUT","TUB","CRY","LET","WED","LED","IRK"
950 DATA "SKY","CUE","TEN","NET","SAW","WAS","CUT","THE"
960 DATA "FAR","YOU","HIM","HER","ERG","ALP","INK","PEN"
970 DATA "PIN","DIG","DEW","AMP","WHY","SUN","SON","OPT"
999 END