Different warning_level for include_directories directory

[synalice]

I have a directory that contains a bunch of header files. I add it like this:

kernel_includes_dir = include_directories('kernel-includes')

I also set 'warning_level=3' for my project. This causes GCC to provide warning for code inside kernel_includes_dir. How do I exclude this dir from being checked for errors?

kernel_includes_dirdo not containmeson.build` file. And what do I even put there?

Complete top meson.build file:

project(
	'smth',
	'cpp',
	version: '1.0.0',
	default_options: [
		'cpp_std=c++20',
		'warning_level=3',
	],
)

compiler = meson.get_compiler('cpp')
add_project_arguments(
	compiler.get_supported_arguments(
		[
			'-Wno-unknown-pragmas',
		],
	),
	language: 'cpp',
)

kernel_includes_dir = include_directories('kernel-includes')

subdir('src')

executable(
	meson.project_name(),
	src_sources,
	include_directories: mashtab_t1_kernel_includes_dir,
	install: true,
)

[synalice]

Solved by adding implicit_include_directories: false and is_system: true.

project(
    'smth',
    'cpp',
    version: '1.0.0',
    default_options: [
        'cpp_std=c++20',
        'warning_level=3',
    ],
)

compiler = meson.get_compiler('cpp')
add_project_arguments(
    compiler.get_supported_arguments(
        [
            '-Wno-unknown-pragmas',
        ],
    ),
    language: 'cpp',
)

includes_dir = include_directories(
    'includes_dir',
    is_system: true,
)

subdir('src')

executable(
    meson.project_name(),
    src_sources,
    include_directories: includes_dir,
    implicit_include_directories: false,
    install: true,
)