Using Temple in LiveView's without colocated templates

[mhanberg]

If you'd like to use Temple in a live view directly (as in, you write your Temple template code directly in the live view module, not in a colocated template file), you can use this pattern until something more official is baked into the library itself.

https://gist.github.com/mhanberg/c564703fa31a91464ad948e0dd846269

# lib/my_app/views/live_view.ex
defmodule MyAppWeb.LiveView do
  defmacro render(block) do
    quote do
      def render(var!(assigns)) do
        require Temple

        Temple.compile(unquote(Phoenix.LiveView.Engine), unquote(block))
      end
    end
  end
end

# lib/my_app_web.ex
defmodule MyAppWeb do
  # ...
  
  def live_view do
    quote do
      use Phoenix.LiveView,
        layout: {MyAppWeb.LayoutView, "live.html"}

      import MyAppWeb.LiveView

      unquote(view_helpers())
    end
  end

  def live_component do
    quote do
      use Phoenix.LiveComponent
      import MyAppWeb.LiveView

      unquote(view_helpers())
    end
  end
  
  # ...
end

# lib/my_app_web/live/page/show.ex
defmodule MyAppWeb.Page.Show do
  use MyAppWeb, :live_view
  
  render do
    div do
      "Hello, world!"
    end
  end
end

[eahanson]

I created a little example repo that uses the above code for LiveViews but also for LiveComponents. (There were no changes needed to get it to work with LiveComponents.) Here's the repo if anyone's interested: https://github.com/eahanson/temple_components