build.gradle

plugins {
	id 'java'
	id 'jacoco'
	id 'org.springframework.boot' version '3.3.0'
	id 'io.spring.dependency-management' version '1.1.5'
	id "org.sonarqube" version '4.4.1.3373'
	id "org.flywaydb.flyway" version "10.15.2"
}

group = 'com.quemistry'
version = '0.0.1-SNAPSHOT'

java {
	sourceCompatibility = '21'
}

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}

	testCompile {
		/* only junit 5 should be used */
		exclude group: 'junit', module: 'junit'
		exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
	}
	testRuntime {
		/* only junit 5 should be used */
		exclude group: 'junit', module: 'junit'
		exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
	}

}

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter'
	implementation 'org.springframework.boot:spring-boot-starter-web'

	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.flywaydb:flyway-database-postgresql'
	implementation 'org.flywaydb:flyway-core'

	implementation 'org.springframework.boot:spring-boot-starter-data-redis'
	implementation 'redis.clients:jedis'

	implementation 'org.mapstruct:mapstruct:1.5.5.Final'
	implementation 'com.fasterxml.jackson.core:jackson-databind'

	compileOnly 'org.projectlombok:lombok'
	developmentOnly 'org.springframework.boot:spring-boot-docker-compose'
	annotationProcessor 'org.projectlombok:lombok'

	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
	testImplementation 'com.h2database:h2:2.3.230' // Replace with the latest version

	runtimeOnly "org.springframework.boot:spring-boot-starter-actuator"
	runtimeOnly 'org.postgresql:postgresql'
}

test {
	useJUnitPlatform()
	finalizedBy jacocoTestReport
}

jacocoTestReport {
	dependsOn test

	reports {
		xml.required = true
	}

	afterEvaluate {
		excludedClassFilesForReport(classDirectories)
	}
}

private excludedClassFilesForReport(classDirectories) {
	classDirectories.setFrom(files(classDirectories.files.collect {
		fileTree(dir: it, exclude: [
				'**/entity/*.class',
				'**/model/**/*.class',
				'**/model/*.class',
				'**/entity/**/*.class',
				'**/Application.class',
				'**/constant/**/*.class',
				'**/constant/*.class'
		])
	}))
}

bootJar {
	archiveFileName = "auth_ms.jar"
	archiveClassifier.set(null)
}

tasks.register('installLocalGitHook', Copy) {
	from new File(rootProject.rootDir, 'scripts/pre-commit')
	into { new File(rootProject.rootDir, '.git/hooks') }
	fileMode 0775
}

build {
	finalizedBy('installLocalGitHook')
}

sonar {
	properties {
		property "sonar.projectKey", "mtech-31-quemistry_auth_ms"
		property "sonar.organization", "mtech-31-quemistry"
		property "sonar.host.url", "https://sonarcloud.io"
		property 'sonar.coverage.exclusions', "**/entity/**, **/model/**, **/Application*, **/constant/**, **/entity/**/**"
	}
}