build.gradle

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    id 'org.springframework.boot' version '3.1.1'
    id 'io.spring.dependency-management' version '1.1.0'
    id 'org.jetbrains.kotlin.jvm' version '1.8.22'
    id 'org.jetbrains.kotlin.plugin.spring' version '1.8.22'
    id 'org.jetbrains.kotlin.plugin.allopen' version '1.8.22'
}

bootJar.enabled = false
jar.enabled = true

allprojects {
    group = 'io.philo'
    version = '0.0.1-SNAPSHOT'

    repositories {
        mavenCentral()
    }
}

subprojects {

    apply plugin: 'java'
    apply plugin: 'org.jetbrains.kotlin.jvm'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'org.jetbrains.kotlin.plugin.spring'
    apply plugin: 'org.jetbrains.kotlin.plugin.allopen'

    java {
        sourceCompatibility = '17'
    }

    tasks.withType(KotlinCompile).configureEach {
        kotlinOptions {
            freeCompilerArgs += '-Xjsr305=strict'
            jvmTarget = '17'
        }
    }

    bootJar.enabled = true
    jar.enabled = false

    dependencies {
        // Kotlin
        implementation 'org.jetbrains.kotlin:kotlin-reflect'
        implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"

        // Coroutine
        implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-core'

        // kotlin logging
        implementation 'io.github.microutils:kotlin-logging:3.0.5'

        // Kotest
        testImplementation "io.kotest:kotest-runner-junit5:5.6.2"
        testImplementation "io.kotest:kotest-assertions-core:5.6.2"

        // Spring Web MVC
        implementation 'org.springframework.boot:spring-boot-starter-web'

        // Spring Test
        testImplementation 'org.springframework.boot:spring-boot-starter-test'

        // JVM Test
        testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.1'
        testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.1'

        // YAML Auto Config
        annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'

        implementation 'org.springframework.boot:spring-boot-starter-actuator'
    }

    ext {
        set('springCloudVersion', "2022.0.4")
    }

    dependencyManagement {
        imports {
            mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
        }
    }

    allOpen {
        annotation("jakarta.persistence.Entity")
        annotation("jakarta.persistence.Embeddable")
        annotation("jakarta.persistence.MappedSuperclass")
    }

    tasks.named('test') {
        useJUnitPlatform()
    }
}

tasks.named('test') {
    useJUnitPlatform()
}