Grammar railroad diagram

[mingodad]

After massaging a bit the grammar at src/lang/lang_parser.mly shown bellow we can copy and paste it at https://www.bottlecaps.de/rr/ui on the TAB Edit Grammar and then switching to the TAB View Diagram we get a railroad diagram for the grammar.

program ::=  error
	| EOF
	| exprs EOF

interactive ::=  error
	| exprs SEQSEQ
	| EOF

s ::=  /* empty */
	| SEQ

g ::=  /* empty */
	| GETS

exprs ::=  OPEN expr s exprs
	| expr s
	| expr s exprs
	| binding s
	| binding s exprs
	| list_binding s
	| list_binding s exprs

exprss ::=  expr
	| expr SEQ exprss

expr ::=  LPAR expr COLON ty RPAR
	| UMINUS FLOAT
	| UMINUS INT
	| UMINUS LPAR expr RPAR
	| LPAR expr RPAR
	| INT
	| NOT expr
	| BOOL
	| FLOAT
	| STRING
	| VAR
	| varlist
	| GET expr
	| expr SET expr
	| MP3 app_opt
	| MP3_VBR app_opt
	| MP3_ABR app_opt
	| SHINE app_opt
	| FDKAAC app_opt
	| FLAC app_opt
	| FFMPEG ffmpeg_opt
	| EXTERNAL app_opt
	| GSTREAMER app_opt
	| WAV app_opt
	| AVI app_opt
	| OGG LPAR ogg_audio_item COMMA ogg_video_item RPAR
	| OGG LPAR ogg_video_item COMMA ogg_audio_item RPAR
	| OGG LPAR ogg_audio_item RPAR
	| OGG LPAR ogg_video_item RPAR
	| top_level_ogg_audio_item
	| ogg_video_item
	| LPAR RPAR
	| LPAR inner_tuple RPAR
	| expr DOT LCUR record RCUR
	| LCUR record RCUR
	| LCUR RCUR
	| expr DOT VAR
	| expr DOT VARLPAR app_list RPAR
	| VARLPAR app_list RPAR
	| VARLBRA expr RBRA
	| expr DOT VARLBRA expr RBRA
	| BEGIN exprs END
	| FUN LPAR arglist RPAR YIELDS expr
	| LCUR exprss RCUR
	| WHILE expr DO exprs END
	| FOR bindvar GETS expr DO exprs END
	| expr TO expr
	| expr COALESCE expr
	| TRY exprs CATCH bindvar IN varlist DO exprs END
	| TRY exprs CATCH bindvar DO exprs END
	| IF exprs THEN exprs if_elsif END
	| expr QUESTION expr COLON expr
	| expr BINB expr
	| expr BIN1 expr
	| expr BIN2 expr
	| expr BIN3 expr
	| expr TIMES expr
	| expr MINUS expr
	| INTERVAL
	| TIME

ty ::=  VAR
	| ty QUESTION
	| LBRA ty RBRA
	| LPAR ty_tuple RPAR
	| LPAR argsty RPAR YIELDS ty
	| ty_source

ty_source ::=  VARLPAR RPAR
	| VARLPAR ty_source_params RPAR

ty_source_params ::=  VAR GETS ty_content
	| VAR GETS ty_content COMMA ty_source_params

ty_content ::=  VAR
	| VAR DOT VAR
	| VAR DOT VAR DOT VAR
	| VARLPAR ty_content_args RPAR
	| VAR DOT VARLPAR ty_content_args RPAR
	| VAR DOT VAR DOT VARLPAR ty_content_args RPAR

ty_content_args ::=  /* empty */
	| ty_content_arg
	| ty_content_arg COMMA ty_content_args

ty_content_arg ::=  VAR
	| STRING
	| VAR GETS VAR
	| VAR GETS STRING
	| VAR GETS INT

ty_tuple ::=  ty TIMES ty
	| ty TIMES ty_tuple

argty ::=  ty
	| VAR COLON ty
	| QUESTION VAR COLON ty

argsty ::=  /* empty */
	| argty
	| argty COMMA argsty

varlist ::=  LBRA inner_list RBRA

inner_list ::=  inner_list_item COMMA inner_list
	| inner_list_item
	| /* empty */

inner_list_item ::=  DOTDOTDOT expr
	| expr

inner_tuple ::=  expr COMMA expr
	| expr COMMA inner_tuple

app_list_elem ::=  VAR GETS expr
	| expr
	| ARGS_OF LPAR var RPAR
	| ARGS_OF LPAR subfield RPAR
	| ARGS_OF LPAR VARLBRA args_of_params RBRA RPAR
	| ARGS_OF LPAR subfield_lbra args_of_params RBRA RPAR

app_list ::=  /* empty */
	| app_list_elem
	| app_list_elem COMMA app_list

bindvar ::=  VAR
	| UNDERSCORE

pattern ::=  bindvar
	| LPAR pattern_list RPAR

subfield ::=  VAR DOT in_subfield

in_subfield ::=  var
	| VAR DOT in_subfield

pattern_list ::=  pattern COMMA pattern
	| pattern COMMA pattern_list

binding ::=  bindvar GETS expr
	| LET replaces pattern GETS expr
	| LET replaces subfield GETS expr
	| DEF replaces pattern g exprs END
	| DEF replaces subfield g exprs END
	| DEF replaces varlpar arglist RPAR g exprs END
	| DEF REC VARLPAR arglist RPAR g exprs END

list_binding ::=  LET LBRA list_bind RBRA GETS expr

list_bind ::=  bindvar COMMA list_bind
	| DOTDOTDOT var
	| bindvar

replaces ::=  /* empty */
	| REPLACES

var ::=  VAR
	| IN

varlpar ::=  VARLPAR
	| VAR DOT varlpar

arglist ::=  /* empty */
	| arg
	| arg COMMA arglist

arg ::=  TILD var opt
	| TILD LPAR var COLON ty RPAR opt
	| TILD var GETS UNDERSCORE opt
	| bindvar opt
	| LPAR bindvar COLON ty RPAR opt
	| ARGS_OF LPAR var RPAR
	| ARGS_OF LPAR subfield RPAR
	| ARGS_OF LPAR VARLBRA args_of_params RBRA RPAR
	| ARGS_OF LPAR subfield_lbra args_of_params RBRA RPAR

opt ::=  GETS expr
	| /* empty */

args_of_params ::=  var
	| GET var
	| var COMMA args_of_params
	| GET var COMMA args_of_params

subfield_lbra ::=  VAR DOT in_subfield_lbra

in_subfield_lbra ::=  VARLBRA
	| VAR DOT in_subfield_lbra

if_elsif ::=  ELSIF exprs THEN exprs if_elsif
	| ELSE exprs
	| /* empty */

app_opt ::=  /* empty */
	| LPAR app_list RPAR

top_level_ogg_audio_item ::=  VORBIS app_opt
	| VORBIS_CBR app_opt
	| VORBIS_ABR app_opt
	| SPEEX app_opt
	| OPUS app_opt

ogg_audio_item ::=  FLAC app_opt
	| top_level_ogg_audio_item

ogg_video_item ::=  THEORA app_opt

ffmpeg_param ::=  STRING GETS expr
	| VAR GETS expr

ffmpeg_params ::=  /* empty */
	| ffmpeg_param
	| ffmpeg_param COMMA ffmpeg_params

ffmpeg_list_elem ::=  AUDIO_NONE
	| AUDIO_COPY
	| AUDIO_RAW LPAR ffmpeg_params RPAR
	| AUDIO_RAW
	| AUDIO LPAR ffmpeg_params RPAR
	| VIDEO_NONE
	| VIDEO_COPY
	| VIDEO_RAW
	| VIDEO_RAW LPAR ffmpeg_params RPAR
	| VIDEO LPAR ffmpeg_params RPAR
	| ffmpeg_param

ffmpeg_list ::=  /* empty */
	| ffmpeg_list_elem
	| ffmpeg_list_elem COMMA ffmpeg_list

ffmpeg_opt ::=  /* empty */
	| LPAR ffmpeg_list RPAR

record ::=  VAR GETS expr
	| record COMMA VAR GETS expr

// Tokens

DOT ::= '.'
DOTDOTDOT ::= "..."
LBRA ::= '['
RBRA ::= ']'
LPAR ::= '('
RPAR ::= ')'
LCUR ::= '{'
RCUR ::= '}'
COMMA ::= ','
COLON ::= ':'
SEQ ::= ';'
SEQSEQ ::= ";;"
TILD ::= "~"
QUESTION ::= "?"
MINUS ::= "-"
WHILE ::= "while"
FOR ::= "for"
IN ::= "in"
TO ::= "to"
DO ::= "do"
NOT ::= "not"
OPEN ::= "open"
COALESCE ::= "??"
TIMES ::= "*"
GET ::= "!"
SET ::= ":="
UNDERSCORE ::= '_'
BOOL ::= "true" true
BOOL ::= "false" false

[smimram]

Thanks for letting us know!

[toots]

This looks pretty neat actually: diagram.pdf