How to record video+audio stream from input.srt?

[rrolla]

Version:

Liquidsoap 2.2.5

I'm trying same hacks as audio create blank ref then set from input.srt but i'm getting type errors

Error:

At /var/liquidsoap/live.liq, line 32, char 127-139:
    output.file(fallible=true, mpegtsCopySourceEncoder, {time.string("/var/liquidsoap/recordings/%Y-%m-%d-#{hour}-%M-%S.ts")}, liveSource())

Error 5: this value has type
  source('A) where 'A is a set of internal tracks (inferred at /var/liquidsoap/live.liq, line 18, char 17-24)
but it should be a subtype of
  source(audio=ffmpeg.copy, video=ffmpeg.copy)

live.liq

settings.log.level.set(3)
settings.server.log.level.set(3)
settings.log.stdout.set(true)

settings.srt.log.set(true)
settings.srt.log.level.set(3)

# Set SRT log level, one of: “critical”, “error”, “warning”, “notice” or “debug”
settings.srt.log.verbosity.set("warning")

# Set FFMPEG log level, one of: “quiet”, “panic”, “fatal”, “error”, “warning”, “info”, “verbose”, “debug” or “trace”.
settings.ffmpeg.log.verbosity.set("warning")

settings.frame.video.width.set(1920)
settings.frame.video.height.set(1080)
settings.frame.video.framerate.set(50)

liveSource = ref(blank())

sourceRecordingToggle = ref(true)
encodedRecordingToggle = ref(true)

mpegtsCopySourceEncoder = %ffmpeg(
     format="mpegts",
     %audio.copy,
     %video.copy,
   )

def record()
    timeStamp = time.local()
    hour = timeStamp.hour+3
    output.file(fallible=true, mpegtsCopySourceEncoder, {time.string("/var/liquidsoap/recordings/%Y-%m-%d-#{hour}-%M-%S.ts")}, liveSource())
    {}
end

def startRecord()
    thread.run((fun() -> begin record() end))
end

def onConnect()
    print("Live connected!")
    startRecord()
    {}
end


liveSource.set(input.srt(
    bind_address="0.0.0.0",
    mode="listener",
    port=38112,
    pbkeylen=16,
    on_connect=onConnect,
    passphrase="test123456",
    streamid="srt",
    enforced_encryption=false,
    read_timeout=null(),
    write_timeout=null()
    )
)

output.srt(fallible=true, bind_address="0.0.0.0", port=38113, enforced_encryption=false, mpegtsCopySourceEncoder, liveSource())

[vitoyucepi]

Hi @rrolla,
I think blank produces data in internal format, so if you want to save the result of it, you can't use copy codec.
I'm not sure, but output.file will continue writing to the file after reconnecting, in addition to opening a new file.

[rrolla]

Hi @vitoyucepi that blank is like hack to set at the beginning blank source so later i can set it to real input.srt and able to access it in record function

@toots Not sure why on all that callbacks on_connect() there no possibility to pass source as argument, so we can easily pass to next functions?

Because function order matters a lot otherwise i will get error that something is not defined eg:

In perfect scenario i want something like this without refing

liveSource = input.srt(
    bind_address="0.0.0.0",
    mode="listener",
    port=38112,
    pbkeylen=16,
    on_connect=onConnect,
    passphrase="test123456",
    streamid="srt",
    enforced_encryption=false,
    read_timeout=null(),
    write_timeout=null()
    )

mpegtsCopySourceEncoder = %ffmpeg(
     format="mpegts",
     %audio.copy,
     %video.copy,
   )

def record()
    timeStamp = time.local()
    hour = timeStamp.hour+3
    output.file(fallible=true, mpegtsCopySourceEncoder, {time.string("/var/liquidsoap/recordings/%Y-%m-%d-#{hour}-%M-%S.ts")}, liveSource)
    {}
end

def startRecord()
    thread.run((fun() -> begin record() end))
end

def onConnect()
    print("Live connected!")
    startRecord()
    {}
end

output.srt(mode="listener", fallible=true, bind_address="0.0.0.0", port=38113, enforced_encryption=false, mpegtsCopySourceEncoder, liveSource)

But then i got error:

At /var/liquidsoap/live.liq, line 23, char 15-24:
    on_connect=onConnect,

Error 4: Undefined variable onConnect

Because onConnect is defined after liveSource if i move it up i will get next error

At /var/liquidsoap/live.liq, line 20, char 4-16:
    startRecord()

Error 4: Undefined variable startRecord 

and it gets in rabbit hole because at the end if i move everything up i will get error that livesource is not defined

At /var/liquidsoap/live.liq, line 27, char 127-137:
    output.file(fallible=true, mpegtsCopySourceEncoder, {time.string("/var/liquidsoap/recordings/%Y-%m-%d-#{hour}-%M-%S.ts")}, liveSource)

Error 4: Undefined variable liveSource

Changed order script

mpegtsCopySourceEncoder = %ffmpeg(
     format="mpegts",
     %audio.copy,
     %video.copy,
   )

def record()
    timeStamp = time.local()
    hour = timeStamp.hour+3
    output.file(fallible=true, mpegtsCopySourceEncoder, {time.string("/var/liquidsoap/recordings/%Y-%m-%d-#{hour}-%M-%S.ts")}, liveSource)
    {}
end

def startRecord()
    thread.run((fun() -> begin record() end))
end

def onConnect()
    print("Live connected!")
    startRecord()
    {}
end

liveSource = input.srt(
    bind_address="0.0.0.0",
    mode="listener",
    port=38112,
    pbkeylen=16,
    on_connect=onConnect,
    passphrase="test123456",
    streamid="srt",
    enforced_encryption=false,
    read_timeout=null(),
    write_timeout=null()
    )

output.srt(mode="listener", fallible=true, bind_address="0.0.0.0", port=38113, enforced_encryption=false, mpegtsCopySourceEncoder, liveSource)

[vitoyucepi]

How about this one:

onConnect = ref(fun() -> ())

liveSource = input.srt(
    bind_address="0.0.0.0",
    mode="listener",
    port=38112,
    pbkeylen=16,
    on_connect={onConnect()},
    passphrase="test",
    streamid="srt",
    enforced_encryption=false,
    read_timeout=null(),
    write_timeout=null()
)

mpegtsCopySourceEncoder = %ffmpeg(
     format="mpegts",
     %audio.copy,
     %video.copy,
   )

def record()
    timeStamp = time.local()
    hour = timeStamp.hour+3
    output.file(fallible=true, mpegtsCopySourceEncoder, {time.string("/var/liquidsoap/recordings/%Y-%m-%d-#{hour}-%M-%S.ts")}, liveSource)
end

def startRecord()
    record()
end

onConnect := fun() -> begin
    print("Live connected!")
    startRecord()
end

output.srt(mode="listener", fallible=true, bind_address="0.0.0.0", port=38113, enforced_encryption=false, mpegtsCopySourceEncoder, liveSource)

1. At the beginning I define a reference onConnect, which could be dereferenced by calling onConnect() in a function that does nothing.
2. At the end, I reassign onConnect to a new function.
3. on_connect={onConnect()} should be a function that does something.
   • on_connect=onConnect will not work because on call it will just return the dereferenced value.
   • on_connect=onConnect()` will work, but will do nothing because it dereferences into the stub function.

I can't run the script because some of the parameters in input.srt are wrong.

[vitoyucepi]

I made a mistake in on_connect, the correct way to do it is like this:

liquidsoap/src/libs/playlist.liq

Lines 254 to 271 in 530afaf

	next_fun = ref(fun () -> null())
	def next() =
	f = next_fun()
	f()
	end
	# Instantiate the source
	default =
	fun () ->
	request.dynamic(
	id=id,
	prefetch=prefetch,
	timeout=timeout,
	retry_delay=1.,
	available={not has_stopped()},
	next
	)

on_connect_ref = ref(fun() -> ())
def on_connect()
  f = on_connect_ref()
  f()
end

liveSource = input.srt(
    bind_address="0.0.0.0",
    mode="listener",
    port=38112,
    pbkeylen=16,
    on_connect=on_connect,
    passphrase="test",
    streamid="srt",
    enforced_encryption=false,
    read_timeout=null(),
    write_timeout=null()
)

def startRecord()
    record()
end

on_connect_ref := startRecord

[rrolla]

Huge thanks @vitoyucepi it works, I was also trying basically the same thing before, but was incorrect in one part that I need to pass real function on_connect not referenced one.

Is this somewhere written in the docs? Can be very helpful to not nudge typecheker but just create reference for function and later set what that function really need to do, this can also simplify function ordering in the code.

Thanks again, for me this is very important and I can continue to build. 📺