print-to-json.f90

program print_to_json
  !!  Demonstrate writing a dag_t object in JSON format
  !!
  !!  Compile and run run this program by executing the following
  !!  command from the top-level directory of the dag source tree:
  !!
  !!   fpm run --example print-to-json
  !!
  use dag_m, only: dag_t
  use vertex_m, only: vertex_t
  use iso_varying_string, only : varying_string, var_str
  implicit none

  character(len=*), parameter :: longest_name = "iso_varying_string"
   character(len=len(longest_name)), parameter :: names(*) = &
  [character(len=len(longest_name)) :: "iso_varying_string", "assert_m", "vertex_s", "vertex_m", "dag_m", "dag_s", "main"]
  type(varying_string) name_string(size(names))

  name_string = var_str(names)

  associate( &
     iso_varying_string => findloc(names, "iso_varying_string", dim=1) &
    ,assert_m           => findloc(names, "assert_m",           dim=1) &
    ,vertex_s           => findloc(names, "vertex_s",           dim=1) &
    ,vertex_m           => findloc(names, "vertex_m",           dim=1) &
    ,dag_m              => findloc(names, "dag_m",              dim=1) &
    ,dag_s              => findloc(names, "dag_s",              dim=1) &
    ,main               => findloc(names, "main",               dim=1) &
  )
    block
      type(dag_t) program_units

      program_units = dag_t([ &
          vertex_t( [integer::],          name_string(iso_varying_string) ) &
         ,vertex_t( [integer::],          name_string(assert_m)           ) &
         ,vertex_t( [vertex_m, assert_m], name_string(vertex_s)           ) &
         ,vertex_t( [integer::],          name_string(vertex_m)           ) &
         ,vertex_t( [vertex_m],           name_string(dag_m)              ) &
         ,vertex_t( [dag_m, assert_m],    name_string(dag_s)              ) &
         ,vertex_t( [dag_m, vertex_m],    name_string(main)               ) &
       ])

       associate(json_object => program_units%to_json())
         print *, json_object%to_expanded_string()
       end associate
     end block
   end associate
end program