USFletcher.bos

#define TAK

piece base, hull, railings, boats,
	  main_turret_a, main_sleeve_a, main_barrel_a, main_flare_a, main_turret_b, main_sleeve_b, main_barrel_b, main_flare_b,
	  main_turret_c, main_sleeve_c, main_barrel_c, main_flare_c, main_turret_d, main_sleeve_d, main_barrel_d, main_flare_d,
	  main_turret_e, main_sleeve_e, main_barrel_e, main_flare_e,
	  aa40_turret_1, aa40_sleeve_1, aa40_barrel_11, aa40_flare_11, aa40_barrel_21, aa40_flare_21,
	  aa40_turret_2, aa40_sleeve_2, aa40_barrel_12, aa40_flare_12, aa40_barrel_22, aa40_flare_22,
	  aa40_turret_3, aa40_sleeve_3, aa40_barrel_13, aa40_flare_13, aa40_barrel_23, aa40_flare_23,
	  aa40_turret_4, aa40_sleeve_4, aa40_barrel_14, aa40_flare_14, aa40_barrel_24, aa40_flare_24,
	  aa40_turret_5, aa40_sleeve_5, aa40_barrel_15, aa40_flare_15, aa40_barrel_25, aa40_flare_25,
	  aa20_turret_1, aa20_sleeve_1, aa20_barrel_1, aa20_flare_1, aa20_turret_2, aa20_sleeve_2, aa20_barrel_2, aa20_flare_2,
	  aa20_turret_3, aa20_sleeve_3, aa20_barrel_3, aa20_flare_3, aa20_turret_4, aa20_sleeve_4, aa20_barrel_4, aa20_flare_4,
	  aa20_turret_5, aa20_sleeve_5, aa20_barrel_5, aa20_flare_5, aa20_turret_6, aa20_sleeve_6, aa20_barrel_6, aa20_flare_6,
	  aa20_turret_7, aa20_sleeve_7, aa20_barrel_7, aa20_flare_7,
	  tl_front, torp1_f, torp2_f, torp3_f, torp4_f, torp5_f,
	  tl_rear, torp1_r, torp2_r, torp3_r, torp4_r, torp5_r,
	  exhaust1, exhaust2, wake1, wake2, wake3, wake4;

#define BASE_SMOKE_PERIOD	40
#define MIN_SMOKE_PERIOD	240

//********************Turret turn speeds
#define MAIN_TURRET_TURN		<28.75>
#define MAIN_TURRET_PITCH		<15>

#define AA40_TURRET_TURN		<200>
#define AA40_TURRET_PITCH		<150>

#define AA20_TURRET_TURN			<225>
#define AA20_TURRET_PITCH			<175>

#define TL_TURRET_TURN			<25>

//*********************Recoil
#define MAIN_GUN_RECOIL			[0.375]
#define MAIN_GUN_RECOIL_SPEED	[10]
#define MAIN_GUN_BACK_SPEED		[2]

#define AA40_GUN_RECOIL			[0.06]
#define AA40_GUN_RECOIL_SPEED	[10]
#define AA40_GUN_BACK_SPEED		[4]

#define AA20_GUN_RECOIL			[0.045]
#define AA20_GUN_RECOIL_SPEED	[10]
#define AA20_GUN_BACK_SPEED		[5]

//*********************Death anim
#define HULL_LIST_SPEED			<3>
#define HULL_LIST_ANGLE_X			<15>
#define HULL_LIST_ANGLE_Z			<5>

//********************Engine smoke
#define ENGINE_SMOKE_PIECE1	exhaust1
#define ENGINE_SMOKE_PIECE2 exhaust2
#define ENGINE_SMOKE_PERIOD	200

#define RESTORE_PERIOD		2500

#define SIG_DEATH			1
#define SIG_MOVE			2
// main guns
#define SIG_AIM1			4
#define SIG_AIM2			8
#define SIG_AIM3			16
#define SIG_AIM4			32
#define SIG_AIM5			64
// 40mm AA
#define SIG_AIM6			128
#define SIG_AIM7			256
#define SIG_AIM8			512
#define SIG_AIM9			1024
#define SIG_AIM10			2048
// 20mm single guns
#define SIG_AIM11			4096
#define SIG_AIM12			8192
#define SIG_AIM13			16384
#define SIG_AIM14			32768
#define SIG_AIM15			65536
#define SIG_AIM16			131072
#define SIG_AIM17			262144
// torpedo launchers
#define SIG_AIM18			524288
#define SIG_AIM19			1048576

#define ALL_WEAPON_SIGS		2097148

#define SMOKEPIECE	hull

#define XSMALL_MUZZLEFLASH	1024+3
#define XSMALL_MUZZLEDUST		1024+4

#define SMALL_MUZZLEFLASH	1024+5
#define SMALL_MUZZLEDUST			1024+6

#define MG_MUZZLEFLASH		1024+7

#define LARGE_MUZZLEFLASH	1024+8
#define LARGE_MUZZLEDUST		1024+9

#include "constants.h"
#include "damageSmoke.h"
static-var	CurrentSpeed, bMoving, aa40_1_flare, aa40_2_flare, aa40_3_flare, aa40_4_flare, aa40_5_flare,
 			tl1Flare, tl2Flare, oldXZ, oldHeading;

WorkingLoop()
{
	while(TRUE)
	{
		if(bMoving)
		{
			// engine smoke comes here. And engine sound.
			emit-sfx SFXTYPE_BLACKSMOKE from ENGINE_SMOKE_PIECE1;
			emit-sfx SFXTYPE_BLACKSMOKE from ENGINE_SMOKE_PIECE2;
			sleep ENGINE_SMOKE_PERIOD;
		}
		sleep 500;
	}
}

InitTurrets()
//Pre-position turrets
{
	turn main_turret_d to y-axis <180> now;
	turn main_turret_e to y-axis <180> now;
	turn aa40_turret_5 to y-axis <180> now;
	turn aa20_turret_1 to y-axis <-90> now;
	turn aa20_turret_2 to y-axis <90> now;
	turn aa20_turret_3 to y-axis <-90> now;
	turn aa20_turret_4 to y-axis <90> now;
	turn aa20_turret_5 to y-axis <180> now;
	turn aa20_turret_6 to y-axis <180> now;
	turn aa20_turret_7 to y-axis <180> now;
	aa40_1_flare=TRUE;
	aa40_2_flare=TRUE;
	aa40_3_flare=TRUE;
	aa40_4_flare=TRUE;
	aa40_5_flare=TRUE;
	tl1Flare=1;
	tl2Flare=1;
}

WaitForConstructionToFinish()
{
	while(get BUILD_PERCENT_LEFT)
	{
		sleep 150;
	}
}

HideFlares()
{
	hide main_flare_a;
	hide main_flare_b;
	hide main_flare_c;
	hide main_flare_d;
	hide main_flare_e;
	hide aa40_flare_11;
	hide aa40_flare_21;
	hide aa40_flare_12;
	hide aa40_flare_22;
	hide aa40_flare_13;
	hide aa40_flare_23;
	hide aa40_flare_14;
	hide aa40_flare_24;
	hide aa40_flare_15;
	hide aa40_flare_25;
	hide aa20_flare_1;
	hide aa20_flare_2;
	hide aa20_flare_3;
	hide aa20_flare_4;
	hide aa20_flare_5;
	hide aa20_flare_6;
	hide aa20_flare_7;
}

Create()
{
	start-script HideFlares();
	bMoving = FALSE;
	call-script InitTurrets();
	call-script WaitForConstructionToFinish();
	start-script DamageSmoke();
	start-script WorkingLoop();
}

SweetSpot(piecenum)
{
	piecenum = hull;
}

EmitWakes()
{
	set-signal-mask SIG_MOVE|SIG_DEATH;
	while( TRUE )
	{
		emit-sfx 2 from wake1;
		emit-sfx 2 from wake2;
		emit-sfx 2 from wake3;
		emit-sfx 2 from wake4;
		sleep 300;
	}
}

StopMoving()
{
	signal SIG_MOVE;
	set-signal-mask SIG_MOVE;
	// We don't want this to trigger on VERY short stops
	sleep 300;
	bMoving = FALSE;
}

StopCatcher()
{
	var newXZ, newHeading;
	set-signal-mask SIG_MOVE|SIG_DEATH;
	while(TRUE)
	{
		sleep 300;
		newXZ = get PIECE_XZ(base);
		newHeading = get HEADING;
		if((oldXZ == newXZ) && (oldHeading == newHeading))
		{
			call-script StopMoving();
		}
		oldXZ = newXZ;
		oldHeading = newHeading;
	}
}

StartMoving()
{
	signal SIG_MOVE;
	start-script EmitWakes();
	start-script StopCatcher();
	bMoving = TRUE;
}

RestoreTurret()
{
	set-signal-mask SIG_DEATH|ALL_WEAPON_SIGS;
	sleep RESTORE_PERIOD;

	turn main_turret_a to y-axis <0> speed MAIN_TURRET_TURN;
	turn main_sleeve_a to x-axis <0> speed MAIN_TURRET_PITCH;
	turn main_turret_b to y-axis <0> speed MAIN_TURRET_TURN;
	turn main_sleeve_b to x-axis <0> speed MAIN_TURRET_PITCH;
	turn main_turret_c to y-axis <0> speed MAIN_TURRET_TURN;
	turn main_sleeve_c to x-axis <0> speed MAIN_TURRET_PITCH;
	turn main_turret_d to y-axis <180> speed MAIN_TURRET_TURN;
	turn main_sleeve_d to x-axis <0> speed MAIN_TURRET_PITCH;
	turn main_turret_e to y-axis <180> speed MAIN_TURRET_TURN;
	turn main_sleeve_e to x-axis <0> speed MAIN_TURRET_PITCH;

	turn aa40_turret_1 to y-axis <0> speed AA40_TURRET_TURN;
	turn aa40_sleeve_1 to x-axis <0> speed AA40_TURRET_PITCH;
	turn aa40_turret_2 to y-axis <0> speed AA40_TURRET_TURN;
	turn aa40_sleeve_2 to x-axis <0> speed AA40_TURRET_PITCH;
	turn aa40_turret_3 to y-axis <0> speed AA40_TURRET_TURN;
	turn aa40_sleeve_3 to x-axis <0> speed AA40_TURRET_PITCH;
	turn aa40_turret_4 to y-axis <0> speed AA40_TURRET_TURN;
	turn aa40_sleeve_4 to x-axis <0> speed AA40_TURRET_PITCH;
	turn aa40_turret_5 to y-axis <180> speed AA40_TURRET_TURN;
	turn aa40_sleeve_5 to x-axis <0> speed AA40_TURRET_PITCH;

	turn aa20_turret_1 to y-axis <-90> speed AA20_TURRET_TURN;
	turn aa20_sleeve_1 to x-axis <0> speed AA20_TURRET_PITCH;
	turn aa20_turret_2 to y-axis <90> speed AA20_TURRET_TURN;
	turn aa20_sleeve_2 to x-axis <0> speed AA20_TURRET_PITCH;
	turn aa20_turret_3 to y-axis <-90> speed AA20_TURRET_TURN;
	turn aa20_sleeve_3 to x-axis <0> speed AA20_TURRET_PITCH;
	turn aa20_turret_4 to y-axis <90> speed AA20_TURRET_TURN;
	turn aa20_sleeve_4 to x-axis <0> speed AA20_TURRET_PITCH;
	turn aa20_turret_5 to y-axis <180> speed AA20_TURRET_TURN;
	turn aa20_sleeve_5 to x-axis <0> speed AA20_TURRET_PITCH;
	turn aa20_turret_6 to y-axis <180> speed AA20_TURRET_TURN;
	turn aa20_sleeve_6 to x-axis <0> speed AA20_TURRET_PITCH;
	turn aa20_turret_7 to y-axis <180> speed AA20_TURRET_TURN;
	turn aa20_sleeve_7 to x-axis <0> speed AA20_TURRET_PITCH;

	turn tl_front to y-axis <0> speed TL_TURRET_TURN;
	turn tl_rear to y-axis <0> speed TL_TURRET_TURN;
}

QueryWeapon1(piecenum)
{
	piecenum = main_flare_a;
}

AimFromWeapon1(piecenum)
{
	piecenum = main_turret_a;
}

AimWeapon1(heading, pitch)
{
	signal SIG_AIM1;
	set-signal-mask SIG_AIM1|SIG_DEATH;
	turn main_turret_a to y-axis heading speed MAIN_TURRET_TURN;
	turn main_sleeve_a to x-axis (0-pitch) speed MAIN_TURRET_PITCH;
	wait-for-turn main_turret_a around y-axis;
	wait-for-turn main_sleeve_a around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon1()
{
	emit-sfx LARGE_MUZZLEFLASH from main_flare_a;
	emit-sfx LARGE_MUZZLEDUST from main_flare_a;
	move main_barrel_a to z-axis (0-MAIN_GUN_RECOIL) speed MAIN_GUN_RECOIL_SPEED;
	sleep 200;
	move main_barrel_a to z-axis [0] speed MAIN_GUN_BACK_SPEED;
}

QueryWeapon2(piecenum)
{
	piecenum = main_flare_b;
}

AimFromWeapon2(piecenum)
{
	piecenum = main_turret_b;
}

AimWeapon2(heading, pitch)
{
	signal SIG_AIM2;
	set-signal-mask SIG_AIM2|SIG_DEATH;
	turn main_turret_b to y-axis heading speed MAIN_TURRET_TURN;
	turn main_sleeve_b to x-axis (0-pitch) speed MAIN_TURRET_PITCH;
	wait-for-turn main_turret_b around y-axis;
	wait-for-turn main_sleeve_b around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon2()
{
	emit-sfx LARGE_MUZZLEFLASH from main_flare_b;
	emit-sfx LARGE_MUZZLEDUST from main_flare_b;
	move main_barrel_b to z-axis (0-MAIN_GUN_RECOIL) speed MAIN_GUN_RECOIL_SPEED;
	sleep 200;
	move main_barrel_b to z-axis [0] speed MAIN_GUN_BACK_SPEED;
}

QueryWeapon3(piecenum)
{
	piecenum = main_flare_c;
}

AimFromWeapon3(piecenum)
{
	piecenum = main_turret_c;
}

AimWeapon3(heading, pitch)
{
	signal SIG_AIM3;
	set-signal-mask SIG_AIM3|SIG_DEATH;
	turn main_turret_c to y-axis heading speed MAIN_TURRET_TURN;
	turn main_sleeve_c to x-axis (0-pitch) speed MAIN_TURRET_PITCH;
	wait-for-turn main_turret_c around y-axis;
	wait-for-turn main_sleeve_c around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon3()
{
	emit-sfx LARGE_MUZZLEFLASH from main_flare_c;
	emit-sfx LARGE_MUZZLEDUST from main_flare_c;
	move main_barrel_c to z-axis (0-MAIN_GUN_RECOIL) speed MAIN_GUN_RECOIL_SPEED;
	sleep 200;
	move main_barrel_c to z-axis [0] speed MAIN_GUN_BACK_SPEED;
}

QueryWeapon4(piecenum)
{
	piecenum = main_flare_d;
}

AimFromWeapon4(piecenum)
{
	piecenum = main_turret_d;
}

AimWeapon4(heading, pitch)
{
	signal SIG_AIM4;
	set-signal-mask SIG_AIM4|SIG_DEATH;
	turn main_turret_d to y-axis heading speed MAIN_TURRET_TURN;
	turn main_sleeve_d to x-axis (0-pitch) speed MAIN_TURRET_PITCH;
	wait-for-turn main_turret_d around y-axis;
	wait-for-turn main_sleeve_d around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon4()
{
	emit-sfx LARGE_MUZZLEFLASH from main_flare_d;
	emit-sfx LARGE_MUZZLEDUST from main_flare_d;
	move main_barrel_d to z-axis (0-MAIN_GUN_RECOIL) speed MAIN_GUN_RECOIL_SPEED;
	sleep 200;
	move main_barrel_d to z-axis [0] speed MAIN_GUN_BACK_SPEED;
}

QueryWeapon5(piecenum)
{
	piecenum = main_flare_e;
}

AimFromWeapon5(piecenum)
{
	piecenum = main_turret_e;
}

AimWeapon5(heading, pitch)
{
	signal SIG_AIM5;
	set-signal-mask SIG_AIM5|SIG_DEATH;
	turn main_turret_e to y-axis heading speed MAIN_TURRET_TURN;
	turn main_sleeve_e to x-axis (0-pitch) speed MAIN_TURRET_PITCH;
	wait-for-turn main_turret_e around y-axis;
	wait-for-turn main_sleeve_e around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon5()
{
	emit-sfx LARGE_MUZZLEFLASH from main_flare_e;
	emit-sfx LARGE_MUZZLEDUST from main_flare_e;
	move main_barrel_e to z-axis (0-MAIN_GUN_RECOIL) speed MAIN_GUN_RECOIL_SPEED;
	sleep 200;
	move main_barrel_e to z-axis [0] speed MAIN_GUN_BACK_SPEED;
}

QueryWeapon6(piecenum)
{
	if(aa40_1_flare)
	{
		piecenum = aa40_flare_11;
	} else
	{
		piecenum = aa40_flare_21;
	}
}

AimFromWeapon6(piecenum)
{
	piecenum = aa40_turret_1;
}

AimWeapon6(heading, pitch)
{
	signal SIG_AIM6;
	set-signal-mask SIG_AIM6|SIG_DEATH;
	turn aa40_turret_1 to y-axis heading speed AA40_TURRET_TURN;
	turn aa40_sleeve_1 to x-axis (0-pitch) speed AA40_TURRET_PITCH;
	wait-for-turn aa40_turret_1 around y-axis;
	wait-for-turn aa40_sleeve_1 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

Shot6(foo)
{
	aa40_1_flare = !aa40_1_flare;
}

FireWeapon6()
{
	if(aa40_1_flare)
	{
		emit-sfx SMALL_MUZZLEFLASH from aa40_flare_11;
		emit-sfx SMALL_MUZZLEDUST from aa40_flare_11;
		move aa40_barrel_11 to z-axis (0-AA40_GUN_RECOIL) speed AA40_GUN_RECOIL_SPEED;
		sleep 200;
		move aa40_barrel_11 to z-axis [0] speed AA40_GUN_BACK_SPEED;
	} else
	{
		emit-sfx SMALL_MUZZLEFLASH from aa40_flare_21;
		emit-sfx SMALL_MUZZLEDUST from aa40_flare_21;
		move aa40_barrel_21 to z-axis (0-AA40_GUN_RECOIL) speed AA40_GUN_RECOIL_SPEED;
		sleep 200;
		move aa40_barrel_21 to z-axis [0] speed AA40_GUN_BACK_SPEED;
	}
}

QueryWeapon7(piecenum)
{
	if(aa40_2_flare)
	{
		piecenum = aa40_flare_12;
	} else
	{
		piecenum = aa40_flare_22;
	}
}

AimFromWeapon7(piecenum)
{
	piecenum = aa40_turret_2;
}

AimWeapon7(heading, pitch)
{
	signal SIG_AIM7;
	set-signal-mask SIG_AIM7|SIG_DEATH;
	turn aa40_turret_2 to y-axis heading speed AA40_TURRET_TURN;
	turn aa40_sleeve_2 to x-axis (0-pitch) speed AA40_TURRET_PITCH;
	wait-for-turn aa40_turret_2 around y-axis;
	wait-for-turn aa40_sleeve_2 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

Shot7(foo)
{
	aa40_2_flare = !aa40_2_flare;
}

FireWeapon7()
{
	if(aa40_2_flare)
	{
		emit-sfx SMALL_MUZZLEFLASH from aa40_flare_12;
		emit-sfx SMALL_MUZZLEDUST from aa40_flare_12;
		move aa40_barrel_12 to z-axis (0-AA40_GUN_RECOIL) speed AA40_GUN_RECOIL_SPEED;
		sleep 200;
		move aa40_barrel_12 to z-axis [0] speed AA40_GUN_BACK_SPEED;
	} else
	{
		emit-sfx SMALL_MUZZLEFLASH from aa40_flare_22;
		emit-sfx SMALL_MUZZLEDUST from aa40_flare_22;
		move aa40_barrel_22 to z-axis (0-AA40_GUN_RECOIL) speed AA40_GUN_RECOIL_SPEED;
		sleep 200;
		move aa40_barrel_22 to z-axis [0] speed AA40_GUN_BACK_SPEED;
	}
}

QueryWeapon8(piecenum)
{
	if(aa40_3_flare)
	{
		piecenum = aa40_flare_13;
	} else
	{
		piecenum = aa40_flare_23;
	}
}

AimFromWeapon8(piecenum)
{
	piecenum = aa40_turret_3;
}

AimWeapon8(heading, pitch)
{
	signal SIG_AIM8;
	set-signal-mask SIG_AIM8|SIG_DEATH;
	turn aa40_turret_3 to y-axis heading speed AA40_TURRET_TURN;
	turn aa40_sleeve_3 to x-axis (0-pitch) speed AA40_TURRET_PITCH;
	wait-for-turn aa40_turret_3 around y-axis;
	wait-for-turn aa40_sleeve_3 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

Shot8(foo)
{
	aa40_3_flare = !aa40_3_flare;
}

FireWeapon8()
{
	if(aa40_3_flare)
	{
		emit-sfx SMALL_MUZZLEFLASH from aa40_flare_13;
		emit-sfx SMALL_MUZZLEDUST from aa40_flare_13;
		move aa40_barrel_13 to z-axis (0-AA40_GUN_RECOIL) speed AA40_GUN_RECOIL_SPEED;
		sleep 200;
		move aa40_barrel_13 to z-axis [0] speed AA40_GUN_BACK_SPEED;
	} else
	{
		emit-sfx SMALL_MUZZLEFLASH from aa40_flare_23;
		emit-sfx SMALL_MUZZLEDUST from aa40_flare_23;
		move aa40_barrel_23 to z-axis (0-AA40_GUN_RECOIL) speed AA40_GUN_RECOIL_SPEED;
		sleep 200;
		move aa40_barrel_23 to z-axis [0] speed AA40_GUN_BACK_SPEED;
	}
}

QueryWeapon9(piecenum)
{
	if(aa40_4_flare)
	{
		piecenum = aa40_flare_14;
	} else
	{
		piecenum = aa40_flare_24;
	}
}

AimFromWeapon9(piecenum)
{
	piecenum = aa40_turret_4;
}

AimWeapon9(heading, pitch)
{
	signal SIG_AIM9;
	set-signal-mask SIG_AIM9|SIG_DEATH;
	turn aa40_turret_4 to y-axis heading speed AA40_TURRET_TURN;
	turn aa40_sleeve_4 to x-axis (0-pitch) speed AA40_TURRET_PITCH;
	wait-for-turn aa40_turret_4 around y-axis;
	wait-for-turn aa40_sleeve_4 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

Shot9(foo)
{
	aa40_4_flare = !aa40_4_flare;
}

FireWeapon9()
{
	if(aa40_4_flare)
	{
		emit-sfx SMALL_MUZZLEFLASH from aa40_flare_14;
		emit-sfx SMALL_MUZZLEDUST from aa40_flare_14;
		move aa40_barrel_14 to z-axis (0-AA40_GUN_RECOIL) speed AA40_GUN_RECOIL_SPEED;
		sleep 200;
		move aa40_barrel_14 to z-axis [0] speed AA40_GUN_BACK_SPEED;
	} else
	{
		emit-sfx SMALL_MUZZLEFLASH from aa40_flare_24;
		emit-sfx SMALL_MUZZLEDUST from aa40_flare_24;
		move aa40_barrel_24 to z-axis (0-AA40_GUN_RECOIL) speed AA40_GUN_RECOIL_SPEED;
		sleep 200;
		move aa40_barrel_24 to z-axis [0] speed AA40_GUN_BACK_SPEED;
	}
}

QueryWeapon10(piecenum)
{
	if(aa40_5_flare)
	{
		piecenum = aa40_flare_15;
	} else
	{
		piecenum = aa40_flare_25;
	}
}

AimFromWeapon10(piecenum)
{
	piecenum = aa40_turret_5;
}

AimWeapon10(heading, pitch)
{
	signal SIG_AIM10;
	set-signal-mask SIG_AIM10|SIG_DEATH;
	turn aa40_turret_5 to y-axis heading speed AA40_TURRET_TURN;
	turn aa40_sleeve_5 to x-axis (0-pitch) speed AA40_TURRET_PITCH;
	wait-for-turn aa40_turret_5 around y-axis;
	wait-for-turn aa40_sleeve_5 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

Shot10(foo)
{
	aa40_5_flare = !aa40_5_flare;
}

FireWeapon10()
{
	if(aa40_5_flare)
	{
		emit-sfx SMALL_MUZZLEFLASH from aa40_flare_15;
		emit-sfx SMALL_MUZZLEDUST from aa40_flare_15;
		move aa40_barrel_15 to z-axis (0-AA40_GUN_RECOIL) speed AA40_GUN_RECOIL_SPEED;
		sleep 200;
		move aa40_barrel_15 to z-axis [0] speed AA40_GUN_BACK_SPEED;
	} else
	{
		emit-sfx SMALL_MUZZLEFLASH from aa40_flare_25;
		emit-sfx SMALL_MUZZLEDUST from aa40_flare_25;
		move aa40_barrel_25 to z-axis (0-AA40_GUN_RECOIL) speed AA40_GUN_RECOIL_SPEED;
		sleep 200;
		move aa40_barrel_25 to z-axis [0] speed AA40_GUN_BACK_SPEED;
	}
}

QueryWeapon11(piecenum)
{
	piecenum = aa20_flare_1;
}

AimFromWeapon11(piecenum)
{
	piecenum = aa20_turret_1;
}

AimWeapon11(heading, pitch)
{
	signal SIG_AIM11;
	set-signal-mask SIG_AIM11|SIG_DEATH;
	turn aa20_turret_1 to y-axis heading speed AA20_TURRET_TURN;
	turn aa20_sleeve_1 to x-axis (0-pitch) speed AA20_TURRET_PITCH;
	wait-for-turn aa20_turret_1 around y-axis;
	wait-for-turn aa20_sleeve_1 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon11()
{
	emit-sfx XSMALL_MUZZLEFLASH from aa20_flare_1;
	emit-sfx XSMALL_MUZZLEDUST from aa20_flare_1;
	move aa20_barrel_1 to z-axis (0-AA20_GUN_RECOIL) speed AA20_GUN_RECOIL_SPEED;
	sleep 200;
	move aa20_barrel_1 to z-axis [0] speed AA20_GUN_BACK_SPEED;
}

QueryWeapon12(piecenum)
{
	piecenum = aa20_flare_2;
}

AimFromWeapon12(piecenum)
{
	piecenum = aa20_turret_2;
}

AimWeapon12(heading, pitch)
{
	signal SIG_AIM12;
	set-signal-mask SIG_AIM12|SIG_DEATH;
	turn aa20_turret_2 to y-axis heading speed AA20_TURRET_TURN;
	turn aa20_sleeve_2 to x-axis (0-pitch) speed AA20_TURRET_PITCH;
	wait-for-turn aa20_turret_2 around y-axis;
	wait-for-turn aa20_sleeve_2 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon12()
{
	emit-sfx XSMALL_MUZZLEFLASH from aa20_flare_2;
	emit-sfx XSMALL_MUZZLEDUST from aa20_flare_2;
	move aa20_barrel_2 to z-axis (0-AA20_GUN_RECOIL) speed AA20_GUN_RECOIL_SPEED;
	sleep 200;
	move aa20_barrel_2 to z-axis [0] speed AA20_GUN_BACK_SPEED;
}

QueryWeapon13(piecenum)
{
	piecenum = aa20_flare_3;
}

AimFromWeapon13(piecenum)
{
	piecenum = aa20_turret_3;
}

AimWeapon13(heading, pitch)
{
	signal SIG_AIM13;
	set-signal-mask SIG_AIM13|SIG_DEATH;
	turn aa20_turret_3 to y-axis heading speed AA20_TURRET_TURN;
	turn aa20_sleeve_3 to x-axis (0-pitch) speed AA20_TURRET_PITCH;
	wait-for-turn aa20_turret_3 around y-axis;
	wait-for-turn aa20_sleeve_3 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon13()
{
	emit-sfx XSMALL_MUZZLEFLASH from aa20_flare_3;
	emit-sfx XSMALL_MUZZLEDUST from aa20_flare_3;
	move aa20_barrel_3 to z-axis (0-AA20_GUN_RECOIL) speed AA20_GUN_RECOIL_SPEED;
	sleep 200;
	move aa20_barrel_3 to z-axis [0] speed AA20_GUN_BACK_SPEED;
}

QueryWeapon14(piecenum)
{
	piecenum = aa20_flare_4;
}

AimFromWeapon14(piecenum)
{
	piecenum = aa20_turret_4;
}

AimWeapon14(heading, pitch)
{
	signal SIG_AIM14;
	set-signal-mask SIG_AIM14|SIG_DEATH;
	turn aa20_turret_4 to y-axis heading speed AA20_TURRET_TURN;
	turn aa20_sleeve_4 to x-axis (0-pitch) speed AA20_TURRET_PITCH;
	wait-for-turn aa20_turret_4 around y-axis;
	wait-for-turn aa20_sleeve_4 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon14()
{
	emit-sfx XSMALL_MUZZLEFLASH from aa20_flare_4;
	emit-sfx XSMALL_MUZZLEDUST from aa20_flare_4;
	move aa20_barrel_4 to z-axis (0-AA20_GUN_RECOIL) speed AA20_GUN_RECOIL_SPEED;
	sleep 200;
	move aa20_barrel_4 to z-axis [0] speed AA20_GUN_BACK_SPEED;
}

QueryWeapon15(piecenum)
{
	piecenum = aa20_flare_5;
}

AimFromWeapon15(piecenum)
{
	piecenum = aa20_turret_5;
}

AimWeapon15(heading, pitch)
{
	signal SIG_AIM15;
	set-signal-mask SIG_AIM15|SIG_DEATH;
	turn aa20_turret_5 to y-axis heading speed AA20_TURRET_TURN;
	turn aa20_sleeve_5 to x-axis (0-pitch) speed AA20_TURRET_PITCH;
	wait-for-turn aa20_turret_5 around y-axis;
	wait-for-turn aa20_sleeve_5 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon15()
{
	emit-sfx XSMALL_MUZZLEFLASH from aa20_flare_5;
	emit-sfx XSMALL_MUZZLEDUST from aa20_flare_5;
	move aa20_barrel_5 to z-axis (0-AA20_GUN_RECOIL) speed AA20_GUN_RECOIL_SPEED;
	sleep 200;
	move aa20_barrel_5 to z-axis [0] speed AA20_GUN_BACK_SPEED;
}

QueryWeapon16(piecenum)
{
	piecenum = aa20_flare_6;
}

AimFromWeapon16(piecenum)
{
	piecenum = aa20_turret_6;
}

AimWeapon16(heading, pitch)
{
	signal SIG_AIM16;
	set-signal-mask SIG_AIM16|SIG_DEATH;
	turn aa20_turret_6 to y-axis heading speed AA20_TURRET_TURN;
	turn aa20_sleeve_6 to x-axis (0-pitch) speed AA20_TURRET_PITCH;
	wait-for-turn aa20_turret_6 around y-axis;
	wait-for-turn aa20_sleeve_6 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon16()
{
	emit-sfx XSMALL_MUZZLEFLASH from aa20_flare_6;
	emit-sfx XSMALL_MUZZLEDUST from aa20_flare_6;
	move aa20_barrel_6 to z-axis (0-AA20_GUN_RECOIL) speed AA20_GUN_RECOIL_SPEED;
	sleep 200;
	move aa20_barrel_6 to z-axis [0] speed AA20_GUN_BACK_SPEED;
}

QueryWeapon17(piecenum)
{
	piecenum = aa20_flare_7;
}

AimFromWeapon17(piecenum)
{
	piecenum = aa20_turret_7;
}

AimWeapon17(heading, pitch)
{
	signal SIG_AIM17;
	set-signal-mask SIG_AIM17|SIG_DEATH;
	turn aa20_turret_7 to y-axis heading speed AA20_TURRET_TURN;
	turn aa20_sleeve_7 to x-axis (0-pitch) speed AA20_TURRET_PITCH;
	wait-for-turn aa20_turret_7 around y-axis;
	wait-for-turn aa20_sleeve_7 around x-axis;
	start-script RestoreTurret();
	return (TRUE);
}

FireWeapon17()
{
	emit-sfx XSMALL_MUZZLEFLASH from aa20_flare_7;
	emit-sfx XSMALL_MUZZLEDUST from aa20_flare_7;
	move aa20_barrel_7 to z-axis (0-AA20_GUN_RECOIL) speed AA20_GUN_RECOIL_SPEED;
	sleep 200;
	move aa20_barrel_7 to z-axis [0] speed AA20_GUN_BACK_SPEED;
}

QueryWeapon18(piecenum)
{
	if(tl1Flare == 1)
	{
		piecenum = torp1_f;
	}
	if(tl1Flare == 2)
	{
		piecenum = torp2_f;
	}
	if(tl1Flare == 3)
	{
		piecenum = torp3_f;
	}
	if(tl1Flare == 4)
	{
		piecenum = torp4_f;
	}
	if(tl1Flare == 5)
	{
		piecenum = torp5_f;
	}
}

AimFromWeapon18(piecenum)
{
	piecenum = tl_front;
}

AimWeapon18(heading, pitch)
{
	signal SIG_AIM18;
	set-signal-mask SIG_AIM18|SIG_DEATH;
	turn tl_front to y-axis heading speed TL_TURRET_TURN;
	wait-for-turn tl_front around y-axis;
	start-script RestoreTurret();
	return (TRUE);
}

Shot18(foo)
{
	tl1Flare = tl1Flare + 1;
	if(tl1Flare > 5)
	{
		tl1Flare = 1;
	}
}

FireWeapon18()
{
	if(tl1Flare == 1)
	{
		show torp1_f;
		sleep 200;
		hide torp1_f;
	}
	if(tl1Flare == 2)
	{
		show torp2_f;
		sleep 200;
		hide torp2_f;
	}
	if(tl1Flare == 3)
	{
		show torp3_f;
		sleep 200;
		hide torp3_f;
	}
	if(tl1Flare == 4)
	{
		show torp4_f;
		sleep 200;
		hide torp4_f;
	}
	if(tl1Flare == 5)
	{
		show torp5_f;
		sleep 200;
		hide torp5_f;
	}
}

QueryWeapon19(piecenum)
{
	if(tl2Flare == 1)
	{
		piecenum = torp1_r;
	}
	if(tl2Flare == 2)
	{
		piecenum = torp2_r;
	}
	if(tl2Flare == 3)
	{
		piecenum = torp3_r;
	}
	if(tl2Flare == 4)
	{
		piecenum = torp4_r;
	}
	if(tl2Flare == 5)
	{
		piecenum = torp5_r;
	}
}

AimFromWeapon19(piecenum)
{
	piecenum = tl_rear;
}

AimWeapon19(heading, pitch)
{
	signal SIG_AIM19;
	set-signal-mask SIG_AIM19|SIG_DEATH;
	turn tl_rear to y-axis heading speed TL_TURRET_TURN;
	wait-for-turn tl_rear around y-axis;
	start-script RestoreTurret();
	return (TRUE);
}

Shot19(foo)
{
	tl2Flare = tl2Flare + 1;
	if(tl2Flare > 5)
	{
		tl2Flare = 1;
	}
}

FireWeapon19()
{
	if(tl2Flare == 1)
	{
		show torp1_r;
		sleep 200;
		hide torp1_r;
	}
	if(tl2Flare == 2)
	{
		show torp2_r;
		sleep 200;
		hide torp2_r;
	}
	if(tl2Flare == 3)
	{
		show torp3_r;
		sleep 200;
		hide torp3_r;
	}
	if(tl2Flare == 4)
	{
		show torp4_r;
		sleep 200;
		hide torp4_r;
	}
	if(tl2Flare == 5)
	{
		show torp5_r;
		sleep 200;
		hide torp5_r;
	}
}

Killed(severity, corpsetype)
{
	signal SIG_DEATH;
	if (severity<99)
	{
		corpsetype = 1;
		turn hull to x-axis (0-HULL_LIST_ANGLE_X) speed HULL_LIST_SPEED;
		turn hull to z-axis (0-HULL_LIST_ANGLE_Z) speed HULL_LIST_SPEED;
		wait-for-turn hull around x-axis;
		wait-for-turn hull around z-axis;
		return (TRUE);
	}
	corpsetype = 1;
	return (TRUE);
}