build.gradle

plugins {
    id "java"
    id "org.jetbrains.kotlin.jvm" version "1.8.20"
    id "org.jetbrains.intellij" version "1.13.3"
}

def pluginVersion = "1.6.0"
def pluginSinceBuild = "203.5981.155"
def pluginUntilBuild = ""
def flexmarkVersion = "0.64.4"
def javaVersion = "11"

group = "com.vladsch.clionarduinoplugin"
version = pluginVersion

repositories {
    mavenCentral()
/*
    // NOTE: using plugin in intellij config instead of jar, since the plugin is now available
    maven {
        name = "GitHubPackages"
        url = "https://maven.pkg.github.com/vsch/SimpleSerialConnectorService"
        credentials {
            username = System.getenv("GITHUB_ACTOR")
            password = System.getenv("GITHUB_TOKEN")
        }
    }
*/
    mavenLocal() {
        content {
            includeGroup "com.vladsch.plugin-util"
        }
    }
}

// Configure Gradle IntelliJ Plugin
// Read more: https://plugins.jetbrains.com/docs/intellij/tools-gradle-intellij-plugin.html
intellij {
    version = "2020.3"
    type = "CL" // Target IDE Platform

    plugins = ["com.intellij.clion", "com.intellij.cidr.base", "com.vladsch.plugins.SimpleSerialConnectorService:1.0.4"]
    downloadSources = true
}

dependencies {
    testImplementation("junit:junit:4.13.2")
    testImplementation("com.vladsch.flexmark:flexmark-test-util:$flexmarkVersion")

    // for newer versions of CLion need to include the older clion.jar
    // compileOnly(files("excluded_lib/clion.jar"))

    implementation("com.vladsch.flexmark:flexmark:$flexmarkVersion")
    implementation("com.vladsch.flexmark:flexmark-util:$flexmarkVersion")
    implementation("com.vladsch.flexmark:flexmark-tree-iteration:$flexmarkVersion")

    implementation("org.jetbrains:annotations:24.0.1")
    implementation('commons-io:commons-io:2.11.0')
    implementation("com.vladsch.plugin-util:plugin-util-lib:1.201.8")
}

sourceSets {
    main {
        java {
            srcDirs = ["src"]
            resources.srcDirs = ["resources"]
        }

        kotlin {
            //noinspection GroovyAssignabilityCheck
            srcDirs = ["src"]
        }
    }

    test {
        java {
            srcDirs = ["test"]
            resources.srcDirs = ["test-resources", "test"]
        }

        kotlin {
            //noinspection GroovyAssignabilityCheck
            srcDirs = ["test"]
        }
    }
}

// Set the JVM compatibility versions
compileJava {
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
}

compileKotlin {
    kotlinOptions.jvmTarget = javaVersion
}

tasks {

    patchPluginXml {
        sinceBuild = pluginSinceBuild
        untilBuild = pluginUntilBuild
        version = pluginVersion
    }

    signPlugin {
        certificateChainFile = file(System.getenv("CERTIFICATE_CHAIN"))
        privateKeyFile = file(System.getenv("PRIVATE_KEY"))
        password = System.getenv("PRIVATE_KEY_PASSWORD")
    }

    publishPlugin {
        token = System.getenv("PUBLISH_TOKEN")
    }
}