101-app-service-environment

quickstart/101-app-service-environment/README.md

@@ -0,0 +1,23 @@
+# Azure App Service Environment v3
+This template deploys an Azure App Service Environment v3.
+
+## Terraform resource types
+
+- [random_pet](https://registry.terraform.io/providers/hashicorp/random/latest/docs/resources/pet)
+- [azurerm_resource_group](https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/resource_group)
+- [azurerm_virtual_network](https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/virtual_network)
+- [azurerm_subnet](https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/subnet)
+- [random_string](https://registry.terraform.io/providers/hashicorp/random/latest/docs/resources/string)
+- [azurerm_app_service_environment_v3](https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/app_service_environment_v3)
+
+## Variables
+
+| Name | Description | Default value |
+|-|-|-|
+| `resource_group_name_prefix` | Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription. | rg |
+| `resource_group_location` | Location of the resource group. | eastus |
+| `virtual_network_name` | Name of the virtual network resource. | "" |
+| `subnet_name` | Name of the virtual network subnet. | "" |
+| `app_service_environment_v3_name` | Name of the App Service Environment v3 resource. | "" |
+
+## Example

quickstart/101-app-service-environment/main.tf

@@ -0,0 +1,83 @@
+resource "random_pet" "rg_name" {
+  prefix = var.resource_group_name_prefix
+}
+
+resource "azurerm_resource_group" "rg" {
+  location = var.resource_group_location
+  name     = random_pet.rg_name.id
+}
+
+resource "random_string" "azurerm_virtual_network_name" {
+  length  = 13
+  lower   = true
+  numeric = false
+  special = false
+  upper   = false
+}
+
+resource "azurerm_virtual_network" "example" {
+  name                = coalesce(var.virtual_network_name, "vnet-${random_string.azurerm_virtual_network_name.result}")
+  resource_group_name = azurerm_resource_group.rg.name
+  location            = azurerm_resource_group.rg.location
+  address_space       = ["10.0.0.0/16"]
+}
+
+resource "random_string" "azurerm_subnet_name" {
+  length  = 13
+  lower   = true
+  numeric = false
+  special = false
+  upper   = false
+}
+
+resource "azurerm_subnet" "ase" {
+  name                 = coalesce(var.subnet_name, "subnet-${random_string.azurerm_subnet_name.result}")
+  resource_group_name  = azurerm_resource_group.rg.name
+  virtual_network_name = azurerm_virtual_network.example.name
+  address_prefixes     = ["10.0.1.0/24"]
+
+  delegation {
+    name = "delegation"
+
+    service_delegation {
+      name    = "Microsoft.Web/hostingEnvironments"
+      actions = ["Microsoft.Network/virtualNetworks/subnets/action"]
+    }
+  }
+}
+
+resource "random_string" "azurerm_app_service_environment_v3_name" {
+  length  = 13
+  lower   = true
+  numeric = false
+  special = false
+  upper   = false
+}
+
+resource "azurerm_app_service_environment_v3" "example" {
+  name                = coalesce(var.app_service_environment_v3_name, "asev3-${random_string.azurerm_app_service_environment_v3_name.result}")
+  resource_group_name = azurerm_resource_group.rg.name
+  subnet_id           = azurerm_subnet.ase.id
+
+  internal_load_balancing_mode = "Web, Publishing"
+
+  cluster_setting {
+    name  = "DisableTls1.0"
+    value = "1"
+  }
+
+  cluster_setting {
+    name  = "InternalEncryption"
+    value = "true"
+  }
+
+  cluster_setting {
+    name  = "FrontEndSSLCipherSuiteOrder"
+    value = "TLS_ECDHE_RSA_WITH_AES_256_GCM_SHA384,TLS_ECDHE_RSA_WITH_AES_128_GCM_SHA256"
+  }
+
+  tags = {
+    env         = "production"
+    terraformed = "true"
+  }
+}

quickstart/101-app-service-environment/outputs.tf

@@ -0,0 +1,15 @@
+output "resource_group_name" {
+  value = azurerm_resource_group.rg.name
+}
+
+output "virtual_network_name" {
+  value = azurerm_virtual_network.example.name
+}
+
+output "subnet_name" {
+  value = azurerm_subnet.ase.name
+}
+
+output "app_service_environment_v3_name" {
+  value = azurerm_app_service_environment_v3.example.name
+}

quickstart/101-app-service-environment/providers.tf

@@ -0,0 +1,18 @@
+terraform {
+  required_version = ">=1.0"
+
+  required_providers {
+    azurerm = {
+      source  = "hashicorp/azurerm"
+      version = "~>3.0"
+    }
+    random = {
+      source  = "hashicorp/random"
+      version = "~>3.0"
+    }
+  }
+}
+
+provider "azurerm" {
+  features {}
+}

quickstart/101-app-service-environment/variables.tf

@@ -0,0 +1,29 @@
+variable "resource_group_name_prefix" {
+  type        = string
+  default     = "rg"
+  description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
+}
+
+variable "resource_group_location" {
+  type        = string
+  default     = "eastus"
+  description = "Location of the resource group."
+}
+
+variable "virtual_network_name" {
+  type        = string
+  description = "The name of the virtual network resource. The value will be randomly generated if blank."
+  default     = ""
+}
+
+variable "subnet_name" {
+  type        = string
+  description = "The name of the virtual network subnet. The value will be randomly generated if blank."
+  default     = ""
+}
+
+variable "app_service_environment_v3_name" {
+  type        = string
+  description = "The name of the App Service Environment v3 resource. The value will be randomly generated if blank."
+  default     = ""
+}