chore: migrate to gradle.kts, clean up build scripts (#21)

build.gradle.kts

@@ -0,0 +1,84 @@
+import com.diffplug.gradle.spotless.SpotlessExtension
+
+plugins {
+    id("org.jetbrains.kotlinx.kover") version "0.5.0"
+    id("com.diffplug.gradle.spotless") version "6.2.0" apply false
+    id("org.jetbrains.kotlin.jvm") version "1.6.10" apply false
+}
+
+subprojects {
+    pluginManager.apply("com.diffplug.spotless")
+
+    configure<SpotlessExtension> {
+        kotlin {
+            ktlint()
+            licenseHeaderFile(rootProject.file("spotless.license.java.txt"))
+        }
+
+        kotlinGradle {
+            ktlint()
+            target("*.gradle.kts")
+        }
+    }
+
+    afterEvaluate {
+        tasks.withType<Test> {
+            testLogging {
+                events("passed", "skipped", "failed")
+            }
+        }
+    }
+
+    pluginManager.withPlugin("maven-publish") {
+        apply<JavaPlugin>()
+
+        version = extra["VERSION_NAME"] as String
+        group = extra["GROUP"] as String
+
+        configure<JavaPluginExtension> {
+            withSourcesJar()
+            withJavadocJar()
+        }
+
+        configure<PublishingExtension> {
+            publications {
+                create<MavenPublication>("maven") {
+                    from(components["java"])
+
+                    groupId = extra["GROUP"] as String
+                    artifactId = extra["POM_ARTIFACT_ID"] as String
+                    version = extra["VERSION_NAME"] as String
+
+                    pom {
+                        packaging = extra["POM_PACKAGING"] as String
+
+                        name.set(extra["POM_NAME"] as String)
+                        description.set(extra["POM_DESCRIPTION"] as String)
+                        url.set(extra["POM_URL"] as String)
+
+                        scm {
+                            url.set(extra["POM_SCM_URL"] as String)
+                            connection.set(extra["POM_SCM_CONNECTION"] as String)
+                            developerConnection.set(extra["POM_SCM_DEV_CONNECTION"] as String)
+                        }
+
+                        licenses {
+                            license {
+                                name.set(extra["POM_LICENCE_NAME"] as String)
+                                url.set(extra["POM_LICENCE_URL"] as String)
+                                distribution.set(extra["POM_LICENCE_DIST"] as String)
+                            }
+                        }
+
+                        developers {
+                            developer {
+                                id.set(extra["POM_DEVELOPER_ID"] as String)
+                                name.set(extra["POM_DEVELOPER_NAME"] as String)
+                            }
+                        }
+                    }
+                }
+            }
+        }
+    }
+}

gradle/libs.versions.toml

@@ -0,0 +1,14 @@
+[libraries]
+inject = "javax.inject:javax.inject:1"
+
+kotlinpoet-core = "com.squareup:kotlinpoet:1.10.2"
+kotlinpoet-ksp = "com.squareup:kotlinpoet-ksp:1.10.2"
+ksp = "com.google.devtools.ksp:symbol-processing-api:1.6.10-1.0.4"
+
+tp = "com.github.stephanenicolas.toothpick:toothpick:3.1.0"
+
+junit4 = "junit:junit:4.13-beta-3"
+compiletesting-kt = "com.github.tschuchortdev:kotlin-compile-testing:1.4.7"
+compiletesting-ksp = "com.github.tschuchortdev:kotlin-compile-testing-ksp:1.4.7"
+mockito = "org.mockito:mockito-core:2.4.0"
+mockito_kotlin = "com.nhaarman.mockitokotlin2:mockito-kotlin:2.1.0"

gradle/wrapper/gradle-wrapper.properties

@@ -1,5 +1,5 @@
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-7.3.3-all.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-7.4.2-all.zip
 zipStoreBase=GRADLE_USER_HOME
 zipStorePath=wrapper/dists

settings.gradle.kts

@@ -0,0 +1,15 @@
+rootProject.name = "toothpick-compiler-ksp-parent"
+
+include(":toothpick-compiler-ksp")
+include(":toothpick-compiler-ksp-core")
+include(":toothpick-compiler-ksp-factory")
+include(":toothpick-compiler-ksp-memberinjector")
+include(":toothpick-compiler-test")
+
+dependencyResolutionManagement {
+    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
+    repositories {
+        google()
+        mavenCentral()
+    }
+}

toothpick-compiler-ksp-core/build.gradle.kts

@@ -0,0 +1,22 @@
+import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
+
+plugins {
+    id("org.jetbrains.kotlin.jvm")
+    `maven-publish`
+}
+
+tasks.withType<KotlinCompile> {
+    kotlinOptions {
+        jvmTarget = "1.8"
+    }
+}
+
+dependencies {
+    api(libs.inject)
+    api(libs.tp)
+
+    implementation(libs.ksp)
+
+    implementation(libs.kotlinpoet.core)
+    implementation(libs.kotlinpoet.ksp)
+}