add nix devenv flake

.envrc

@@ -0,0 +1 @@
+use flake

flake.nix

@@ -0,0 +1,94 @@
+{
+  description = "VATSIM LoA";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable-small";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    systems.url = "github:nix-systems/default-linux";
+
+    pyproject-nix = {
+      url = "github:nix-community/pyproject.nix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
+    uv2nix = {
+      url = "github:adisbladis/uv2nix";
+      inputs.pyproject-nix.follows = "pyproject-nix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
+    pyproject-build-systems = {
+      url = "github:pyproject-nix/build-system-pkgs";
+      inputs.pyproject-nix.follows = "pyproject-nix";
+      inputs.uv2nix.follows = "uv2nix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs =
+    inputs:
+    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
+      systems = import inputs.systems;
+
+      perSystem =
+        { pkgs, lib, ... }:
+        let
+          workspace = inputs.uv2nix.lib.workspace.loadWorkspace { workspaceRoot = ./.; };
+
+          overlay = workspace.mkPyprojectOverlay {
+            sourcePreference = "wheel";
+          };
+
+          python = pkgs.python313;
+
+          pythonSet =
+            (pkgs.callPackage inputs.pyproject-nix.build.packages {
+              inherit python;
+            }).overrideScope
+              (
+                lib.composeManyExtensions [
+                  inputs.pyproject-build-systems.overlays.default
+                  overlay
+                ]
+              );
+        in
+        {
+          formatter = pkgs.nixfmt-rfc-style;
+
+          packages = {
+            default = pythonSet.mkVirtualEnv "loa-env" workspace.deps.default;
+          };
+
+          devShells = {
+            impure = pkgs.mkShell {
+              packages = [
+                python
+                pkgs.uv
+              ];
+              shellHook = ''
+                unset PYTHONPATH
+              '';
+            };
+
+            default =
+              let
+                editableOverlay = workspace.mkEditablePyprojectOverlay {
+                  root = "$REPO_ROOT";
+                };
+                editablePythonSet = pythonSet.overrideScope editableOverlay;
+                virtualenv = editablePythonSet.mkVirtualEnv "loa-dev-env" workspace.deps.all;
+              in
+              pkgs.mkShell {
+                packages = [
+                  virtualenv
+                  pkgs.uv
+                ];
+                shellHook = ''
+                  unset PYTHONPATH
+                  export REPO_ROOT=$(git rev-parse --show-toplevel)
+                '';
+              };
+          };
+        };
+    };
+}