Karpatkey-Gho-Growth (#559)

* feat: karpatkey funding proposal - gho growth

* feat: update md file and merge main

* chore: remove unused dependencies

* chore: update aave-helper

* Update src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/karpatkeyGhoGrowth.md

Co-authored-by: Harsh Pandey <[email protected]>

---------

Co-authored-by: Harsh Pandey <[email protected]>

diffs/AaveV3Ethereum_karpatkeyGhoGrowth_20241231_before_AaveV3Ethereum_karpatkeyGhoGrowth_20241231_after.md

@@ -0,0 +1,5 @@
+## Raw diff
+
+```json
+{}
+```

src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/AaveV3Ethereum_karpatkeyGhoGrowth_20241231.sol

@@ -0,0 +1,47 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {CollectorUtils, ICollector} from 'aave-helpers/src/CollectorUtils.sol';
+import {AaveV3Ethereum, AaveV3EthereumAssets} from 'aave-address-book/AaveV3Ethereum.sol';
+import {AaveV3EthereumLido, AaveV3EthereumLidoAssets} from 'aave-address-book/AaveV3EthereumLido.sol';
+import {IProposalGenericExecutor} from 'aave-helpers/src/interfaces/IProposalGenericExecutor.sol';
+
+/**
+ * @title karpatkey Gho Growth Service Provider
+ * @author karpatkey
+ * - Snapshot: https://snapshot.box/#/s:aave.eth/proposal/0x87585d9dcb104d2946ca2def6bcf57708480fafc5e310de4850dc2fbe1820893
+ * - Discussion: https://governance.aave.com/t/arfc-karpatkey-as-gho-growth-service-provider/20206
+ */
+contract AaveV3Ethereum_karpatkeyGhoGrowth_20241231 is IProposalGenericExecutor {
+  using CollectorUtils for ICollector;
+
+  uint256 public constant KARPATKEY_STREAM_AMOUNT = 250_000e18;
+  address public constant KARPATKEY_SAFE = 0x58e6c7ab55Aa9012eAccA16d1ED4c15795669E1C;
+  uint256 public constant STREAM_DURATION = 180 days;
+  uint256 public constant STREAM_START_TIME = 1734912000; // Sun Dec 23 2024 12:00 GMT+0000
+  uint256 public constant ACTUAL_STREAM_AMOUNT =
+    (KARPATKEY_STREAM_AMOUNT / STREAM_DURATION) * STREAM_DURATION;
+
+  function execute() external override {
+    uint256 backDatedAmount = (ACTUAL_STREAM_AMOUNT * (block.timestamp - STREAM_START_TIME)) /
+      STREAM_DURATION;
+
+    // transfer backend amount
+    AaveV3Ethereum.COLLECTOR.transfer(
+      AaveV3EthereumLidoAssets.GHO_A_TOKEN,
+      KARPATKEY_SAFE,
+      backDatedAmount
+    );
+
+    // stream
+    AaveV3Ethereum.COLLECTOR.stream(
+      CollectorUtils.CreateStreamInput({
+        underlying: AaveV3EthereumLidoAssets.GHO_A_TOKEN,
+        receiver: KARPATKEY_SAFE,
+        amount: ACTUAL_STREAM_AMOUNT - backDatedAmount,
+        start: block.timestamp,
+        duration: STREAM_DURATION + STREAM_START_TIME - block.timestamp
+      })
+    );
+  }
+}

src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/AaveV3Ethereum_karpatkeyGhoGrowth_20241231.t.sol

@@ -0,0 +1,103 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {AaveV3Ethereum, AaveV3EthereumAssets} from 'aave-address-book/AaveV3Ethereum.sol';
+import {AaveV3EthereumLido, AaveV3EthereumLidoAssets} from 'aave-address-book/AaveV3EthereumLido.sol';
+import {IERC20} from 'solidity-utils/contracts/oz-common/interfaces/IERC20.sol';
+
+import 'forge-std/Test.sol';
+import {ProtocolV3TestBase, ReserveConfig} from 'aave-helpers/src/ProtocolV3TestBase.sol';
+import {AaveV3Ethereum_karpatkeyGhoGrowth_20241231} from './AaveV3Ethereum_karpatkeyGhoGrowth_20241231.sol';
+
+/**
+ * @dev Test for AaveV3Ethereum_karpatkeyGhoGrowth_20241231
+ * command: FOUNDRY_PROFILE=mainnet forge test --match-path=src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/AaveV3Ethereum_karpatkeyGhoGrowth_20241231.t.sol -vv
+ */
+contract AaveV3Ethereum_karpatkeyGhoGrowth_20241231_Test is ProtocolV3TestBase {
+  AaveV3Ethereum_karpatkeyGhoGrowth_20241231 internal proposal;
+
+  function setUp() public {
+    vm.createSelectFork(vm.rpcUrl('mainnet'), 21524445);
+    proposal = new AaveV3Ethereum_karpatkeyGhoGrowth_20241231();
+  }
+
+  /**
+   * @dev executes the generic test suite including e2e and config snapshots
+   */
+  function test_defaultProposalExecution() public {
+    defaultTest(
+      'AaveV3Ethereum_karpatkeyGhoGrowth_20241231',
+      AaveV3Ethereum.POOL,
+      address(proposal)
+    );
+  }
+
+  function test_stream() public {
+    uint256 backDatedAmount = (proposal.ACTUAL_STREAM_AMOUNT() *
+      (block.timestamp - proposal.STREAM_START_TIME())) / proposal.STREAM_DURATION();
+
+    uint256 nextCollectorStreamID = AaveV3Ethereum.COLLECTOR.getNextStreamId();
+
+    executePayload(vm, address(proposal));
+
+    (
+      address sender,
+      address recipient,
+      uint256 deposit,
+      address tokenAddress,
+      uint256 startTime,
+      uint256 stopTime,
+      uint256 remainingBalance,
+
+    ) = AaveV3Ethereum.COLLECTOR.getStream(nextCollectorStreamID);
+
+    assertEq(sender, address(AaveV3Ethereum.COLLECTOR));
+    assertEq(recipient, proposal.KARPATKEY_SAFE());
+    assertEq(deposit, proposal.ACTUAL_STREAM_AMOUNT() - backDatedAmount);
+    assertEq(tokenAddress, AaveV3EthereumLidoAssets.GHO_A_TOKEN);
+    assertEq(startTime, block.timestamp);
+    assertEq(stopTime, proposal.STREAM_START_TIME() + proposal.STREAM_DURATION());
+    assertEq(remainingBalance, proposal.ACTUAL_STREAM_AMOUNT() - backDatedAmount);
+
+    // Can withdraw during stream
+    vm.warp(block.timestamp + 30 days);
+
+    uint256 collectorGhoBalanceBefore = IERC20(AaveV3EthereumLidoAssets.GHO_A_TOKEN).balanceOf(
+      address(AaveV3Ethereum.COLLECTOR)
+    );
+    uint256 receiverGhoBalanceBefore = IERC20(AaveV3EthereumLidoAssets.GHO_A_TOKEN).balanceOf(
+      proposal.KARPATKEY_SAFE()
+    );
+
+    vm.startPrank(proposal.KARPATKEY_SAFE());
+    AaveV3Ethereum.COLLECTOR.withdrawFromStream(
+      nextCollectorStreamID,
+      proposal.ACTUAL_STREAM_AMOUNT() / 9
+    );
+    vm.stopPrank();
+
+    assertGt(
+      IERC20(AaveV3EthereumLidoAssets.GHO_A_TOKEN).balanceOf(proposal.KARPATKEY_SAFE()),
+      receiverGhoBalanceBefore
+    );
+
+    assertLt(
+      IERC20(AaveV3EthereumLidoAssets.GHO_A_TOKEN).balanceOf(address(AaveV3Ethereum.COLLECTOR)),
+      collectorGhoBalanceBefore
+    );
+
+    // Can withdraw post stream all remaining funds
+    vm.warp(block.timestamp + proposal.STREAM_DURATION());
+
+    (, , , , , , uint256 remaining, ) = AaveV3Ethereum.COLLECTOR.getStream(nextCollectorStreamID);
+
+    vm.startPrank(proposal.KARPATKEY_SAFE());
+    AaveV3Ethereum.COLLECTOR.withdrawFromStream(nextCollectorStreamID, remaining);
+    vm.stopPrank();
+
+    assertEq(
+      IERC20(AaveV3EthereumLidoAssets.GHO_A_TOKEN).balanceOf(proposal.KARPATKEY_SAFE()),
+      receiverGhoBalanceBefore + proposal.ACTUAL_STREAM_AMOUNT() - backDatedAmount
+    );
+  }
+}

src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/config.ts

@@ -0,0 +1,16 @@
+import {ConfigFile} from '../../generator/types';
+export const config: ConfigFile = {
+  rootOptions: {
+    pools: ['AaveV3Ethereum'],
+    title: 'karpatkey Gho Growth Service Provider',
+    shortName: 'karpatkeyGhoGrowthServiceProvider',
+    date: '20241231',
+    author: 'karpatkey',
+    discussion:
+      ' https://governance.aave.com/t/arfc-karpatkey-as-gho-growth-service-provider/20206',
+    snapshot:
+      'https://snapshot.box/#/s:aave.eth/proposal/0x87585d9dcb104d2946ca2def6bcf57708480fafc5e310de4850dc2fbe1820893',
+    votingNetwork: 'POLYGON',
+  },
+  poolOptions: {AaveV3Ethereum: {configs: {}, cache: {blockNumber: 21524445}}},
+};

src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/karpatkeyGhoGrowth.md

@@ -0,0 +1,48 @@
+---
+title: "Funding Proposal: karpatkey as GHO Growth Service Provider"
+author: "karpatkey"
+discussions: https://governance.aave.com/t/arfc-karpatkey-as-gho-growth-service-provider/20206
+snapshot: https://snapshot.box/#/s:aave.eth/proposal/0x87585d9dcb104d2946ca2def6bcf57708480fafc5e310de4850dc2fbe1820893
+---
+
+## Simple Summary
+
+The AIP proposes appointing karpatkey as a service provider dedicated to drive the growth of GHO for the following 6 months, with an initial focus on opportunities within the Gnosis Chain while also expanding efforts to other chains.
+
+## Motivation
+
+Over the past 12 months, karpatkey has been pleased to have supported the AaveDAO in improving treasury management practices and GHO adoption (see Phase 1 and Phase 2 for more details). These efforts have been a significant success, and will continue, with the deployment of the Finance Steward upcoming features. That said, by focusing on increasing GHO’s adoption, we believe karpatkey can provide more value to the Aave ecosystem.
+
+The stablecoin ecosystem is one of the most dynamic and competitive sectors in the DeFi landscape, and the accelerating adoption of GHO represents a unique opportunity for Aave DAO to solidify its position as a leader in this space. Since its deployment over a year ago, GHO achieved a notable milestone of a 180M supply across mainnet and Arbitrum, market depth in most reputable DEXes with total liquidity ranging between $30M and $50M. This success is a testament to the strength of Aave’s products, user base and brand.
+
+While GHO’s initial growth has been remarkable, the stablecoin market is evolving rapidly. The demand for reliable, decentralised stablecoins continues to grow, and GHO is well-positioned to capture this market—provided we continue to expand its utility, adoption, and ecosystem integrations proactively.
+
+karpatkey has the tools and resources to capitalise on the range of opportunities GHO presents. With a proven track record in DeFi innovation and strong partnerships with other DAOs, we are excited to present our new 6-month proposal to Aave DAO, focused on the areas where we can contribute most.
+
+To drive proactive growth and expansion of GHO across multiple blockchains, we are proposing a phased mandate that includes tailored strategies for each ecosystem, with the initial phase prioritizing the deployment and adoption of GHO on the Gnosis Chain. With an Aave instance holding $100M, Gnosis Chain currently has a total value locked of $410M and a thriving environment of stablecoins, which includes Gnosis Pay, Monerium’s e-money EURe and other RWAs. We plan to focus primarily on opportunities where both AaveDAO and GnosisDAO can mutually benefit from a vibrant GHO ecosystem on Gnosis Chain, taking advantage of karpatkey’s unique position supporting both the DeFi ecosystems of both DAOs.
+
+## Terms
+
+- 6-month engagement, December 23th 2024 to June 21th 2025;
+- $250k, streamed linearly throughout the engagement;
+
+## Specification
+
+Create the following stream allowing TokenLogic to withdraw aEthLidoGHO from the Prime instance.
+
+- Recipient: karpatkey
+- Stream: 250K aEthLidoGHO over 180 days
+- Address: `0x58e6c7ab55aa9012eacca16d1ed4c15795669e1c`
+
+The stream shall commence the next block from when the previous stream finishes.
+
+## References
+
+- Implementation: [AaveV3Ethereum](https://github.com/bgd-labs/aave-proposals-v3/blob/main/src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/AaveV3Ethereum_karpatkeyGhoGrowth_20241231.sol)
+- Tests: [AaveV3Ethereum](https://github.com/bgd-labs/aave-proposals-v3/blob/main/src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/AaveV3Ethereum_karpatkeyGhoGrowth_20241231.t.sol)
+  [Snapshot](https://snapshot.box/#/s:aave.eth/proposal/0x87585d9dcb104d2946ca2def6bcf57708480fafc5e310de4850dc2fbe1820893)
+- [Discussion](https://governance.aave.com/t/arfc-karpatkey-as-gho-growth-service-provider/20206)
+
+## Copyright
+
+Copyright and related rights waived via [CC0](https://creativecommons.org/publicdomain/zero/1.0/).

src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/karpatkeyGhoGrowth_20241231.s.sol

@@ -0,0 +1,60 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {GovV3Helpers, IPayloadsControllerCore, PayloadsControllerUtils} from 'aave-helpers/src/GovV3Helpers.sol';
+import {GovernanceV3Ethereum} from 'aave-address-book/GovernanceV3Ethereum.sol';
+import {EthereumScript} from 'solidity-utils/contracts/utils/ScriptUtils.sol';
+import {AaveV3Ethereum_karpatkeyGhoGrowth_20241231} from './AaveV3Ethereum_karpatkeyGhoGrowth_20241231.sol';
+
+/**
+ * @dev Deploy Ethereum
+ * deploy-command: make deploy-ledger contract=src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/AaveV3Ethereum_karpatkeyGhoGrowth_20241231.s.sol:DeployEthereum chain=mainnet
+ * verify-command: FOUNDRY_PROFILE=mainnet npx catapulta-verify -b broadcast/AaveV3Ethereum_karpatkeyGhoGrowth_20241231.s.sol/1/run-latest.json
+ */
+contract DeployEthereum is EthereumScript {
+  function run() external broadcast {
+    // deploy payloads
+    address payload0 = GovV3Helpers.deployDeterministic(
+      type(AaveV3Ethereum_karpatkeyGhoGrowth_20241231).creationCode
+    );
+
+    // compose action
+    IPayloadsControllerCore.ExecutionAction[]
+      memory actions = new IPayloadsControllerCore.ExecutionAction[](1);
+    actions[0] = GovV3Helpers.buildAction(payload0);
+
+    // register action at payloadsController
+    GovV3Helpers.createPayload(actions);
+  }
+}
+
+/**
+ * @dev Create Proposal
+ * command: make deploy-ledger contract=src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/AaveV3Ethereum_karpatkeyGhoGrowth_20241231.s.sol:CreateProposal chain=mainnet
+ */
+contract CreateProposal is EthereumScript {
+  function run() external {
+    // create payloads
+    PayloadsControllerUtils.Payload[] memory payloads = new PayloadsControllerUtils.Payload[](1);
+
+    // compose actions for validation
+    IPayloadsControllerCore.ExecutionAction[]
+      memory actionsEthereum = new IPayloadsControllerCore.ExecutionAction[](1);
+    actionsEthereum[0] = GovV3Helpers.buildAction(
+      type(AaveV3Ethereum_karpatkeyGhoGrowth_20241231).creationCode
+    );
+    payloads[0] = GovV3Helpers.buildMainnetPayload(vm, actionsEthereum);
+
+    // create proposal
+    vm.startBroadcast();
+    GovV3Helpers.createProposal(
+      vm,
+      payloads,
+      GovernanceV3Ethereum.VOTING_PORTAL_ETH_POL,
+      GovV3Helpers.ipfsHashFile(
+        vm,
+        'src/20241231_AaveV3Ethereum_karpatkeyGhoGrowth/karpatkeyGhoGrowth.md'
+      )
+    );
+  }
+}