media-sound/lms: add 3.55.0

Signed-off-by: David Roman <[email protected]>

media-sound/lms/Manifest

@@ -1 +1,2 @@
 DIST lms-3.54.0.tar.gz 428132 BLAKE2B bec14813d42e5a0d2854c62827218c06b56d092e6228ff7b32b37a0c0d85f545eb8747c8108dd390e445d28921c4a79f4a86d9985a3d1e0ffe888b4beb1a2261 SHA512 e0434c12d460d9ee2a1aaaa32ef0344dbce7ee11d250d31a9f3f08213834e48620f8c14ed97ba6a625c6a8f292efdbe1dcd90d50ce3c51b369c6d67c5ac6a0c9
+DIST lms-3.55.0.tar.gz 435761 BLAKE2B 355a5c356b70d01ad8141209f479541a8b2fbedc6a289a86f117d6de5981903edbb08c7e4648c315ceb191b88f18840370fff5ad912b5993b3d557e1b1109c8a SHA512 8dcc6335d25e372b161034e8caa8ca182c7320569b16648db824a118013f647711da7d7c38a8aabc12eb608e203d14c6fe332b4a8b14125726e030f4e591eb3e

media-sound/lms/lms-3.55.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake pam systemd
+
+DESCRIPTION="Lightweight Music Server."
+HOMEPAGE="https://lms-demo.poupon.dev/ https://github.com/epoupon/lms"
+SRC_URI="https://github.com/epoupon/lms/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test stb"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-user/lms
+	dev-cpp/wt
+	dev-libs/boost
+	dev-libs/libconfig[cxx]
+	media-libs/taglib
+	media-video/ffmpeg[mp3,opus]
+
+	!stb? ( media-gfx/graphicsmagick )
+
+"
+
+DEPEND="
+	${RDEPEND}
+
+	stb? ( dev-libs/stb )
+"
+
+BDEPEND="
+	test? ( dev-cpp/gtest )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-respect-ldflags.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DLMS_IMAGE_BACKEND=$(usex stb stb graphicsmagick)
+		-DENABLE_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	systemd_newunit conf/systemd/default.service lms.service
+	newinitd "${FILESDIR}/lms.init" lms
+	dopamd conf/pam/lms
+	mv "${ED}/usr/share/lms/lms.conf" "${ED}/etc/lms.conf" || die
+
+	# Already installed in the proper directory
+	rm "${ED}/usr/share/lms/default.service" || die
+	rm "${ED}/usr/share/lms/lms" || die
+
+	keepdir /var/log/lms
+	fowners -R lms:lms /var/log/lms
+
+	keepdir /var/lms
+	fowners lms:lms /var/lms
+}