RP2040_ISR_Servo Library

---

---

Table of Contents

• Important Change from v1.1.0
• Why do we need this RP2040_ISR_Servo library
  • Features
  • Important Notes about using ISR
  • Currently supported Boards
• Changelog
• Prerequisites
• Installation
  • Use Arduino Library Manager
  • Manual Install
  • VS Code & PlatformIO
• HOWTO Fix Multiple Definitions Linker Error
• What special in this RP2040_ISR_Servo library
• HOWTO Usage
• Examples
  • 1. RP2040_MultipleRandomServos
  • 2. RP2040_MultipleServos
  • 3. multiFileProject New
• Example RP2040_MultipleServos
  • 1. File RP2040_MultipleServos.ino
• Debug Terminal Output Samples
  • 1. RP2040_MultipleRandomServos on Mbed RaspberryPi Pico
  • 2. RP2040_MultipleRandomServos on RaspberryPi Pico
  • 3. RP2040_MultipleServos on RaspberryPi Pico
• Debug
• Troubleshooting
• Issues
• TO DO
• DONE
• Contributions and Thanks
• Contributing
• License
• Copyright

---

---

Important Change from v1.1.0

Please have a look at HOWTO Fix Multiple Definitions Linker Error

---

---

Why do we need this RP2040_ISR_Servo library

Features

Imagine you have a system with a mission-critical function controlling a robot arm or doing something much more important. You normally use a software timer to poll, or even place the function in loop(). But what if another function is blocking the loop() or setup().

So your function might not be executed, and the result would be disastrous.

You'd prefer to have your function called, no matter what happening with other functions (busy loop, bug, etc.).

The correct choice is to use a Hardware Timer with Interrupt to call your function.

These hardware timers, using interrupt, still work even if other functions are blocking. Moreover, they are much more precise (certainly depending on clock frequency accuracy) than other software timers using millis() or micros(). That's necessary if you need to measure some data requiring better accuracy.

Functions using normal software timers, relying on loop() and calling millis(), won't work if the loop() or setup() is blocked by certain operation. For example, certain function is blocking while it's connecting to WiFi or some services.

This library enables you to use 1 Hardware Timer on an RP2040-based board to control up to 16 independent servo motors.

Important Notes about using ISR

1. Inside the attached function, delay() won’t work and the value returned by millis() will not increment. Serial data received while in the function may be lost. You should declare as volatile any variables that you modify within the attached function.

2. Typically global variables are used to pass data between an ISR and the main program. To make sure variables shared between an ISR and the main program are updated correctly, declare them as volatile.

3. Avoid using Serial.print()-related functions inside ISR. Just for temporary debug purpose, but even this also can crash the system any time. Beware.

4. Your functions are now part of ISR (Interrupt Service Routine), and must be lean / mean, and follow certain rules. More to read on:

HOWTO Attach Interrupt

Currently supported Boards

1. RP2040-based boards such as Nano_RP2040_Connect, RASPBERRY_PI_PICO, ADAFRUIT_FEATHER_RP2040 and GENERIC_RP2040, etc. using Arduino-mbed RP2040 core
2. RP2040-based boards such as Nano_RP2040_Connect, RASPBERRY_PI_PICO, ADAFRUIT_FEATHER_RP2040 and GENERIC_RP2040, etc. using Earle Philhower's arduino-pico core

---

---

Prerequisites

1. Arduino IDE 1.8.19+ for Arduino.
2. Arduino mbed_rp2040 core 3.4.1+ for Arduino (Use Arduino Board Manager) RP2040-based boards, such as Arduino Nano RP2040 Connect, RASPBERRY_PI_PICO, etc..
3. Earle Philhower's arduino-pico core v2.6.3+ for RP2040-based boards such as RASPBERRY_PI_PICO, ADAFRUIT_FEATHER_RP2040 and GENERIC_RP2040, etc.

---

Installation

Use Arduino Library Manager

The best and easiest way is to use Arduino Library Manager. Search for RP2040_ISR_Servo, then select / install the latest version. You can also use this link for more detailed instructions.

Manual Install

Another way to install is to:

1. Navigate to RP2040_ISR_Servo page.
2. Download the latest release RP2040_ISR_Servo-main.zip.
3. Extract the zip file to RP2040_ISR_Servo-main directory
4. Copy whole RP2040_ISR_Servo-main folder to Arduino libraries' directory such as ~/Arduino/libraries/.

VS Code & PlatformIO

1. Install VS Code
2. Install PlatformIO
3. Install RP2040_ISR_Servo library by using Library Manager. Search for RP2040_ISR_Servo in Platform.io Author's Libraries
4. Please visit documentation for the other options and examples at Project Configuration File

---

---

HOWTO Fix Multiple Definitions Linker Error

The current library implementation, using xyz-Impl.h instead of standard xyz.cpp, possibly creates certain Multiple Definitions Linker error in certain use cases.

You can include this .hpp file

// Can be included as many times as necessary, without `Multiple Definitions` Linker Error
#include "RP2040_ISR_Servo.hpp"     //https://github.com/khoih-prog/RP2040_ISR_Servo

in many files. But be sure to use the following .h file in just 1 .h, .cpp or .ino file, which must not be included in any other file, to avoid Multiple Definitions Linker Error

// To be included only in main(), .ino with setup() to avoid `Multiple Definitions` Linker Error
#include "RP2040_ISR_Servo.h"           //https://github.com/khoih-prog/RP2040_ISR_Servo

Check the new multiFileProject example for a HOWTO demo.

Have a look at the discussion in Different behaviour using the src_cpp or src_h lib #80

---

---

What special in this RP2040_ISR_Servo library

Now these new 16 ISR-based Servo controllers just use one RP2040 Hardware Timer. The number 16 is just arbitrarily chosen, and depending on application, you can increase that number to 32, 48, etc. without problem.

The accuracy is nearly perfect compared to software timers. The most important feature is they're ISR-based timers

Therefore, their executions are not blocked by bad-behaving functions / tasks. This important feature is absolutely necessary for mission-critical tasks.

The RP2040_MultipleServos example, which controls 6 servos independently, will demonstrate the nearly perfect accuracy.

Being ISR-based servo controllers, their executions are not blocked by bad-behaving functions / tasks, such as connecting to WiFi, Internet and Blynk services.

This non-being-blocked important feature is absolutely necessary for mission-critical tasks.

---

---

HOWTO Usage

How to use:

#if ( defined(ARDUINO_ARCH_RP2040) || defined(ARDUINO_RASPBERRY_PI_PICO) || defined(ARDUINO_ADAFRUIT_FEATHER_RP2040) || \
      defined(ARDUINO_GENERIC_RP2040) ) && !defined(ARDUINO_ARCH_MBED)
  #if !defined(RP2040_ISR_SERVO_USING_MBED)    
    #define RP2040_ISR_SERVO_USING_MBED     false
  #endif  
  
#elif ( defined(ARDUINO_NANO_RP2040_CONNECT) || defined(ARDUINO_RASPBERRY_PI_PICO) || defined(ARDUINO_ADAFRUIT_FEATHER_RP2040) || \
      defined(ARDUINO_GENERIC_RP2040) ) && defined(ARDUINO_ARCH_MBED)
      
  #if !defined(RP2040_ISR_SERVO_USING_MBED)    
    #define RP2040_ISR_SERVO_USING_MBED     true
  #endif  
  
#else      
  #error This code is intended to run on the mbed / non-mbed RP2040 platform! Please check your Tools->Board setting.
#endif

#define TIMER_INTERRUPT_DEBUG       4
#define ISR_SERVO_DEBUG             4

#include "RP2040_ISR_Servo.h"

// Published values for SG90 servos; adjust if needed
#define MIN_MICROS        800
#define MAX_MICROS        2450 

#define SERVO_PIN_1       16
#define SERVO_PIN_2       17
#define SERVO_PIN_3       18
#define SERVO_PIN_4       19
#define SERVO_PIN_5       20
#define SERVO_PIN_6       21

typedef struct
{
  int     servoIndex;
  uint8_t servoPin;
} ISR_servo_t;

#define NUM_SERVOS            6

ISR_servo_t ISR_servo[NUM_SERVOS] =
{
  { -1, SERVO_PIN_1 }, { -1, SERVO_PIN_2 }, { -1, SERVO_PIN_3 }, { -1, SERVO_PIN_4 }, { -1, SERVO_PIN_5 }, { -1, SERVO_PIN_6 }
};

void setup()
{
  for (int index = 0; index < NUM_SERVOS; index++)
  {
    pinMode(ISR_servo[index].servoPin, OUTPUT);
    digitalWrite(ISR_servo[index].servoPin, LOW);
  }
  
  Serial.begin(115200);
  while (!Serial);

  delay(200);

#if defined(ARDUINO_ARCH_MBED)
  Serial.print(F("\nStarting RP2040_MultipleRandomServos on Mbed "));
#else
  Serial.print(F("\nStarting RP2040_MultipleRandomServos on "));
#endif

  Serial.println(BOARD_NAME);
  Serial.println(RP2040_ISR_SERVO_VERSION);

  for (int index = 0; index < NUM_SERVOS; index++)
  {
    ISR_servo[index].servoIndex = RP2040_ISR_Servos.setupServo(ISR_servo[index].servoPin, MIN_MICROS, MAX_MICROS);

    if (ISR_servo[index].servoIndex != -1)
    {
      Serial.print(F("Setup OK Servo index = ")); Serial.println(ISR_servo[index].servoIndex);

      RP2040_ISR_Servos.setPosition(ISR_servo[index].servoIndex, 0);
    }
    else
    {
      Serial.print(F("Setup Failed Servo index = ")); Serial.println(ISR_servo[index].servoIndex);
    }
  }
}

void printServoInfo(int indexServo)
{
  Serial.print(F("Servos idx = "));
  Serial.print(indexServo);
  Serial.print(F(", act. pos. (deg) = "));
  Serial.print(RP2040_ISR_Servos.getPosition(ISR_servo[indexServo].servoIndex) );
  Serial.print(F(", pulseWidth (us) = "));
  Serial.println(RP2040_ISR_Servos.getPulseWidth(ISR_servo[indexServo].servoIndex));
}

void loop()
{
  int position;      // position in degrees

  position = 0;
  Serial.println(F("Servos @ 0 degree"));
  
  for (int index = 0; index < NUM_SERVOS; index++)
  {
    RP2040_ISR_Servos.setPosition(ISR_servo[index].servoIndex, position );
    printServoInfo(index);
  }
  // waits 5s between test
  delay(5000);

  position = 90;
  Serial.println(F("Servos @ 90 degree"));
  
  for (int index = 0; index < NUM_SERVOS; index++)
  {
    RP2040_ISR_Servos.setPosition(ISR_servo[index].servoIndex, position );
    printServoInfo(index);
  }
  
  // waits 5s between test
  delay(5000);

  position = 180;
  Serial.println(F("Servos @ 180 degree"));
  
  for (int index = 0; index < NUM_SERVOS; index++)
  {
    RP2040_ISR_Servos.setPosition(ISR_servo[index].servoIndex, position );
    printServoInfo(index);
  }
  
  // waits 5s between test
  delay(5000);

  Serial.println(F("Servos sweeps from 0-180 degrees"));
  
  for (position = 0; position <= 180; position += 5)
  {
    // goes from 0 degrees to 180 degrees
    // in steps of 1 degree
    for (int index = 0; index < NUM_SERVOS; index++)
    {
      RP2040_ISR_Servos.setPosition(ISR_servo[index].servoIndex, position );
    }
    
    // waits 0.1s for the servo to reach the position
    delay(100);
  }
  
  // waits 5s between test
  delay(5000);
}

---

---

Examples:

1. RP2040_MultipleRandomServos
2. RP2040_MultipleServos
3. multiFileProject New

---

Example RP2040_MultipleServos

1. File RP2040_MultipleServos.ino

RP2040_ISR_Servo/examples/RP2040_MultipleServos/RP2040_MultipleServos.ino

Lines 45 to 149 in 39e1604

	#if ( defined(ARDUINO_ARCH_RP2040) || defined(ARDUINO_RASPBERRY_PI_PICO) || defined(ARDUINO_ADAFRUIT_FEATHER_RP2040) || \
	defined(ARDUINO_GENERIC_RP2040) ) && !defined(ARDUINO_ARCH_MBED)
	#if !defined(RP2040_ISR_SERVO_USING_MBED)
	#define RP2040_ISR_SERVO_USING_MBED false
	#endif
	#elif ( defined(ARDUINO_NANO_RP2040_CONNECT) || defined(ARDUINO_RASPBERRY_PI_PICO) || defined(ARDUINO_ADAFRUIT_FEATHER_RP2040) || \
	defined(ARDUINO_GENERIC_RP2040) ) && defined(ARDUINO_ARCH_MBED)
	#if !defined(RP2040_ISR_SERVO_USING_MBED)
	#define RP2040_ISR_SERVO_USING_MBED true
	#endif
	#else
	#error This code is intended to run on the mbed / non-mbed RP2040 platform! Please check your Tools->Board setting.
	#endif
	#define ISR_SERVO_DEBUG 4
	// Can be included as many times as necessary, without `Multiple Definitions` Linker Error
	#include "RP2040_ISR_Servo.h"
	// Published values for SG90 servos; adjust if needed
	#define MIN_MICROS 800
	#define MAX_MICROS 2450
	#define SERVO_PIN_1 16
	#define SERVO_PIN_2 17
	#define SERVO_PIN_3 18
	#define SERVO_PIN_4 19
	#define SERVO_PIN_5 20
	#define SERVO_PIN_6 21
	typedef struct
	{
	int servoIndex;
	uint8_t servoPin;
	} ISR_servo_t;
	#define NUM_SERVOS 6
	ISR_servo_t ISR_servo[NUM_SERVOS] =
	{
	{ -1, SERVO_PIN_1 }, { -1, SERVO_PIN_2 }, { -1, SERVO_PIN_3 }, { -1, SERVO_PIN_4 }, { -1, SERVO_PIN_5 }, { -1, SERVO_PIN_6 }
	};
	void setup()
	{
	for (int index = 0; index < NUM_SERVOS; index++)
	{
	pinMode(ISR_servo[index].servoPin, OUTPUT);
	digitalWrite(ISR_servo[index].servoPin, LOW);
	}
	Serial.begin(115200);
	while (!Serial);
	delay(200);
	#if defined(ARDUINO_ARCH_MBED)
	Serial.print(F("\nStarting RP2040_MultipleServos on Mbed "));
	#else
	Serial.print(F("\nStarting RP2040_MultipleServos on "));
	#endif
	Serial.println(BOARD_NAME);
	Serial.println(RP2040_ISR_SERVO_VERSION);
	for (int index = 0; index < NUM_SERVOS; index++)
	{
	ISR_servo[index].servoIndex = RP2040_ISR_Servos.setupServo(ISR_servo[index].servoPin, MIN_MICROS, MAX_MICROS);
	if (ISR_servo[index].servoIndex != -1)
	{
	Serial.print(F("Setup OK Servo index = ")); Serial.println(ISR_servo[index].servoIndex);
	RP2040_ISR_Servos.setPosition(ISR_servo[index].servoIndex, 0);
	}
	else
	{
	Serial.print(F("Setup Failed Servo index = ")); Serial.println(ISR_servo[index].servoIndex);
	}
	}
	}
	void loop()
	{
	int position; // position in degrees
	for (position = 0; position <= 180; position += 10)
	{
	// goes from 0 degrees to 180 degrees
	// in steps of 10 degree
	for (int index = 0; index < NUM_SERVOS; index++)
	{
	RP2040_ISR_Servos.setPosition(ISR_servo[index].servoIndex, position);
	}
	// waits 1s for the servo to reach the position
	delay(1000);
	}
	delay(5000);
	}

---

---

Debug Terminal Output Samples

1. RP2040_MultipleRandomServos on Mbed RaspberryPi Pico

Starting RP2040_MultipleRandomServos on Mbed RaspberryPi Pico
Mbed RP2040_ISR_Servo v1.1.2
Setup OK Servo index = 0
Setup OK Servo index = 1
Setup OK Servo index = 2
Setup OK Servo index = 3
Setup OK Servo index = 4
Setup OK Servo index = 5
Servos @ 0 degree
Servos idx = 0, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 1, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 2, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 3, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 4, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 5, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos @ 90 degree
Servos idx = 0, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos idx = 1, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos idx = 2, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos idx = 3, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos idx = 4, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos idx = 5, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos @ 180 degree
Servos idx = 0, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos idx = 1, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos idx = 2, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos idx = 3, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos idx = 4, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos idx = 5, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos sweeps from 0-180 degrees
Servos @ 0 degree
Servos idx = 0, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 1, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 2, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 3, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 4, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 5, act. pos. (deg) = 800, pulseWidth (us) = 800

---

2. RP2040_MultipleRandomServos on RaspberryPi Pico

Starting RP2040_MultipleRandomServos on RaspberryPi Pico
RP2040_ISR_Servo v1.1.2
Setup OK Servo index = 0
Setup OK Servo index = 1
Setup OK Servo index = 2
Setup OK Servo index = 3
Setup OK Servo index = 4
Setup OK Servo index = 5
Servos @ 0 degree
Servos idx = 0, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 1, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 2, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 3, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 4, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 5, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos @ 90 degree
Servos idx = 0, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos idx = 1, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos idx = 2, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos idx = 3, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos idx = 4, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos idx = 5, act. pos. (deg) = 1625, pulseWidth (us) = 1625
Servos @ 180 degree
Servos idx = 0, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos idx = 1, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos idx = 2, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos idx = 3, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos idx = 4, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos idx = 5, act. pos. (deg) = 2450, pulseWidth (us) = 2450
Servos sweeps from 0-180 degrees
Servos @ 0 degree
Servos idx = 0, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 1, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 2, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 3, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 4, act. pos. (deg) = 800, pulseWidth (us) = 800
Servos idx = 5, act. pos. (deg) = 800, pulseWidth (us) = 800

---

3. RP2040_MultipleServos on RaspberryPi Pico

Starting RP2040_MultipleServos on RASPBERRY_PI_PICO
RP2040_ISR_Servo v1.1.2
Setup OK Servo index = 0
Setup OK Servo index = 1
Setup OK Servo index = 2
Setup OK Servo index = 3
Setup OK Servo index = 4
Setup OK Servo index = 5

---

---

Debug

Debug is enabled by default on Serial.

You can also change the debugging level from 0 to 2. Be careful and using level 2 only for temporary debug purpose only.

#define TIMER_INTERRUPT_DEBUG       1
#define ISR_SERVO_DEBUG             1

---

Troubleshooting

If you get compilation errors, more often than not, you may need to install a newer version of the core for Arduino boards.

Sometimes, the library will only work if you update the board core to the latest version because I am using newly added functions.

---

---

Issues

Submit issues to: RP2040_ISR_Servo issues

---

---

TO DO

1. Search for bug and improvement.

---

DONE

1. Similar features for Arduino (UNO, Mega, etc...), ESP32, ESP8266 and STM32
2. Add functions getPosition() and getPulseWidth()
3. Optimize the code
4. Add complicated examples
5. Convert to h-only style
6. Add example multiFileProject to demo for multiple-file project
7. Optimize code by using passing by reference instead of by `value
8. Permit using servos with different pulse ranges simultaneously
9. Add astyle using allman style. Restyle the library

---

---

Contributions and thanks

Many thanks for everyone for bug reporting, new feature suggesting, testing and contributing to the development of this library. Especially to these people who have directly or indirectly contributed to this RP2040_ISR_Servo library

1. Thanks to Radek Voltr for the PR setPulseWidth - removed wrong map #2, leading to new version v1.1.0
2. Thanks to Samt43 for the PR Fix Bug #5 : Permit using servos with different pulse ranges simultaneously #4, leading to new version v1.1.2

Radek Voltr

Samt43

---

Contributing

If you want to contribute to this project:

• Report bugs and errors
• Ask for enhancements
• Create issues and pull requests
• Tell other people about this library

---

---

License

• The library is licensed under MIT

---

Copyright

Copyright (c) 2021- Khoi Hoang